*COMDECK COMFGFL                                                         DECK2
 GFL      CTEXT  COMFGFL - GET FILE LABEL                                DECK2
                                                                         DECK2
                                                                         DECK2
          BASE   D                                                       DECK2
          IF     -DEF,QUAL$,1                                            DECK2
          QUAL   COMFGFL                                                 DECK2
                                                                         DECK2
                                                                         DECK2
***       GFL - GET FILE LABEL                                           DECK2
*                                                                        DECK2
*         P. M. OVERELL                                                  DECK2
*         ADAPTED FOR RECORD MANAGER I/O FROM *COMQGFL* BY R. H. GOODELL DECK2
*                                                                        DECK2
*         ENTRY  (X1) = REWIND FLAG                                      DECK2
*                     = 0, NO REWIND                                     DECK2
*                     " 0, REWIND FILE                                   DECK2
*                (X2) = PSEUDO-FET ADDRESS                               DECK2
*                (B1) = 1                                                DECK2
*                                                                        DECK2
*         EXIT   (X6) = 0, 7RM HAS NO USER LABEL PROCESSING              DECK2
*                                                                        DECK2
*         CALLS  RECORD MANAGER (OPEN, REWIND)                           DECK2
                                                                         DECK2
                                                                         DECK2
 GFL      JP     *+1S17      ENTRY/EXIT...                               DECK2
          SA2    X2                                                      DECK2
          ZR     X1,GFL1     IF NO REWIND                                DECK2
          STORE  X2,OF=R                                                 DECK2
          STORE  X2,LT=S     SET LABEL TYPE = STANDARD
          STORE  X2,LA=GFLA  SET LABEL AREA 
          STORE  X2,LBL=80   SET LABEL LENGTH 
          STORE  X2,LX=GFL3  SET LABEL EXIT OWN CODE ADDRESS
          STORE  X2,ULP=F    USER LABEL PROCESSING = FILE LABELS
                                                                         DECK2
 GFL1     OPEN   A2                                                      DECK2
          STORE  X2,LX=0
          SA1    GFLA        FIRST WORD OF LABEL
          MX6    24 
          SA3    A1+B1       SECOND WORD OF LABEL 
          BX1    -X6*X1      WIPE OUT HDR1
          SA4    A3+B1       THIRD WORD OF LABEL
          BX7    X6*X3       CHARS 7-10 OF ID 
          LX1    24 
          BX3    -X6*X3      CHARS 11-16 OF ID
          LX7    24 
          MX6    6
          BX4    X6*X4
          LX3    24 
          BX6    X1+X7       1ST 10 CHARS OF LABEL ID 
          LX4    24 
          SA1    =3R
          BX4    X3+X4       LAST 7 CHARS OF LABEL ID 
          IX7    X4+X1       BLANK THE LAST PART OF WORD
          EQ     GFL         EXIT..                                      DECK2
  
 GFL3     GETL   X2,GFLA,80  GET LABEL
          CLOSEL X2          RETURN TO 7RM
  
 GFLA     BSSZ   8           LABEL AREA 
          SPACE  4                                                       DECK2
          BASE   *                                                       DECK2
 QUAL$    IF     -DEF,QUAL$                                              DECK2
          QUAL   *                                                       DECK2
 GFL      EQU    /COMFGFL/GFL                                            DECK2
 QUAL=    ENDIF                                                          DECK2
                                                                         DECK2
                                                                         DECK2
 GFL      ENDX                                                           DECK2
