*COMDECK  COMCWOD            CONVERT WORD TO OCTAL DISPLAY CODE.         COMCWOD
 WOD      CTEXT  COMCWOD - CONVERT WORD TO OCTAL DISPLAY CODE.           COMCWOD
 WOD      SPACE  4,10                                                    COMCWOD
          IF     -DEF,QUAL$,1                                            COMCWOD
          QUAL   COMCWOD                                                 COMCWOD
          BASE   D                                                       COMCWOD
 WOD      SPACE  4,10                                                    COMCWOD
***       WOD - CONVERT WORD TO OCTAL DISPLAY CODE.                      COMCWOD
*                                                                        COMCWOD
*         C. R. WILLIS.      UNIVERSITY OF MINNESOTA.                    COMCWOD
* 
*         ******************************************************* 
*         * THIS COMMON DECK IS PART OF THE COMMON COMMON DECKS * 
*         * RESIDING ON THE COMPASS PROGRAM LIBRARY, AND BEING  * 
*         * MAINTAINED BY THE COMPASS PROJECT.  ANY CHANGES     * 
*         * REQUIRED SHOULD BE DIRECTED TO THE COMPASS PROJECT  * 
*         * THROUGH THE PROPER PROCEDURE.                       * 
*         ******************************************************* 
* 
*                                                                        COMCWOD
*         WOD CONVERTS A WORD INTO OCTAL DISPLAY CODE.                   COMCWOD
 WOD      SPACE  4,10                                                    COMCWOD
***       ENTRY  (X1) = WORD TO BE CONVERTED.                            COMCWOD
*                                                                        COMCWOD
*         EXIT   (X6,X7) = CONVERSION.                                   COMCWOD
*                (B1) = 1.                                               COMCWOD
*                                                                        COMCWOD
*         USES   X - 0, 1, 2, 3, 4, 5, 6, 7.                             COMCWOD
*                B - NONE.                                               COMCWOD
*                A - 2, 3, 4, 5.                                         COMCWOD
*                                                                        COMCWOD
*         CALLS  NONE.                                                   COMCWOD
                                                                         COMCWOD
                                                                         COMCWOD
 WOD      SUBR               ENTRY/EXIT                                  COMCWOD
          IF     -DEF,B1=1,1                                             COMCWOD
          SB1    1                                                       COMCWOD
                                                                         COMCWOD
*         (X1)   =           ABCDE FGHIJ KLMNO PQRST                     COMCWOD
                                                                         COMCWOD
          SA2    WODA        7.... 7.... 7.... 7....                     COMCWOD
          BX7    X2*X1       A.... F.... K.... P....                     COMCWOD
          LX1    3           BCDEF GHIJK LMNOP QRSTA                     COMCWOD
          BX6    X2*X1       B.... G.... L.... Q....                     COMCWOD
          LX1    3           CDEFG HIJKL MNOPQ RSTAB                     COMCWOD
          LX7    27          .K... .P... .A... .F...                     COMCWOD
          BX0    X2*X1       C.... H.... M.... R....                     COMCWOD
          LX6    21          ...L. ...Q. ...B. ...G.                     COMCWOD
          LX1    3           DEFGH IJKLM NOPQR STABC                     COMCWOD
          IX7    X6+X7       .K.L. .P.Q. .A.B. .F.G.                     COMCWOD
          BX5    X2*X1       D.... I.... N.... S....                     COMCWOD
          LX1    3           EFGHI JKLMN OPQRS TABCD                     COMCWOD
          LX0    15          H.... M.... R.... C....                     COMCWOD
          BX6    X2*X1       E.... J.... O.... T....                     COMCWOD
          IX7    X7+X0       HK.L. MP.Q. RA.B. CF.G.                     COMCWOD
          LX5    9           ..I.. ..N.. ..S.. ..D..                     COMCWOD
          LX6    3           ....J ....O ....T ....E                     COMCWOD
          IX7    X7+X6       HK.LJ MP.QO RA.BT CF.GE                     COMCWOD
          SA4    A2+B1       .7.7. 7.7.7 ..... .....                     COMCWOD
          SA3    A4+B1       ..... .7.7. 7.7.7 .....                     COMCWOD
          BX7    X7+X5       HKILJ MPNQO RASBT CFDGE                     COMCWOD
          BX2    X7*X4       .K.L. M.N.O ..... .....                     COMCWOD
          SA5    A3+B1       00000 00000 00000 00000                     COMCWOD
          BX1    X7*X3       ..... .P.Q. R.S.T .....                     COMCWOD
          LX7    30          RASBT CFDGE HKILJ MPNQO                     COMCWOD
          IX2    X5+X2       .K.L. M.N.O 00000 00000                     COMCWOD
          BX0    X7*X4       .A.B. C.D.E ..... .....                     COMCWOD
          IX0    X0+X5       .A.B. C.D.E 00000 00000                     COMCWOD
          LX1    45          ..... ..... .P.Q. R.S.T                     COMCWOD
          BX3    X7*X3       ..... .F.G. H.I.J .....                     COMCWOD
          IX7    X1+X2       .K.L. M.N.O .P.Q. R.S.T                     COMCWOD
          LX3    45          ..... ..... .F.G. H.I.J                     COMCWOD
          IX6    X0+X3       .A.B. C.D.E .F.G. H.I.J                     COMCWOD
          EQ     WODX        RETURN                                      COMCWOD
                                                                         COMCWOD
 WODA     CON    70000700007000070000B                                   COMCWOD
          CON    07070707070000000000B                                   COMCWOD
          CON    00000070707070700000B                                   COMCWOD
          CON    10H0000000000                                           COMCWOD
 WOD      SPACE  4,10                                                    COMCWOD
          BASE   *                                                       COMCWOD
 QUAL$    IF     -DEF,QUAL$                                              COMCWOD
          QUAL   *                                                       COMCWOD
 WOD      EQU    /COMCWOD/WOD                                            COMCWOD
 WOD=     EQU    /COMCWOD/WOD 
 QUAL$    ENDIF                                                          COMCWOD
 WOD      ENDX                                                           COMCWOD
