*COMDECK GSS
          TITLE  COMMON MEMORY MANAGER, V1.0, CMM.GSS - GET SUMMARY STAT
,S
*CALL CMMCOM
          COMMENT  "SUBSYS"GET SUMMARY STATISTICS.
          B1=1
 CMM.GSS  SPACE  4
***       CMM.GSS - GET SUMMARY STATISTICS. 
* 
* 
*              THE INFORMATION SHOWN BELOW IS RETURNED BY CMM.
*         THIS FUNCTION IS ESPECIFLLY INTENDED FOR USE BY ROUTINES
*         WHICH PROVIDE JOB SUMMARY INFORMATION AT THE END OF THE 
*         JOB STEP. 
* 
*         ENTRY  NONE.
* 
*         EXIT   (B1) = 1.
*                (X1) = FWA OF THE FOLLOWING ARRAY: 
* 
*                WORD 0  - MAXIMUM NUMBER OF ALLOCATED WORDS. 
*                WORD 1  - MAXIMUM FIELD LENGTH ATTAINED. 
*                WORD 2  - NUMBER OF CRASHES. 
*                WORD 3  - NUMBER OF FIELD LENGTH INCREASES.
*                WORD 4  - NUMBER OF FIELD LENGTH DECREASES.
*                WORD 5  - NUMBER OF OVERFLOW-ACTION CALLS. 
* 
*         SAVES  X - 0, 5.
*                B - 2, 3.
*                A - 0. 
  
  
          CMMENT  GSS 
 CMM.GSS  EQ     *+400000B   ENTRY / EXIT 
          SB1    1
          RJ     =XCMM.ICM   INITIALIZE AND SET A0
  
 IS       IFSAFE
          SX7    3RGSS       SAVE FUNCTION NAME 
          SA7    A0-MNFNAME 
          SA4    CMM.GSS     SAVE RETURN ADDRESS
          LX4    30 
          BX6    X4 
          SA6    A0-MNRETURN
          SA2    A0-IMAPM 
          ZR     X2,GSS102
          UERR   CMEPMR,0    CALLED FROM POINTER-MAINTENANCE ROUTINE
  
 GSS102   BSS    0
 IS       ENDIF 
  
          MX1    0           SET CURRENT MAX. ALLOCATED SPACE 
          RJ     =XCMM.AUS   -- ADJUST USED SPACE --
          SA6    AMAXALL     MAXIMUM NO. OF ALLOCATED WORDS 
          SA2    A0-FLMAX    MAXIMUM FIELD LENGTH ATTAINED
          SA3    A0-CRASHES  NUMBER OF CRASHES
          BX6    X2 
          LX7    X3 
          SA6    AFLMAX 
          SA7    ACRASHES 
          SA2    A0-FLUP     NUMBER OF FL INCREASES 
          SA3    A0-FLDOWN   NUMBER OF FL DECREASES 
          BX6    X2 
          LX7    X3 
          SA6    AFLUP
          SA7    AFLDOWN
          SA2    A0-OACALLS  NUMBER OF OVERFLOW-ACTION CALLS
          BX6    X2 
          SA6    AOACALLS 
          SX1    AREA        (X1) = FWA RETURN AREA 
          SA2    A0-MNSAVEA0  RESTORE A0
          SA0    X2 
          EQ     CMM.GSS     RETURN 
  
*         RETURN AREA.
  
 AREA     BSS    0
 AMAXALL  BSS    1           MAXIMUM NO. OF ALLOCATED WORDS 
 AFLMAX   BSS    1           MAXIMUM FIELD LENGTH ATTAINED
 ACRASHES BSS    1           NUMBER OF CRASHES
 AFLUP    BSS    1           NUMBER OF FL INCREASES 
 AFLDOWN  BSS    1           NUMBER OF FL DECREASES 
 AOACALLS BSS    1           NUMBER OF OVERFLOW-ACTION CALLS
  
