*COMDECK MFL
          TITLE  COMMON MEMORY MANAGER, V1.0, CMM.MFL - SET MAXFL 
*CALL CMMCOM
          COMMENT  "SUBSYS"SET MAXFL. 
          B1=1
 CMM.MFL  SPACE  4
***       CMM.MFL - SET MAXFL.
* 
* 
*              THE VALUE USED BY CMM FOR *MAXFL* IS CHANGED TO NEW-MFL. 
*         ALL BLOCK CONTENTS ARE UNAFFECTED.  AN INITIAL CALL OF THIS 
*         FORM IS NOT NECESSARY.
* 
*         ENTRY  (X1) = NEW-MFL.
* 
*         EXIT   (B1) = 1.
* 
*         SAVES  X - 0, 5.
*                B - 2, 3.
*                A - 0. 
  
  
          CMMENT  MFL 
 CMM.MFL  EQ     *+400000B   ENTRY / EXIT 
          SB1    1
          RJ     =XCMM.ICM   INITIALIZE AND SET A0
  
 IS       IFSAFE
          SX6    3RMFL       SAVE FUNCTION NAME 
          SA6    A0-MNFNAME 
          SA4    CMM.MFL     SAVE RETURN ADDRESS
          LX4    30 
          BX6    X4 
          SA6    A0-MNRETURN
          SA3    A0-IMAPM 
          ZR     X3,MFL101
          UERR   CMEPMR,0    CALLED FROM POINTER-MAINTENANCE ROUTINE
  
 MFL101   SA2    RA65        (X2) = CURRENT FL
          BX2    -X2
          SA2    X2 
          SX2    X2 
          IX3    X1-X2
          PL     X3,MFL102
          UERR   CMEMXSM,0   MAY NOT REDUCE MAXFL LT FL 
  
 MFL102   SA2    A0-MAXFLST  (X2) = TRUE JOB MAXFL
          IX3    X2-X1
          PL     X3,MFL103
          UERR   CMEMXBG,0   MAY NOT SET MAXFL GT ORIGINAL VALUE
  
 MFL103   BSS    0
 IS       ENDIF 
  
          SX7    X1          SET MAXFL FOR USE BY CMM 
          SA7    A0-MAXFL 
          SA2    A0-MNSAVEA0  RESTORE A0
          SA0    X2 
          EQ     CMM.MFL     RETURN 
  
