*COMDECK  COMCWTW            WRITE WORDS FROM WORKING BUFFER.            COMCWTW
 WTW      CTEXT  COMCWTW - WRITE WORDS FROM WORKING BUFFER.              COMCWTW
 WTW      SPACE  4,10                                                    COMCWTW
          IF     -DEF,QUAL$,1                                            COMCWTW
          QUAL   COMCWTW                                                 COMCWTW
          BASE   D                                                       COMCWTW
*         COMMENT COPYRIGHT CONTROL DATA CORPORATION. 1970, 1978.        COMCWTW
 WTW      SPACE  4,10                                                    COMCWTW
***       WTW - WRITE WORDS FROM WORKING BUFFER.                         COMCWTW
*                                                                        COMCWTW
*         D. A. CAHLANDER.   70/11/29.                                   COMCWTW
*         R. E. TATE.        73/11/04.                                   COMCWTW
*         G. M. TOWNSEND.    77/06/15.                                   COMCWTW
*         C. J. CONRAD.      81/08/06.
* 
*         ******************************************************* 
*         * THIS COMMON DECK IS PART OF THE COMMON COMMON DECKS * 
*         * RESIDING ON THE COMPASS PROGRAM LIBRARY, AND BEING  * 
*         * MAINTAINED BY THE COMPASS PROJECT.  ANY CHANGES     * 
*         * REQUIRED SHOULD BE DIRECTED TO THE COMPASS PROJECT  * 
*         * THROUGH THE PROPER PROCEDURE.                       * 
*         ******************************************************* 
* 
*                                                                        COMCWTW
*         WTW TRANSFERS DATA FROM A WORKING BUFFER TO A CIO              COMCWTW
*         BUFFER.  IT ALSO CONTAINS THE DUMP CIO BUFFER AND WRITE EXIT   COMCWTW
*         ROUTINES REQUIRED BY WTC, WTH, AND WTS.                        COMCWTW
 WTW      SPACE  4,10                                                    COMCWTW
***       WTW TRANSFERS DATA FROM A WORKING BUFFER TO A CIO              COMCWTW
*         BUFFER.  THIS DECK ALSO CONTAINS DCB=, AND WTX=.               COMCWTW
*         IF THE BUFFER BECOMES SUFFICIENTLY FULL TO REQUIRE WRITING,    COMCWTW
*         OR THE DEVICE TYPE INDICATES A NOS/BE TERMINAL,                COMCWTW
*         WTW WILL PERFORM A *WRITE* FUNCTION UNLESS THE SYMBOL *WRIF$*  COMCWTW
*         IS DEFINED. IN THIS CASE, THE CIO FUNCTION THAT IS IN THE FET  COMCWTW
*         WILL BE RE-ISSUED.                                             COMCWTW
*                                                                        COMCWTW
*         WHEN CALLING CIO= FROM THIS ROUTINE B6 AND B7                  COMCWTW
*         MUST CONTAIN WORKING STORAGE BUFFER ADDRESS,                   COMCWTW
*         AND NUMBER OF WORDS TO TRANSFER RESPECTIVELY                   COMCWTW
*         AS ERROR PROCESSING ROUTINES DEPEND UPON                       COMCWTW
*         THESE REGISTERS.                                               COMCWTW
*                                                                        COMCWTW
*         THE THRESHOLD CONDITION TO ISSUE WRITE FUNCTIONS
*         IS BUFFER HALF FULL FOR BUFFERS LARGER
*         THAN 511 DECIMAL WORDS, AND BUFFER TOTALLY
*         FULL FOR SMALLER BUFFERS.  IF THE SYMBOL
*         WTX$ IS DEFINED, THEN THE THRESHOLD IS
*         BUFFER FULL FOR ALL BUFFER SIZES. 
* 
*         ENTRY  (X2) = ADDRESS OF FET FOR FILE.                         COMCWTW
*                (B6) = FWA WORKING BUFFER.                              COMCWTW
*                (B7) = WORD COUNT OF WORKING BUFFER.                    COMCWTW
*                IF (B7) = 0, NO TRANSFER WILL BE PERFORMED.             COMCWTW
*                                                                        COMCWTW
*         EXIT   (B1) = 1.                                               COMCWTW
*                (X2) = ADDRESS OF FET FOR FILE.                         COMCWTW
*                (B6) = ADDRESS OF NEXT WORD TO BE TRANSFERRED FROM      COMCWTW
*                       WORKING BUFFER.                                  COMCWTW
*                (B7) = 0 IF TRANSFER COMPLETE.                          COMCWTW
*                     = REMAINING WORD COUNT IF *CIO=* WAS CALLED TO     COMCWTW
*                       WRITE DATA AND RETURNED AN ERROR STATUS.         COMCWTW
*                (X7) = ERROR STATUS IF (B7) = 0.                        COMCWTW
*                                                                        COMCWTW
*         USES   X - 1, 2, 3, 4, 6, 7.                                   COMCWTW
*                B - 1, 2, 3, 4, 5, 6, 7.                                COMCWTW
*                A - 1, 2, 3, 4, 6, 7.                                   COMCWTW
*                                                                        COMCWTW
*         CALLS  CIO=.                                                   COMCWTW
* 
*         MACROS RECALL, WRITE. 
                                                                         COMCWTW
                                                                         COMCWTW
 WTW18    SX6    B3+B4       ADVANCE IN                                  COMCWTW
          SB3    B3+B4                                                   COMCWTW
          SB6    B6+B4                                                   COMCWTW
          SB7    B7-B4                                                   COMCWTW
          SA1    X2+B1                                                   COMCWTW
          NE     B3,B5,WTW19 IF IN .NE. LIMIT                            COMCWTW
          SX6    X1          IN = FIRST                                  COMCWTW
 WTW19    SA6    A1+B1       UPDATE IN                                   COMCWTW
          NZ     B7,WTW1     IF NOT END OF TRANSFER                      COMCWTW
          SA4    X2                                                      COMCWTW
          LX4    59-0                                                    COMCWTW
          PL     X4,WTW=     IF BUFFER BUSY, RETURN                      CPSA104
          AX1    54          CHECK FOR DT = 61XX (NOS/BE TERMINAL)       COMCWTW
          SX1    X1+77B-61B                                              COMCWTW
          ZR     X1,WTW11    IF NOS/BE TERMINAL, FLUSH BUFFER            COMCWTW
                                                                         COMCWTW
 WTW=     SUBR               ENTRY/EXIT                                  COMCWTW
 WTW1     SA1    X2+3        (B4) = OUT                                  COMCWTW
          SA3    X2+2        (B3) = IN                                   COMCWTW
          IF     -DEF,B1=1,1                                             COMCWTW
          SB1    1                                                       COMCWTW
          SA4    A1+B1       (B5) = LIMIT                                COMCWTW
          ZR     B7,WTW=     IF WORKING BUFFER EMPTY, RETURN             CPSA104
          SB4    X1                                                      COMCWTW
          SA1    X2+B1       (B2) = FIRST                                COMCWTW
          SB3    X3                                                      COMCWTW
          SB5    X4                                                      COMCWTW
          SB2    X1                                                      COMCWTW
          SA1    B6          READ FIRST WORD                             COMCWTW
          NE     B2,B4,WTW2  IF OUT .NE. FIRST                           COMCWTW
          SB4    B5                                                      COMCWTW
 WTW2     LT     B3,B4,WTW3  IF NO END AROUND                            COMCWTW
          SB4    B5+1                                                    COMCWTW
 WTW3     SB4    B4-B1       CALCULATE FREE DATA SPACE                   COMCWTW
          SB4    B4-B3       (B4) = TRANSFER LENGTH                      COMCWTW
          ZR     B4,WTW13    IF NO ROOM                                  COMCWTW
          BX7    X1                                                      COMCWTW
          LE     B4,B7,WTW4  IF NOT ENOUGH ROOM                          COMCWTW
          SB4    B7                                                      COMCWTW
                                                                         COMCWTW
*         INITIALIZE REGISTERS FOR TRANSFER.                             COMCWTW
                                                                         COMCWTW
 WTWA     BSS    0                                                       COMCWTW
 WTW4     SA3    WTWC        PRESET CMU CODE AND VOID STACK              COMCWTW
          RJ     WTW16                                                   COMCWTW
*         SA1    A1+B1       (NO CMU)                                    COMCWTW
*         SX4    B4-B1       (NO CMU)                                    COMCWTW
*         MX6    -3          (NO CMU)                                    COMCWTW
*         SA7    B3          (NO CMU)                                    COMCWTW
*                                                                        COMCWTW
*         GT     B4,B1,WTW14 IF MORE THAN 1 WORD  (CMU)                  COMCWTW
*         BX4    X4-X4       (CMU)                                       COMCWTW
*         SA7    B3          (CMU)                                       COMCWTW
                                                                         COMCWTW
 WTW5     BX3    -X6*X4      NUMBER OF ODD WORDS                         COMCWTW
          AX4    3           NUMBER OF BLOCKS                            COMCWTW
          ZR     X3,WTW7     IF NO ODD WORDS                             COMCWTW
                                                                         COMCWTW
*         TRANSFER UP TO 7 WORDS.                                        COMCWTW
                                                                         COMCWTW
 WTW6     SX3    X3-1                                                    COMCWTW
          BX7    X1                                                      COMCWTW
          SA1    A1+B1                                                   COMCWTW
          SA7    A7+B1                                                   COMCWTW
          NZ     X3,WTW6     LOOP                                        COMCWTW
                                                                         COMCWTW
*         PRE-READ REGISTERS.                                            COMCWTW
                                                                         COMCWTW
 WTW7     ZR     X4,WTW18    IF NO BLOCKS                                COMCWTW
          SB5    X2          (B5) = FET ADDRESS                          COMCWTW
          SA2    A1+B1                                                   COMCWTW
          SB2    B1+B1       (B2) = 2                                    COMCWTW
          SA3    A2+B1                                                   COMCWTW
          SB3    X4          (B3) = BLOCK COUNT                          COMCWTW
          SA4    A3+B1                                                   COMCWTW
                                                                         COMCWTW
*         TRANSFER 8 WORD BLOCKS.                                        COMCWTW
                                                                         COMCWTW
 WTW8     BX6    X1                                                      COMCWTW
          LX7    X2                                                      COMCWTW
          SA1    A3+B2                                                   COMCWTW
          SA2    A4+B2                                                   COMCWTW
          SA6    A7+B1                                                   COMCWTW
          SB3    B3-B1                                                   COMCWTW
          SA7    A6+B1                                                   COMCWTW
          BX6    X3                                                      COMCWTW
          LX7    X4                                                      COMCWTW
          SA3    A1+B2                                                   COMCWTW
          SA4    A2+B2                                                   COMCWTW
          SA6    A6+B2                                                   COMCWTW
          SA7    A7+B2                                                   COMCWTW
          BX6    X1                                                      COMCWTW
          LX7    X2                                                      COMCWTW
          SA1    A3+B2                                                   COMCWTW
          SA2    A4+B2                                                   COMCWTW
          SA6    A6+B2                                                   COMCWTW
          SA7    A7+B2                                                   COMCWTW
          BX6    X3                                                      COMCWTW
          LX7    X4                                                      COMCWTW
          SA3    A1+B2                                                   COMCWTW
          SA4    A2+B2                                                   COMCWTW
          SA6    A6+B2                                                   COMCWTW
          SA7    A7+B2                                                   COMCWTW
          NZ     B3,WTW8     LOOP                                        COMCWTW
                                                                         COMCWTW
*         WRITE EXIT.                                                    COMCWTW
                                                                         COMCWTW
          SA3    B5+B2       READ IN                                     COMCWTW
          SA1    A3+B2       (B5) = LIMIT                                COMCWTW
          SX2    B5                                                      COMCWTW
          SB5    X1                                                      COMCWTW
          SA4    X2          CHECK BUFFER STATUS                         COMCWTW
 WTW9     SB6    B6+B4                                                   COMCWTW
          SB7    B7-B4                                                   COMCWTW
          SB3    X3+B4       ADVANCE IN                                  COMCWTW
          SX6    X3+B4                                                   COMCWTW
          LX4    59-0                                                    COMCWTW
          SA3    X2+B1       READ FIRST                                  COMCWTW
          SB2    X3+                                                     COMCWTW
          NE     B3,B5,WTW10 IF IN .NE. LIMIT                            COMCWTW
          SX6    X3+         IN = FIRST                                  COMCWTW
 WTX$     IF     DEF,WTX$ 
 WTW10    EQ     WTW19       CLEAN UP AND RETURN
 WTX$     ELSE
                                                                         COMCWTW
*         TRY TO BUFFER AHEAD.                                           COMCWTW
                                                                         COMCWTW
 WTW10    SA6    A3+B1       STORE IN                                    COMCWTW
          PL     X4,WTW12    IF BUFFER BUSY                              COMCWTW
          AX3    54          CHECK FOR DT = 61XX (NOS/BE TERMINAL)       COMCWTW
          SX3    X3+77B-61B                                              COMCWTW
          ZR     X3,WTW11    IF NOS/BE TERMINAL, FLUSH BUFFER            COMCWTW
          SA1    X2+3        READ OUT                                    COMCWTW
          IX6    X1-X6       (OUT-IN)                                    COMCWTW
          SX7    B5-B2       (LIMIT-FIRST)                               COMCWTW
          LX3    X6,B1       2*(OUT-IN)                                  COMCWTW
          AX6    60          SIGN OF (OUT-IN)                            COMCWTW
          BX4    X6-X7       INVERT BUFFER IF IN .GE. OUT                COMCWTW
          IX6    X4-X3       BUFFER SIZE - 2*(OUT-IN)                    COMCWTW
          NG     X6,WTW12    IF BUFFER THRESHOLD NOT REACHED             COMCWTW
          AX7    9                                                       COMCWTW
          ZR     X7,WTW12    IF BUFFER NOT BIG ENOUGH TO WRITE AHEAD     COMCWTW
 WTX$     ENDIF 
 WRIF$    IF     DEF,WRIF$                                               COMCWTW
 WTW11    SA1    X2          RE-ISSUE CURRENT WRITE FUNCTION             COMCWTW
          SX6    774B                                                    COMCWTW
          BX7    X6*X1                                                   COMCWTW
          RJ     =XCIO=                                                  COMCWTW
 WRIF$    ELSE   1                                                       COMCWTW
 WTW11    WRITE  X2                                                      COMCWTW
          NZ     X7,WTW=     IF ERROR IN LAST *CIO* REQUEST, RETURN      CPSA104
 WTW12    NZ     B7,WTW1     IF NOT DONE                                 COMCWTW
          EQ     WTW=        RETURN                                      CPSA104
                                                                         COMCWTW
*         DUMP CIRCULAR BUFFER.                                          COMCWTW
                                                                         COMCWTW
 WTW13    SA1    X2          CHECK BUFFER STATUS                         COMCWTW
          LX1    59-0                                                    COMCWTW
          NG     X1,WTW11    IF NOT BUSY                                 COMCWTW
          ZR     X1,WTW11    IF BLANK FET                                COMCWTW
          RECALL                                                         COMCWTW
          EQ     WTW1        CONTINUE WRITE                              COMCWTW
                                                                         COMCWTW
*         MOVE DATA WITH CMU.                                            COMCWTW
                                                                         COMCWTW
 WTW14    SX4    B4-819                                                  COMCWTW
          PL     X4,WTW15    IF TOO BIG FOR CMU                          COMCWTW
          SX4    B4          10 * WORDS = CHARACTERS                     COMCWTW
          LX6    X4,B1                                                   COMCWTW
          BX1    X0          SAVE X0                                     COMCWTW
          LX4    3                                                       COMCWTW
          IX6    X4+X6                                                   COMCWTW
          SX7    B6          SET SOURCE ADDRESS                          COMCWTW
          SX4    B3          SET DESTINATION ADDRESS                     COMCWTW
          LX7    30                                                      COMCWTW
          BX4    X4+X7                                                   COMCWTW
          MX7    -4                                                      COMCWTW
          BX3    X7*X6       EXTRACT UPPER PORTION                       COMCWTW
          BX6    -X7*X6      EXTRACT LOWER PORTION                       COMCWTW
          LX3    48-4                                                    COMCWTW
          BX4    X4+X3                                                   COMCWTW
          LX6    26                                                      COMCWTW
          BX6    X4+X6                                                   COMCWTW
          AX3    51                                                      COMCWTW
          SA6    WTWC        STORE DESCRIPTOR WORD                       COMCWTW
          IM     WTWC        MOVE DATA                                   COMCWTW
          BX0    X1          RESTORE X0                                  COMCWTW
          ZR     X3,WTW18    IF NO WRITE EXIT                            COMCWTW
          SA4    X2                                                      COMCWTW
          SX3    B3          RESET IN                                    COMCWTW
          EQ     WTW9                                                    COMCWTW
                                                                         COMCWTW
 WTWB     BSS    0                                                       COMCWTW
 WTW15    SA1    A1+B1       MOVE DATA WITHOUT CMU                       COMCWTW
          SX4    B4-B1                                                   COMCWTW
          MX6    -3                                                      COMCWTW
          SA7    B3                                                      COMCWTW
          EQ     WTW5                                                    COMCWTW
                                                                         COMCWTW
*         CMU PRESET CODE.                                               COMCWTW
*         WTWC IS READ UP AND THEN RETURN JUMPED TO IN ORDER TO VOID     COMCWTW
*         THE INSTRUCTION STACK. WTWC IS ALSO USED AS THE CMU            COMCWTW
*         DESCRIPTOR WORD.                                               COMCWTW
                                                                         COMCWTW
 WTWC     GT     B4,B1,WTW14 IF MORE THAN 1 WORD TO MOVE  (CMU)          COMCWTW
          BX4    X4-X4                                                   COMCWTW
          SA7    B3                                                      COMCWTW
 WTW16    EQU    WTWC        USED TO VOID STACK                          COMCWTW
                                                                         COMCWTW
*         PRESET FOR CMU CODE.                                           COMCWTW
                                                                         COMCWTW
          SA4    RA.CMU      CHECK IF CMU AVAILABLE                      COMCWTW
          SB4    WTWA                                                    COMCWTW
          NG     X4,WTW17    IF CMU                                      COMCWTW
          SA3    WTWB                                                    COMCWTW
 WTW17    BX6    X3                                                      COMCWTW
          SA6    B4                                                      COMCWTW
          RJ     *           VOID INSTRUCTION STACK.
          EQ     WTW1                                                    COMCWTW
                                                                         COMCWTW
 WTX      SPACE  4,10                                                    COMCWTW
**        WTX - WRITE EXIT.                                              COMCWTW
*         IF BUFFER IS BUSY, RETURN.                                     COMCWTW
*         IF DEVICE TYPE = 61XX (NOS/BE TERMINAL), ALWAYS ISSUE WRITE.   COMCWTW
*         OTHERWISE, WORD COUNT OF BUFFER IS CHECKED, AND A WRITE        COMCWTW
*         FUNCTION IS REQUESTED IF NECESSARY.                            COMCWTW
*                                                                        COMCWTW
*         ENTRY  (A2) = ADDRESS OF IN.                                   COMCWTW
*                (A3) = ADDRESS OF FIRST.                                COMCWTW
*                (A4) = RETURN ADDRESS.                                  COMCWTW
*                (B3) = IN+1.                                            COMCWTW
*                (B4) = OUT.                                             COMCWTW
*                (B5) = LIMIT.                                           COMCWTW
*                (X2) = IN                                               COMCWTW
*                (B1) = 1.                                               COMCWTW
*                                                                        COMCWTW
*         EXIT   TO RETURN ADDRESS.                                      COMCWTW
*                                                                        COMCWTW
*         CALLS  CIO=.                                                   COMCWTW
* 
*         MACROS WRITE. 
                                                                         COMCWTW
                                                                         COMCWTW
 WTX=     SA1    A3-B1       CHECK BUFFER STATUS                         COMCWTW
          SX6    X2          STORE IN                                    COMCWTW
          LX1    59                                                      COMCWTW
          SA6    A2                                                      COMCWTW
 WTX$     IF     -DEF,WTX$
          PL     X1,WTX1     IF BUFFER BUSY                              COMCWTW
          SA3    A3          CHECK DEVICE TYPE                           COMCWTW
          BX6    X3                                                      COMCWTW
          AX6    54                                                      COMCWTW
          SX6    X6+77B-61B                                              COMCWTW
          ZR     X6,WTX0     IF NOS/BE TERMINAL                          COMCWTW
                                                                         COMCWTW
*         IF BUFFER IS NOT BUSY, CHECK SIZE OF BUFFER.                   COMCWTW
*         ISSUE WRITE IF THRESHOLD IS REACHED.                           COMCWTW
                                                                         COMCWTW
          SA1    A2+B1       REREAD OUT 
          SB4    X1 
          SX6    B4-B3       (OUT-IN+1)                                  COMCWTW
          SB2    X3          (LIMIT-FIRST)                               COMCWTW
          LX3    X6,B1       2*(OUT-IN+1)                                COMCWTW
          SX7    B5-B2                                                   COMCWTW
          AX6    60          SIGN OF (OUT-IN+1)                          COMCWTW
          BX4    X6-X7       INVERT BUFFER IF IN+1 .GE. OUT              COMCWTW
          IX6    X4-X3       BUFFER SIZE - 2*(OUT-IN+1)                  COMCWTW
          NG     X6,WTX1     IF BUFFER THRESHOLD NOT REACHED             COMCWTW
          AX7    9                                                       COMCWTW
          ZR     X7,WTX1     IF BUFFER NOT BIG ENOUGH TO WRITE AHEAD     COMCWTW
 WRIF$    IF     DEF,WRIF$                                               COMCWTW
 WTX0     SA1    A3-B1       REISSUE CURRENT WRITE FUNCTION              COMCWTW
          SX6    774B                                                    COMCWTW
          BX7    X6*X1                                                   COMCWTW
          SX2    A1          SET FET ADDRESS                             COMCWTW
          RJ     =XCIO=                                                  COMCWTW
 WRIF$    ELSE   1                                                       COMCWTW
 WTX0     WRITE  A3-B1                                                   COMCWTW
 WTX$     ENDIF 
  
 WTX1     SB2    A4          SET RETURN ADDRESS                          COMCWTW
          SX2    A3-B1       RESET (X2)                                  COMCWTW
          JP     B2          RETURN                                      COMCWTW
 DCB      SPACE  4,10                                                    COMCWTW
**        DCB - DUMP CIRCULAR BUFFER.                                    COMCWTW
*         IF BUFFER IS BUSY, RECALL AND RETURN.                          COMCWTW
*         IF BUFFER IS NOT BUSY, REQUEST WRITE FUNCTION AND RETURN.      COMCWTW
*                                                                        COMCWTW
*         ENTRY  (A2) = ADDRESS OF IN.                                   COMCWTW
*                (A3) = ADDRESS OF FIRST.                                COMCWTW
*                (A4) = RETURN ADDRESS.                                  COMCWTW
*                (X2) = IN.                                              COMCWTW
*                (B1) = 1.                                               COMCWTW
*                (B2) = FET STATUS READ PRIOR TO READ OF OUT. 
*                                                                        COMCWTW
*         EXIT   TO RETURN ADDRESS - 1.                                  COMCWTW
*                (X2) = FET ADDRESS.
*                                                                        COMCWTW
*         CALLS  CIO=.
* 
*         MACROS RECALL, WRITE. 
                                                                         COMCWTW
                                                                         COMCWTW
 DCB=     SX1    B2          CHECK BUFFER STATUS
          SX6    X2          STORE IN                                    COMCWTW
          LX1    59                                                      COMCWTW
          SA6    A2                                                      COMCWTW
          NG     X1,DCB1     IF NOT BUSY                                 COMCWTW
          ZR     X1,DCB1     IF BLANK FET                                COMCWTW
          SX2    A3-B1       RESET FET ADDRESS
          RECALL                                                         COMCWTW
          SB2    A4-B1       CONTINUE WRITE                              COMCWTW
          JP     B2                                                      COMCWTW
 WRIF$    IF     DEF,WRIF$                                               COMCWTW
 DCB1     SA1    A3-B1       RE-ISSUE CURRENT WRITE FUNCTION             COMCWTW
          SX6    774B                                                    COMCWTW
          BX7    X6*X1                                                   COMCWTW
          SX2    A1          SET FET ADDRESS                             COMCWTW
          RJ     =XCIO=                                                  COMCWTW
 WRIF$    ELSE   1                                                       COMCWTW
 DCB1     WRITE  A3-B1                                                   COMCWTW
          SB2    A4-B1       CONTINUE WRITE                              COMCWTW
          JP     B2                                                      COMCWTW
 WTW      SPACE  4,10                                                    COMCWTW
          BASE   *                                                       COMCWTW
 QUAL$    IF     -DEF,QUAL$                                              COMCWTW
          QUAL   *                                                       COMCWTW
 WTW=     EQU    /COMCWTW/WTW=                                           COMCWTW
 WTX=     EQU    /COMCWTW/WTX=                                           COMCWTW
 DCB=     EQU    /COMCWTW/DCB=                                           COMCWTW
 QUAL$    ENDIF                                                          COMCWTW
 WTW      ENDX                                                           COMCWTW
