*COMDECK COMFWTW                                                         DECK2
          CTEXT  COMFWTW     WRITE WORDS FROM WORKING BUFFER             DECK2
          QUAL   COMFWTW                                                 DECK2
          BASE   D                                                       DECK2
          SPACE  4                                                       DECK2
 COMFWTW  TITLE  WTW - WRITE WORDS FROM WORKING BUFFER                   DECK2
**        WTW    WRITE WORDS FROM WORKING BUFFER TO SEQUENTIAL FILE.     DECK2
*                                                                        DECK2
*                                                                        DECK2
*         ENTRY  (X2) = PSEUDO-FET WORD 1                                DECK2
*                (A2) = PSEUDO-FET ADDRESS                               DECK2
*                (B1) = 1                                                DECK2
*                (B6) = WSA ADDRESS                                      DECK2
*                (B7) = WSA LENGTH (WORDS)                               DECK2
*                                                                        DECK2
*         EXIT   (X2) = FIT ADDRESS                                      DECK2
*                (B1) = 1                                                DECK2
*                                                                        DECK2
*         USES   ALL BUT A0                                              DECK2
*                                                                        DECK2
*         CALLS  MOVE, RECORD MANAGER                                    DECK2
                                                                         DECK2
                                                                         DECK2
*         MOVE DATA TO HOLDING BUFFER AND EXIT.                          DECK2
                                                                         DECK2
 WTW2     BX0    X2          TEMP SAVE FILE CONTROL WORD                 DECK2
          SX1    B7          WSA LENGTH                                  DECK2
          SX2    B6          WSA ADDRESS                                 DECK2
          SA6    A3          UPDATE -IN-                                 DECK2
          MOVE   X1,X2,X3                                                DECK2
          BX2    X0          RESTORE (X2) = FILE CONTROL WORD (FIT ADDR) DECK2
                                                                         DECK2
 WTW=     JP     *+1S17                                                  DECK2
                                                                         DECK2
                                                                         DECK2
 WTW3     SA3    A2+I.IN     (X3) = HOLDING BUFFER -IN- POINTER          DECK2
          SA4    A2+I.LIMIT  (X4) = HOLDING BUFFER -LIMIT- POINTER       DECK2
          SX6    X3+B7       UPDATED -IN-                                DECK2
          IX0    X6-X4       DATA LENGTH .MI. EMPTY BUFFER SPACE         DECK2
          MI     X0,WTW2     IF DATA WILL NOT OVERFLOW BUFFER            DECK2
                                                                         DECK2
*         FILL HOLDING BUFFER.  CALL RECORD MANAGER TO WRITE IT TO FILE. DECK2
                                                                         DECK2
          MX7    1                                                       DECK2
          IX1    X4-X3       EMPTY BUFFER SPACE = STORAGE MOVE WRD COUNT DECK2
          SX4    X1+B6       FWA REMAINING DATA                          DECK2
          LX7    -59D+58D                                                DECK2
          BX6    X7+X2                                                   DECK2
          LX4    18D                                                     DECK2
          SA6    A2          FILE SPILLED FLAG .ON.                      DECK2
                                                                         DECK2
                                                                         DECK2
          SX2    B6          (X2) = WSA FWA                              DECK2
          SB2    A2          TEMP SAVE ADDR OF FILE CONTROL WORD         DECK2
          BX0    X4+X0       TEMP SAVE DATA TRANSFER RESTART PARAMS --   DECK2
*                            24/0, 18/DATA FWA, 18/REMAINING DATA LENGTH DECK2
          ZR     X1,WTW4     IF ZERO LENGTH MOVE                         DECK2
          MOVE   X1,X2,X3                                                DECK2
 WTW4     SA3    B2+I.LIMIT  (X3) = -LIMIT-                              DECK2
          SA1    B2+B1       (X1) = -FIRST-                              DECK2
          SA2    B2          (X2) = FILE CONTROL WORD                    DECK2
          IX3    X3-X1       (X3) = HOLDING BUFFER LENGTH                DECK2
          BX6    X1                                                      DECK2
          SA6    A1+B1       RESET -IN- = -FIRST-                        DECK2
          FETCH  X2,RT,X4 
          NZ     X4,WTW4A    IF RT " W
          PUTW   X2,X1,X3    WRITE HOLDING BUFFER TO FILE                DECK2
          EQ     WTW4B
 WTW4A    PUTWP  X2,X1,X3    WRITE HOLDING BUFFER TO FILE 
 WTW4B    SB7    X0          LENGTH OF REMAINING DATA 
          AX0    18D                                                     DECK2
          ZR     B7,WTW=     IF NO MORE DATA TO TRANSFER,EXIT            DECK2
          SB6    X0          FWA REMAINING DATA                          DECK2
          EQ     WTW3        CONTINUE FILLING HOLDING BUFFER             DECK2
          QUAL   *                                                       DECK2
 WTW=     EQU    /COMFWTW/WTW=                                           DECK2
          ENDX                                                           DECK2
