*COMDECK  COMCSES                                                        DECK1
          CTEXT  COMCSES - SET EQUAL SIGNS IN PARAMETER LIST.            DECK1
          IF     -DEF,QUAL$,1                                            DECK1
          QUAL   COMCSES                                                 DECK1
          BASE   D                                                       DECK1
 SES      SPACE  4                                                       DECK1
***       SES - SET EQUAL SIGNS IN PARAMETER LIST.                       DECK1
*         R.S. HORECK        71/05/04.                                   DECK1
          SPACE  4                                                       DECK1
***              SES INSERTS EQUAL SIGNS IN THE CONTROL CARD ARGUMENTS   DECK1
*         FROM *ARGR* THROUGH THE END OF THE LIST BASED ON THE CONTROL   DECK1
*         CARD IMAGE FOUND AT *CCDR*.                                    DECK1
*                                                                        DECK1
*         ENTRY  (B1) = 1.                                               DECK1
*                (ACTR) = ARGUMENT COUNT.                                DECK1
*                (ARGR - ARGR+(ACTR)) = ARGUMENT LIST.                   DECK1
*                (CCDR) = CONTROL CARD IMAGE IN *C* FORMAT.              DECK1
*                                                                        DECK1
*         EXIT   EACH EQUIVALENCED PARAMETER CONTAINS THE *=* IN THE LOW DECK1
*                6 BITS OF THE ITEM TO THE LEFT OF THE EQUAL SIGN.       DECK1
*                                                                        DECK1
*         USES   X - 1, 2, 3, 4, 6, 7.                                   DECK1
*                B - 3, 4, 5, 6, 7.                                      DECK1
*                A - 1, 2, 3, 6.                                         DECK1
*                                                                        DECK1
*         CALLS  NONE.                                                   DECK1
                                                                         DECK1
                                                                         DECK1
SESSUB    PS     0
          SB6    B1          IGNORE LEADING BLANKS
 SES1     LX1    6           CHECK CHARACTER                             DECK1
          BX6    -X2*X1                                                  DECK1
          SB7    B7-B1       DECREMENT CHARACTER COUNT                   DECK1
          NZ     B7,SES2     IF NOT END OF WORD                          DECK1
          SA1    A1+B1       READ NEXT WORD                              DECK1
          SB7    X7          RESET CHARACTER COUNT                       DECK1
SES2      SX3    X6-1R+      CHECK FOR ALPHANUMERIC 
          MI     X3,SES4     IF ALPHANUMERIC
          SX3    X6-1R*      CHECK FOR STAR 
          ZR     X3,SES4     IF STAR
          SX3    X6-1R       CHECK FOR BLANK
          NZ     X3,SESSUB   IF NOT BLANK 
          NE     B6,B1,SESSUB  IF NOT LEADING BLANK 
          EQ     SES1 
SES4      SB6    B0          NOW PAST LEADING BLANKS
          EQ     SES1 
  
  
SES5      SB6    X6          TERMINATING CHARACTER
          SA3    A3+B1       ADVANCE PARAMETER                           DECK1
          SB3    B3-B1       DECREMENT ARGUMENT COUNT                    DECK1
          BX6    X2*X3       CLEAR LOW ORDER BITS                        DECK1
          NE     B6,B5,SES3  IF SEPARATOR NOT *=*                        DECK1
          BX6    X6+X4       SET *=*                                     DECK1
 SES3     SA6    A3+                                                     DECK1
          LE     B3,SES      IF END OF ARGUMENTS
SES6      RJ     SESSUB      PICK UP ARGUMENT 
          ZR     X3,SES6     IF BLANK TERMINATOR IGNORE IT
          EQ     SES5 
                                                                         DECK1
 SES      PS     0           ENTRY/EXIT                                  DECK1
          SA4    ACTR        ARGUMENT COUNT                              DECK1
          SB3    X4                                                      DECK1
          MX2    60-6                                                    DECK1
          SA1    CCDR        STATEMENT BUFFER                            DECK1
          BX6    X2*X4       CHECK FOR NULL PROGRAM NAME                 DECK1
          SX7    10                                                      DECK1
          ZR     X6,SES      IF NULL PROGRAM NAME                        DECK1
          SB4    1R9                                                     DECK1
          SX4    1R=                                                     DECK1
          SB7    X7          SET CHARACTER COUNT                         DECK1
          BX6    X6-X6       CLEAR LAST WORD OF LIST FOR *ARG*           DECK1
          SB5    1R=                                                     DECK1
          SA6    B3+ARGR                                                 DECK1
          SA3    A6-B1       LAST PARAMETER                              DECK1
          MX6    42                                                      DECK1
          BX6    X6*X3       CLEAR LOWER 18 BITS                         DECK1
          SA6    A3                                                      DECK1
          SA3    B0          INITIALIZE PARAMETER ADDRESS                DECK1
          RJ     SESSUB      PICK UP ARGUMENT 
          EQ     SES5 
          SPACE  4                                                       DECK1
 QUAL$    IF     -DEF,QUAL$                                              DECK1
          QUAL                                                           DECK1
 SES      EQU    /COMCSES/SES                                            DECK1
 QUAL$    ENDIF                                                          DECK1
          ENDX                                                           DECK1
