*COMDECK KIL
          TITLE  COMMON MEMORY MANAGER, V1.0, CMM.KIL - DEACTIVATE CMM
*CALL CMMCOM
          COMMENT  "SUBSYS"DEACTIVATE CMM.
          B1=1
 CMM.KIL  SPACE  4
***       CMM.KIL - DEACTIVATE CMM. 
* 
* 
*              CMM BECOMES INACTIVE AND CEASES TO EXERCISE ANY
*         CONTROL OVER THE DYNAMIC AREA.  FROM THIS POINT HENCEFORTH
*         NONE OF THE PROGRAMMING RESTRICTIONS IMPOSED BY CMM APPLY, NO 
*              THIS CALL DOES NOT CAUSE ANY OF THE CONTENT OF THE ACTIVE
*         BLOCKS TO CHANGE, THUS THE USER MAY CONTINUE TO REFERENCE ANY 
*         BLOCKS THAT WERE ACTIVE AT THE TIME OF THIS CALL.  HOWEVER, 
*         MANAGEMENT OF THE CONTENTS AND SIZE OF THE DYNAMIC AREA 
*         BECOMES THE USER-S RESPONSIBILITY, AND THERE IS NO WAY TO 
*         HAVE CMM RESUME CONTROL OF ANY SUCH BLOCKS. 
* 
*         ENTRY  NONE.
* 
*         EXIT   (B1) = 1.
* 
*         SAVES  X - 0, 5.
*                B - 2, 3.
*                A - 0. 
  
  
          ENTRY  CMM.KIL
*         CMM POINTER SHOULD BE CONSIDERED VALID AND THE ENTIRE 
*         SITUATION SHOULD BE TREATED AS IF CMM WERE NOT PRESENT. 
 CMM.KIL  EQ     *+400000B   ENTRY / EXIT 
          SB1    1
          SA1    RA65 
          MX6    42 
          BX2    X6*X1
          SX1    X1 
          BX4    -X1
          PL     X1,CMM.KIL  IF CMM NOT ALREADY ACTIVE
          BX6    X2+X4
          SA6    A1          SET DABA POSITIVE
          IFNE   DEFVER,0,2  IF ERROR CHECKING (SAFE) VERSION 
          MX7    0
          SA7    =XCMS.ACT   CLEAR ERROR CHECK ACTIVE FLAG
          SX7    14B         ISSUE SYSTEM REQUEST TO SET NON-CMM MODE 
          SA7    ARG
 SCP2     IFC    EQ,/"OS.NMV"/SCOPE 2/
          MEMORY SCM,ARG
 SCP2     ELSE
          MEMORY  CM,ARG,RCL
 SCP2     ENDIF 
          EQ     CMM.KIL     RETURN 
  
 ARG      CON    0           MEM ARG
  
