*DECK ITEMIZE                                                            DECK4
          IDENT  ITEMIZE,ORGP 
          ABS                                                            DECK4
          IPARAMS 
          LIST   F                                                       DECK4
          SST 
          SYSCOM B1                                                      DECK4
  
          IFC    NE,*"OS.NAME"*SCOPE *
          ENTRY  ITEMIZE
          ENTRY  RFL= 
 ORGP     EQU    101B+2 
          ELSE
          ENTRY  ITEMIZE
 ORGP     EQU    101B+1 
          ENDIF 
  
          ORG    ORGP 
 ITEMIZE  TITLE  ITEMIZE - LIST CONTENTS OF A BINARY FILE.
          COMMENT            LIST CONTENTS OF A BINARY FILE.
 ITEMIZE  SPACE  4,8                                                     DECK4
***       ITEMIZE - LIST CONTENTS OF A BINARY FILE. 
*                                                                        DECK4
*         G. R. MANSFIELD    69/06/03.
*         S. I. JASIK        70/07/01.      *E* OPTION. 
*         P. H. MCQUESTEN    71/08/25.      NEW RECORD TYPES. 
*         R. H. FRANK        73/02/28.      EJECT OPTION BETWEEN FILES. 
*         P. M. OVERELL      73/09/15.      7RM I/O FOR SCOPE 2.
*         S. H. FISCHER      74/08/01.      LIST OUTPUT 8 LINES/INCH. 
*         J. L. PAULSON      75/ 01/01.     RELEASE        VER 1.0
*         K. L. SHARP        76/01/01.      *PW* OPTION    VER 1.1
 COPYRT   SPACE  4,8                                                     DECK4
***       CONTROL DATA  PROPRIETARY PRODUCT.
*         COPYRIGHT CONTROL DATA CORP. 1970, 1971, 1972, 1973, 1974,
*                                      1975,1976,1977,1978,1979,1980, 
*                                      1981,1982. 
 GENL     TITLE  GENERAL DESCRIPTION.                                    DECK4
**        ITEMIZE GENERAL OVERVIEW.                                      UTLA039
*                                                                        UTLA039
*                                                                        UTLA039
*            1)  INITIALIZATION -                                        UTLA039
*                      ITEMIZE IS ENTERED IN *ITEM*.  AT THIS TIME       UTLA039
*                      INITIALIZATION TAKES PLACE AND ENTRY CONDITIONS   UTLA039
*                      ARE FLAGGED.  *ARG* IS CALLED TO CRACK THE        UTLA039
*                      CONTROL CARD ARGUMENTS AND THEN TO CALL THE       UTLA039
*                      PROCESSING ROUTINES.                              UTLA039
*                                                                        UTLA039
*            2)  RECORD PROCESSING -                                     UTLA039
*                      THE MAIN LOOP IN *CAT* READS EACH RECORD AND      UTLA039
*                      CALLS *LRS*,  WHICH LISTS THE STANDARD INFOR-     UTLA039
*                      MATION OF THE RECORDS.  RECORD TYPE PROCESSORS    UTLA039
*                      ARE THEN CALLED BY *CAT* TO LIST THE NONSTANDARD  UTLA039
*                      AND OPTIONAL INFORMATION.                         UTLA039
*                                                                        UTLA039
*            3)  COMPLETION -                                            UTLA039
*                      *CAT*, UNLESS REWIND SUPPRESSED, REWINDS THE      UTLA039
*                      INPUT FILE.  IT THEN CLOSES INPUT AND OUTPUT      UTLA039
*                      FILES AND ISSUES A MESSAGE TO THE DAYFILE,        UTLA039
*                      *ITEMIZE* COMPLETE.                               UTLA039
*                                                                        UTLA039
*                                                                        UTLA039
 ITEMIZE  SPACE  4,8                                                     UTLA039
***       ITEMIZE LISTS PERTINENT INFORMATION ABOUT EACH RECORD OF A     DECK4
*         BINARY FILE.
*                                                                        DECK4
*         INFORMATION INCLUDES -                                         DECK4
*                NUMBER - COUNTING FROM THE BEGINING OF THE FILE.        DECK4
*                NAME - FROM THE FIRST WORD OF THE RECORD OR THE SECOND  DECK4
*                            WORD OF THE 7700 TABLE IF PRESENT.          DECK4
*                TYPE - (SEE BELOW).
*                LENGTH - (LESS 7700 TABLE LENGTH). 
*                A CYCLIC LOGICAL CHECK SUM (NOT INCLUDING 7700 TABLE). 
*                CONTENTS OF 7700 TABLE IF PRESENT.                      DECK4
*                OTHER PERTINENT INFORMATION ACCORDING TO TYPE.          DECK4
*                                                                        DECK4
*         TYPE MAY BE ONE OF THE FOLLOWING --                            DECK4
*                                                                        UTLA039
*                TEXT        TEXT RECORD
*                6PP         6000-SERIES PERIPHERAL PROCESSOR OVERLAY    DECK4
*                OVCAP       OVERLAY CAPSULE
*                REL         RELOCATABLE CENTRAL PROGRAM                 UTLA039
*                OVL         SINGLE ENTRY POINT OVERLAY                  UTLA039
*                ULIB        NOS USER LIBRARY                            UTLA039
*                            NOTE -- NOS/BE USER LIBRARIES ARE NOT       UTLA039
*                                  RECOGNIZED.                           UTLA039
*                OPL         MODIFY PROGRAM LIBRARY DECK                 DECK4
*                OPLC        MODIFY PROGRAM LIBRARY COMMON DECK          DECK4
*                OPLD        MODIFY PROGRAM LIBRARY DIRECTORY            DECK4
*                ABS         MULTIPLE ENTRY POINT OVERLAY 
*                7PP         7000-SERIES PERIPHERAL PROCESSOR OVERLAY    DECK4
*                UPL*        UPDATE PROGRAM LIBRARY (* IS CONTROL CHAR)  DECK4
*                UCF         UPDATE COMPRESSED COMPILE FILE              DECK4
*                ACF         MODIFY COMPRESSED COMPILE FILE              DECK4
*                CAP         CAPSULE
*                DATA        ARBITRARY DATA 
*                UPLR        RANDOM UPDATE PROGRAM LIBRARY
*                UPLRC       RANDOM UPDATE PROGRAM LIBRARY COMMON DECK
*                8PP         CYBER 180 PERIPHERAL PROCESSOR OVERLAY 
* 
*                THE FOLLOWING ARE ONLY ON A NOS/BE DEADSTART TAPE.      UTLA039
*                                                                        UTLA039
*                LIBNT       NOS/BE LIBRARY NAME TABLE RECORD            UTLA039
*                SDR         SPECIAL DEADSTART RECORD                    UTLA039
*                PPNT        NOS/BE PP PROGRAM NAME TABLE                UTLA039
*                                                                        DECK4
*         A RECORD OF *REL* FORMAT WILL HAVE THE ENTRY POINTS LISTED,    DECK4
*                IF THE -E- OPTION IS SELECTED.                          DECK4
*                                                                        DECK4
*         A RECORD OF *TEXT* FORMAT WILL BE LISTED IN ITS ENTIRETY IF 
*                ITS NAME IS *COMMENT* OR IF IT IS A DEADSTART RECORD 
*                (APRDECK, CMRDECK, EQPDECK, IPRDECK, OR LIBDECK).
* 
*         A RECORD OF *TEXT* FORMAT WILL HAVE ITS FIRST LINE LISTED IF
*                ITS NAME IS *OVERLAY*. 
*                                                                        DECK4
*         A RECORD OF *OPL* OR *OPLC* FORMAT WILL HAVE THE MODIFIERS     DECK4
*                AND THEIR *YANK* STATUS LISTED.                         DECK4
*                                                                        DECK4
*         A RECORD OF *ULIB* FORMAT WILL SUPPRESS LISTING OF FOLLOWING   DECK4
*                RECORDS IN *REL* FORMAT UNLESS -U- OPTION IS USED.      DECK4
*                                                                        DECK4
*         A RECORD OF *UPL* FORMAT WILL HAVE THE CORRECTION IDENTS
*                LISTED IF THE -E- OPTION  IS SELECTED. 
 CONTRLC  TITLE  ITEMIZE -  CONTROL CARD CALL.
***       CONTROL CARD CALL.                                             DECK4
*                                                                        DECK4
*                                                                        DECK4
*         ITEMIZE(FNAME,P1,P2,...,PN)                                    DECK4
*                                                                        DECK4
*                FNAME       NAME OF BINARY FILE TO BE ITEMIZED.         DECK4
*                                                                        DECK4
*                PN MAY BE ONE OF --                                     DECK4
*                                                                        DECK4
*                BL          BURSTABLE LISTING. 
*                E           EXPAND = LIST ENTRY POINTS OF RELOCATABLE   DECK4
*                            PROGRAMS, AND UPDATE DECK NAMES.            DECK4
*                            OVERRIDES -N- PARAMETER.                    DECK4
*                L=LFN       OUTPUT ON FILE *LFN*.                       DECK4
*                N           ITEMIZE TO EOI.
*                N=X         LIST X FILES.  *X* IS A DECIMAL INTEGER.    DECK4
*                            IF X = 0, LIST WILL TERMINATE ON AN         DECK4
*                            EMPTY FILE.                                 DECK4
*                NR          NO REWIND OF *FNAME*.                       DECK4
*                PD          LIST OUTPUT AT 8 LINES/INCH (512 ONLY).
*                U           SELECT USER LIBRARY LIST.                   DECK4
*                                                                        DECK4
*         ASSUMED PARAMETERS --                                          DECK4
*                                                                        UTLA039
*                FNAME       = *LGO*. 
*                BL          NOT SELECTED.
*                E           NOT SELECTED.
*                L           = *OUTPUT*.
*                N           = 1. 
*                NR          NOT SELECTED -- *FNAME* WILL BE REWOUND
*                            BEFORE AND AFTER.
*                PD          NOT SELECTED.
*                U           NOT SELECTED.
 ITEMIZE  SPACE  4,8
***       DAYFILE MESSAGES. 
*                                                                        DECK4
*                                                                        DECK4
*         *ERROR IN ARGUMENTS.*                                          DECK4
*                ARGUMENT WAS NOT AS SPECIFIED ABOVE.                    DECK4
*                                                                        DECK4
*         *ILLEGAL FILE COUNT.*                                          DECK4
*                FILE COUNT WAS NOT NUMERIC.                             DECK4
*                                                                        DECK4
*         *FILE NAME CONFLICT.*                                          DECK4
*                OUTPUT FILE NAME AND BINARY FILE NAME WERE THE SAME.    DECK4
 ITEMIZE  TITLE  MACROS AND SYMBOLS.
*         BXQ - CONVENIENCE OPDEF TO ZERO AN *X* REGISTER.               UTLA039
  
  
          PURGDEF  BXQ
  
 BXQ      OPDEF  I,V                                                     DECK4
          ERRNZ  V           BXQ - Q MUST BE ZERO                        DECK4
          IFC    EQ, V -0 ,2                                             DECK4
          BX.I   -X.I-X.I                                                DECK4
          SKIP   1                                                       DECK4
          BX.I   X.I-X.I                                                 DECK4
          ENDM                                                           DECK4
 ITEMIZE  SPACE  4,8
*         SELECT INPUT/OUTPUT SYSTEM.                                    UTLA039
*                                                                        DECK4
*         POSSIBLE VALUES ARE -                                          DECK4
*                CP#RM = 0 - USE CIO                                     DECK4
*                      = 7 - USE 7RM                                     DECK4
  
  
 #MD      IF     MIC,OS.NAME
 #MD      IF     MIC,OS.VER 
 #MD      IFC    EQ,*"OS.NAME"*SCOPE *
 #MD      IFC    EQ,*"OS.VER"*2.1 * 
 CP#RM    EQU    7
 #MD      ELSE
 CP#RM    EQU    0
 #MD      ENDIF 
          SPACE  4                                                       DECK4
*         UTILITY ITEMS.                                                 UTLA039
*                                                                        DECK4
*         CHAR = SYMBOL FOR NUMBER OF BITS PER CHARACTER                 DECK4
*         LINP = SYMBOL FOR NUMBER OF LINES PER PAGE                     DECK4
*         RCL = SYMBOL TO INDICATE RECALL                                DECK4
  
  
 CHAR     EQU    6           NUMBER OF BITS PER CHARACTER 
 IP.PD    CEQU   6
 IP.PW    CEQU   136         DEFAULT PRINT WIDTH
 IP.PS    CEQU   60D         LINES PER PAGE 
 RCL      EQU    1           RECALL SYMBOL
 ARGR     EQU    RA.ARG      ARGUMENT POINTER                            DECK4
 ACTR     EQU    RA.ACT      ARGUMENT COUNT                              DECK4
 CCDR     EQU    RA.CCD      STATEMENT BUFFER                            DECK4
  
 .8LPI    EQU    8D          CONSTANT FOR 8 LPI 
 .8LPILC  EQU    80D         CONSTANT PAGE SIZE FOR 8LPI
 .6LPI    EQU    6D          CONSTANT FOR 6 LPI 
 .TPW     EQU    68D         DEFAULT PRINT WIDTH FOR TTY FILES
 .FPW     EQU    130         MINIMUM FOR FULL WIDTH (NON - TTY FILE)
 ITEMIZE  SPACE  4,8
          NOREF  CHAR                                                    DECK4
 ITEMIZE  SPACE  4,8
**        COMMON DECKS CALLED.                                           UTLA039
*                                                                        UTLA039
*                COMA7IO     MACE I/O MACROS FOR SCOPE2.                 UTLA039
*                COMAREG     ENHANCEMENT FOR COMPASS R= PSEUDO.          UTLA039
*                COMCCDD     CONSTANT TO DECIMAL DISPLAY CODE CONVERSION UTLA039
*                COMCCOD     CONSTANT TO OCTAL DISPLAY CODE CONVERSION.  UTLA039
*                COMCCPM     PROCESS *CPM* REQUEST. 
*                COMCMVE     MOVE BLOCK OF DATA.                         UTLA039
*                COMCSYS     PROCESS SYSTEM REQUEST.                     UTLA039
*                COMCCIO     I/O FUNCTION PROCESSOR.                     UTLA039
*                COMCRDW     READ WORDS TO WORKING BUFFER.               UTLA039
*                COMCWTW     WRITE WORDS TO WORKING BUFFER.              UTLA039
*                COMCWTC     WRITE CODED LINE, -C- FORMAT.               UTLA039
*                COMCGFL     GET FILE LABEL.                             UTLA039
*                COMFRIO     RECORD MANAGER MISC. I/O FUNCTIONS.         UTLA039
*                COMFRDW     READ WORDS TO WORKING BUFFER.               UTLA039
*                COMFWTW     WRITE WORDS FROM WORKING BUFFER.            UTLA039
*                COMFWTC     WRITE CODED LINE, -C- FORMAT.               UTLA039
*                COMFGFL     GET FILE LABEL.                             UTLA039
*                COMCSFN     SPACE FILL NAME.                            UTLA039
*                COMCSRT     SET RECORD TYPE. 
*                COMCSES     SET EQUAL SIGNS IN PARAMETER LIST.          UTLA039
*CALL COMA7IO                                                            DECK4
          SPACE  4                                                       DECK4
          LIST   -F                                                      DECK4
                                                                         DECK4
 #RM      IFNE   CP#RM,0                                                 DECK4
                                                                         DECK4
                                                                         DECK4
 #RM      ENDIF                                                          DECK4
                                                                         DECK4
          LIST   *                                                       DECK4
 ITEMIZE  SPACE  4,8
*         MICROS FOR FILE NAMES.                                         UTLA039
                                                                         DECK4
 OUT      MICRO  1,,$OUTPUT$                                             DECK4
 LGO      MICRO  1,,$LGO$                                                DECK4
  
*         PSRLEVEL MICRO FOR HEADER LINES 
  
 PSRLEVEL MICRO  1,5,*- 871*
          IFC    -EQ,*"MODLEVEL"*"JDATE"*,1 
 PSRLEVEL MICRO  1,5,*"MODLEVEL"* 
 ITEMIZE  SPACE  4,8
*         ASSEMBLY CONSTANTS                                             UTLA039
                                                                         DECK4
                                                                         DECK4
 BUFL     EQU    10000B      WORKING BUFFER 
 ELL      EQU    8           MAXIMUM NUMBER OF ENTRY POINTS PER LINE     DECK4
 SBUFL    EQU    100B        SCRATCH BUFFER                              DECK4
                                                                         DECK4
 #RM      IFEQ   CP#RM,0                                                 DECK4
                                                                         DECK4
*         CIO BUFFER LENGTHS.                                            UTLA039
                                                                         DECK4
 OBUFL    EQU    1001B       OUTPUT BUFFER LENGTH                        DECK4
 FBUFL    EQU    20001B      FILE BUFFER LENGTH 
                                                                         DECK4
 #RM      ELSE                                                           DECK4
                                                                         DECK4
*         HOLDING BUFFER LENGTHS FOR RM I/O.                             UTLA039
                                                                         DECK4
 OBUFL    EQU    0           OUTPUT - NO HOLDING BUFFER USED             DECK4
 FBUFL    EQU    400B        FILE HOLDING BUFFER LENGTH                  DECK4
                                                                         DECK4
 #RM      ENDIF                                                          DECK4
 ITEMIZE  SPACE  4,8
          EJECT                                                          DECK4
 ITEMIZE  SPACE  4,8
 ITEMIZE  TITLE  STORAGE ASSIGNMENT.
*         FETS (FOR CIO) OR PSUEDO-FETS AND FITS (FOR 7RM).              UTLA039
                                                                         DECK4
                                                                         DECK4
 O        BSS    0           OUTPUT LISTING FILE                         DECK4
                                                                         DECK4
          FET    OUT,OBUF,OBUFL,1                                        DECK4
                                                                         DECK4
 #RM      IFNE   CP#RM,0                                                 DECK4
                                                                         DECK4
 FI.OUT   FILE   LFN="OUT",FO=SQ,OF=N,CF=N,PD=OUTPUT,EO=T,CM=YES,BT=, 
,RT=W,MRL=140D
                                                                         DECK4
 #RM      ENDIF                                                          DECK4
                                                                         DECK4
                                                                         DECK4
 F        BSS    0           BINARY INPUT FILE                           DECK4
                                                                         DECK4
          FET    LGO,FBUF,FBUFL,3                                        DECK4
                                                                         DECK4
 #RM      IFNE   CP#RM,0                                                 DECK4
                                                                         DECK4
 FI.LGO   FILE   LFN="LGO",FO=SQ,OF=N,CF=N,PD=INPUT,EO=T,CM=NO,BT=,RT=W 
                                                                         DECK4
 #RM      ENDIF                                                          DECK4
                                                                         DECK4
 COMMON   SPACE  4,8                                                     DECK4
*         COMMON DATA.                                                   DECK4
                                                                         DECK4
                                                                         DECK4
 DS       CON    0           " 0 INDICATES SPECIAL DEADSTART RECORD 
 EF       CON    1           EMPTY FILE FLAG                             DECK4
 EO       CON    0           BL (EJECT) OPTION FLAG 
 FC       CON    1           FILE COUNT                                  DECK4
 FE       CON    0           FUNNY EOF FLAG                              DECK4
 RN       CON    0           RECORD NUMBER                               DECK4
 FN       CON    1           FILE NUMBER                                 DECK4
 CS       CON    0           CHECKSUM                                    DECK4
 PW       CON    IP.PW       PRINT WIDTH
 PWS      CON    0           PRINT WIDTH SPECIFIED FLAG 
 RL       CON    0           RECORD LENGTH                               DECK4
          CON    0           ZERO RECORD SUBTOTAL                        DECK4
          CON    0           FILE LENGTH                                 DECK4
          CON    0           EOI LENGTH                                  DECK4
 RW       CON    1           REWIND FLAG (0=NO)                          DECK4
 NM       CON    0           RECORD NAME                                 DECK4
 TY       CON    0           RECORD TYPE                                 DECK4
 UL       CON    0,0         USER LIBRARY LIST FLAG                      DECK4
 F.ODE    BSSZ   16          OPTICAL DISK FET EXTENSION 
                                                                         DECK4
*         LIST DATA.                                                     DECK4
                                                                         DECK4
 LE       CON    0           NON ZERO IF TO LIST ENTRIES OF REL PROGS    DECK4
 LC       CON    IP.PS       LINE COUNT 
 LL       CON    IP.PS       LINES/PAGE LIMIT 
 PN       CON    1           PAGE NUMBER                                 DECK4
 FW       CON    -.FPW       FULL WIDTH FLAG ( FULL WIDTH IF NEGATIVE ) 
          CON    0           EOL MASK FOR LIMITED WIDTH PRINT LINE
          CON    0           EOL WORD FOR LIMITED WIDTH PRINT LINE
  
*         PRINT DENSITY CONTROL.
  
 PD       CON    IP.PD       DEFAULT PRINT DENSITY
 PDS      CON    0           USER FLAG
  
 PD.R     DATA   0           PRINT DENSITY RESTORE FLAG 
  
 TT       CON    1           TTY FILE FLAG ( 0 IF TTY ) 
                                                                         DECK4
 TITL     CON    1H1
          DIS    1,ITEMIZE OF 
          DIS    1,                                                      DECK4
          CON    4AFILE                                                  DECK4
          CON    5A1                                                     DECK4
          DIS    1,                                                      DECK4
 SHORTTL  EQU    *-TITL 
                                                                         DECK4
 FI       DIS    3, ** UNLABELED **                                      DECK4
                                                                         DECK4
 DATE     DIS    1, YY/MM/DD. 
 TIME     DIS    1, HH.MM.SS.                                            DECK4
          CON    4APAGE                                                  DECK4
 PAGE     CON    8L                                                      DECK4
 TITLL    EQU    *-TITL                                                  DECK4
                                                                         DECK4
                                                                         DECK4
 SBTL     CON    6AREC                                                   DECK4
          DIS    1,NAME                                                  DECK4
          DIS    1,TYPE                                                  DECK4
          CON    6ALENGTH 
          CON    10H   CKSUM
          CON    7ADATE                                                  DECK4
 PWSBTL   EQU    *-SBTL 
          CON    8HCOMMENTS 
          DIS    4, 
          CON    7AITEMIZE
          CON    8L "PSRLEVEL"
 SBTLL    EQU    *-SBTL                                                  DECK4
  
*         DEADSTART FILE DESCRIPTOR BUFFER. 
  
 DS.FD    BSS    30          LIBRARY FILE DISCRIPTORS (10H NAME)         UTLA042
 PPL      DIS    1, 
 PPBUF    BSSZ   45 
 PPCOUNT  CON    1
 PPPOS    CON    15 
 ITEMIZE  TITLE  MAIN PROGRAM.
**        CAT -  MAIN PROGRAM.                                           DECK4
*                                                                        UTLA039
*         HEADER LINES ARE WRITTEN AND PRINT WIDTH IS VALIDATED AND      UTLA039
*         IMPLEMENTED IN THIS ROUTINE.  A LOOP READS EACH RECORD, AND    UTLA039
*         CALLS *LRS* TO BEGIN PROCESSING, AND CALLS THE RECORD TYPE     UTLA039
*         PROCESSORS TO DO THE NONSTANDARD PROCESSING.  AFTER ALL THE    UTLA039
*         RECORDS HAVE BEEN COMPLETED, INPUT AND OUTPUT FILES ARE        UTLA039
*         REWOUND, UNLESS OTHERWISE REQUESTED, AND CLOSED.               UTLA039
*                                                                        UTLA039
*         CALLS  LRS, RDR, EOF, WHL, REL, ULB, OPL, ABS, UPL, TXT, CAP,  UTLA039
*                    SDR.                                                UTLA039
*                                                                        UTLA039
                                                                         DECK4
                                                                         DECK4
 CAT0     RJ     WHL         WRITE HEADER LINES 
  
 CAT1     BSS    0                                                       DECK4
                                                                         DECK4
 #RM      IFEQ   CP#RM,0                                                 DECK4
                                                                         DECK4
          READ   F           BEGIN READ                                  DECK4
                                                                         DECK4
 #RM      ENDIF                                                          DECK4
                                                                         DECK4
          SA1    RN          ADVANCE RECORD NUMBER                       DECK4
          SA2    PW 
          SX6    X1+B1                                                   DECK4
          MX7    0           CLEAR LENGTH 
          SA6    A1                                                      DECK4
          SA7    RL                                                      DECK4
          SA7    CS          CLEAR CHECKSUM                              DECK4
          RJ     RDR         READ RECORD                                 DECK4
          SA2    FE 
          BX1    -X2*X1 
          MI     X1,CAT3     IF EOF/EOI AND NO DATA 
          SA1    RL          ADVANCE SUBTOTAL                            DECK4
          SA2    A1+B1                                                   DECK4
          SA3    A2+B1       ADVANCE FILE TOTAL                          DECK4
          IX6    X2+X1                                                   DECK4
          SA6    A2                                                      DECK4
          IX7    X3+X1                                                   DECK4
          SA7    A3                                                      DECK4
          SA1    UL+1                                                    DECK4
          ZR     X1,CAT2     IF NOT USER LIBRARY                         DECK4
          SA2    TY          CHECK TYPE                                  DECK4
          SB2    X2-10B                                                  DECK4
          NZ     B2,CAT1     IF NOT *OPLD*                               DECK4
          MX7    0           CLEAR USER LIBRARY                          DECK4
          SA7    A1                                                      DECK4
          EQ     CAT1                                                    DECK4
                                                                         DECK4
 CAT2     RJ     LRS         LIST RECORD STATUS                          DECK4
          SA2    FE 
          SA1    TY          PROCESS OTHER LIST                          DECK4
          MX7    0           CLEAR EOF FLAG                              DECK4
          SA4    X1+RTJV
          SA7    EF                                                      DECK4
          MI     X2,CAT3     IF EOF WITH DATA 
          SB7    X4 
          JP     B7          PROCESS CONTENTS 
                                                                         DECK4
 CAT3     RJ     EOF         PROCESS END OF FILE                         DECK4
          MI     X1,CAT5     IF END-OF-INFORMATION                       DECK4
          SA1    FC          CHECK FILE COUNT                            DECK4
          NZ     X1,CAT4     IF NOT EMPTY FILE REQUEST                   DECK4
          SA2    EF          CHECK EOF                                   DECK4
          NZ     X2,CAT5     IF EMPTY FILE                               DECK4
          SX6    X2+B1       SET EOF FLAG                                DECK4
          SA6    A2                                                      DECK4
          EQ     CAT0        LOOP 
                                                                         DECK4
 CAT4     SX6    X1-1        DECREMENT FILE COUNT                        DECK4
          SA6    A1                                                      DECK4
          NZ     X6,CAT0     PROCESS NEXT FILE
                                                                         DECK4
 CAT5     SA1    PN          CHECK PAGE NUMBER                           DECK4
          SA2    EO 
          LX1    59                                                      DECK4
          ZR     X2,CAT6     IF PAGE EJECTS SUPPRESSED
          MI     X1,CAT6     IF PAGE NUMBER EVEN                         DECK4
          WRITEC  O,(=2L1 ),1                                            DECK4
 CAT6     SA1    RW                                                      DECK4
          ZR     X1,CAT7     IF REWIND SUPPRESSED                        DECK4
          REWIND F                                                       DECK4
 CAT7     SA4    TT 
          ZR     X4,CAT9     IF CONNECTED FILE
  
          SA1    PD.R        GET RESTORE *PD* FLAG
          ZR     X1,CAT9     IF NO RESET OF *PD* NEEDED 
  
          WRITEC O,A1,1 
 CAT9     WRITER O,RCL
                                                                         DECK4
 #RM      IFNE   CP#RM,0                                                 DECK4
                                                                         DECK4
          CLOSE  O                                                       DECK4
          CLOSE  F                                                       DECK4
                                                                         DECK4
 #RM      ENDIF                                                          DECK4
                                                                         DECK4
          MESSAGE  (=C* ITEMIZE COMPLETE.*),LOCAL                        DECK4
          ENDRUN                                                         DECK4
 EOF      SPACE  4,8                                                     DECK4
**        EOF - PROCESS END OF FILE.                                     DECK4
*                                                                        DECK4
*         ENTRY  (FE) = FUNNY EOF FLAG.                                  DECK4
* 
*         EXIT   (X1) NEGATIVE IF END-OF-INFORMATION ENCOUNTERED.        DECK4
                                                                         DECK4
                                                                         DECK4
 EOF8     SX1    SBUF        PRINT FILE LENGTH                           DECK4
          RJ     WOF                                                     DECK4
          SA2    FN          ADVANCE FILE NUMBER                         DECK4
          =X7    X2+1 
          SA7    A2                                                      DECK4
          SX1    X2+B1       CONVERT NUMBER                              DECK4
          RJ     CDD         CONVERT TO DECIMAL 
          LX6    4*CHAR 
          SX7    B0          CLEAR LENGTHS                               DECK4
          SA3    DS.FD
          SA6    TITL+4 
          ZR     X3,EOF11    IF NOT DEADSTART RECORD
          SA3    FN 
          SA4    X3+DS.FD-2 
          NZ     X4,EOF10A   IF NOT END OF LIBRARIES
          SA3    =1H
          BX6    X3 
          SA6    FI-1        RESET *LIBRARY* TO *          *
          MX6    0
          BX4    X3 
          SA6    DS.FD       INDICATE END OF PROCESSING DEADSTART 
 EOF10A   LX6    X4 
          SA3    =1H
          SA6    FI          SET NEW LIBRARY NAME INTO TITLE LINE 
          BX6    X3 
          SA6    FI+1 
 EOF11    SA7    RL+1 
          SA7    A7+B1                                                   DECK4
          BX1    X1-X1       INDICATE NOT E-O-I                          DECK4
          SA7    RN          CLEAR RECORD NUMBER                         DECK4
          =X1    0                                                       DECK4
                                                                         DECK4
 EOF      SUBR   0           ENTRY/EXIT 
          SX1    =C*  *                                                  DECK4
          RJ     WOF                                                     DECK4
          SA1    FE                                                      DECK4
          PL     X1,EOF2     IF NO FUNNY EOF                             DECK4
 #RM      IFEQ   CP#RM,0
          SA2    RN                                                      DECK4
          =X7    1                                                       DECK4
          SA7    A1          CLEAR EOF WITH DATA FLAG                    DECK4
          SX1    =C*  EOF WITH DATA*                                     DECK4
          RJ     WOF                                                     DECK4
 #RM      ELSE
          SX7    1
          SA7    A1          CLEAR EOF WITH DATA FLAG 
 #RM      ENDIF 
                                                                         DECK4
 EOF2     SA1    RN          CONVERT RECORD NUMBER                       DECK4
          RJ     CDD                                                     DECK4
          LX6    18                                                      DECK4
          SA6    SBUF                                                    DECK4
          SA1    =7H* EOF *                                              DECK4
          SA2    =6ASUM =                                                DECK4
          BX6    X1                                                      DECK4
          LX7    X2                                                      DECK4
          SA6    A6+B1                                                   DECK4
          SA7    A6+B1                                                   DECK4
          SA1    RL+2        CONVERT FILE LENGTH                         DECK4
          SA2    A1+B1                                                   DECK4
          IX6    X2+X1       ACCUMULATE TOTAL LENGTH                     DECK4
          SA6    A2                                                      DECK4
          RJ     COD                                                     DECK4
          MX7    0                                                       DECK4
          SA6    A7+B1                                                   DECK4
          SA7    A6+B1                                                   DECK4
          SA7    PPBUF
          SA7    UL+1        CLEAR USER LIBRARY FLAG
                                                                         DECK4
          SA1    F                                                       DECK4
                                                                         DECK4
 #RM      IFEQ   CP#RM,0
  
          LX1    59-9 
          PL     X1,EOF8     IF NOT END OF INFORMATION
  
 #RM      ELSE
                                                                         DECK4
          FETCH  X1,FP,X2                                                DECK4
          LX1    X2,B1                                                   DECK4
          SX2    X2-#EOI# 
          NZ     X2,EOF8     IF NOT END OF INFORMATION
                                                                         DECK4
 #RM      ENDIF                                                          DECK4
                                                                         DECK4
                                                                         DECK4
          SX1    =2L                                                     DECK4
          RJ     WOF                                                     DECK4
                                                                         DECK4
          SA3    =1H                                                     DECK4
          SA2    =7H* EOI *                                              DECK4
          SA1    RL+3                                                    DECK4
          LX7    X3                                                      DECK4
          BX6    X2                                                      DECK4
          SA7    SBUF                                                    DECK4
          =A6    A7+1                                                    DECK4
          RJ     COD         CONVERT TOTAL LENGTH                        DECK4
          SX1    A7                                                      DECK4
          SA6    SBUF+3                                                  DECK4
          RJ     WOF                                                     DECK4
          MX1    -1          INDICATE E-O-I                              DECK4
          EQ     EOF         EXIT..                                      DECK4
 LRS      SPACE  4,8
**        LRS - LIST RECORD STATUS.                                      DECK4
* 
*         ENTRY  (BUF) = FIRST BLOCK OF RECORD.                          DECK4
*                (NM) = RECORD NAME.                                     DECK4
*                (TY) = RECORD TYPE.                                     DECK4
*                (RN) = RECORD NUMBER.                                   DECK4
*                (RL) = RECORD LENGTH.                                   DECK4
*                (CS) = CHECK SUM.                                       DECK4
* 
*         USES   ALL REGISTERS.                                          DECK4
* 
*         CALLS  CDD, COD, SFN, WOF.                                     DECK4
                                                                         DECK4
                                                                         DECK4
 LRS      SUBR   0           ENTRY/EXIT                                  DECK4
          SA1    RN          CONVERT RECORD NUMBER                       DECK4
          RJ     CDD                                                     DECK4
          LX6    18                                                      DECK4
          SA6    SBUF                                                    DECK4
          SA1    RL          CHECK RECORD LENGTH                         DECK4
          NZ     X1,LRS1     IF NOT ZERO RECORD                          DECK4
          SA1    =4H(00)     ENTER ZERO RECORD                           DECK4
          SA2    =6ASUM =                                                DECK4
          BX6    X1                                                      DECK4
          LX7    X2                                                      DECK4
          SA6    A6+B1                                                   DECK4
          SA7    A6+B1                                                   DECK4
          SA1    RL+1        ENTER SUBTOTAL                              DECK4
          RJ     COD                                                     DECK4
          LX6    12                                                      DECK4
          SA6    A7+B1                                                   DECK4
          MX7    0           CLEAR SUBTOTAL                              DECK4
          SA7    A6+B1                                                   DECK4
          SA7    A1                                                      DECK4
          SX1    SBUF                                                    DECK4
          RJ     WOF                                                     DECK4
          SX1    =C*  *                                                  DECK4
          RJ     WOF                                                     DECK4
          EQ     LRS         RETURN                                      DECK4
                                                                         DECK4
 LRS1     SA1    NM          SPACE FILL NAME                             DECK4
          RJ     SFN                                                     DECK4
          SA6    A6+B1                                                   DECK4
          SA1    TY          SET TYPE                                    DECK4
          SB7    X1                                                      DECK4
          SA2    LRSA+X1                                                 DECK4
          BX6    X2                                                      DECK4
          SA6    A6+B1                                                   DECK4
          SA1    RL          CONVERT LENGTH                              DECK4
          RJ     COD                                                     DECK4
          SA6    A6+B1                                                   DECK4
                                                                         DECK4
*         PROCESS CHECKSUM.                                              DECK4
                                                                         DECK4
          SA2    CS          FOLD CHECKSUM                               DECK4
          MX3    60-12                                                   DECK4
          BX1    -X3*X2                                                  DECK4
          AX2    12                                                      DECK4
          BX6    -X3*X2                                                  DECK4
          IX1    X1+X6                                                   DECK4
          AX2    12                                                      DECK4
          BX6    -X3*X2                                                  DECK4
          IX1    X1+X6                                                   DECK4
          AX2    12                                                      DECK4
          BX6    -X3*X2                                                  DECK4
          IX1    X1+X6                                                   DECK4
          AX2    12                                                      DECK4
          BX6    -X3*X2                                                  DECK4
          IX1    X1+X6                                                   DECK4
          IX7    X1+X3                                                   DECK4
          BX4    -X3*X7                                                  DECK4
          SX1    X4+10000B                                               DECK4
          RJ     COD                                                     DECK4
          SX2    1R -1R1                                                 DECK4
          LX2    4*CHAR                                                  DECK4
          IX6    X6+X2                                                   DECK4
          LX6    2*CHAR 
          SA6    A6+B1                                                   DECK4
                                                                         DECK4
*         COPY 7700 TABLE.                                               DECK4
                                                                         DECK4
          SA1    BUF                                                     DECK4
          LX1    18                                                      DECK4
          SB2    X1-770000B                                              DECK4
          SB3    B0                                                      DECK4
          NZ     B2,LRS3     IF NO 7700 TABLE                            DECK4
          LX1    6                                                       DECK4
          SB3    X1+B1                                                   DECK4
          SB4    B1+B1                                                   DECK4
          LE     B3,B4,LRS3  IF TOO SHORT TO COPY                        DECK4
          SB2    B4+6                                                    DECK4
          SA1    A1+B4                                                   DECK4
 LRS2     BX6    X1                                                      DECK4
          SA6    A6+B1
          MX0    30 
          SB4    10B         WAS 7
          SA3    FW 
          PL     X3,LRS3     IF NOT FULL WIDTH SPECIFIED
          SA1    A1+6        (+10B) BEGINNING OF COMMENT
          ZR     X1,LRS3     IF ALSO END OF COMMENT 
          SA2    =10HCOPYRIGHT
  
 LRS2.3   BX6    X1-X2
          ZR     X6,LRS3     IF *COPYRIGHT* 
          BX6    X1 
          SA6    A6+B1                                                   DECK4
          SB4    B4+B1                                                   DECK4
          SA1    A1+B1                                                   DECK4
          ZR     X1,LRS3     IF END OF DATA                              DECK4
          GE     B4,B3,LRS3  IF END OF 77-TABLE                          DECK4
          EQ     LRS2.3 
                                                                         DECK4
 LRS3     MX6    0           INSURE LINE TERMINATOR                      DECK4
          SA1    B7+RTJV
          SA6    A6+B1
          AX1    30 
          SB2    X1 
          RJ     MPC
          JP     B2          PROCESS TYPE 
                                                                         DECK4
 LRS4     SX1    SBUF                                                    DECK4
          RJ     WOF                                                     DECK4
          SA2    LRSD                                                    DECK4
          SA3    =1H                                                     DECK4
          ZR     X2,LRS      IF NO LONG LINE, EXIT..                     DECK4
          MX7    0                                                       DECK4
          BX6    X3                                                      DECK4
          SA7    A2                                                      DECK4
          SA6    SBUF                                                    DECK4
          DUP    4,1                                                     DECK4
          =A6    A6+1                                                    DECK4
          SA1    X2+BUF                                                  DECK4
          SB4    X2                                                      DECK4
          SB2    X2+7                                                    DECK4
          SB7    B0                                                      DECK4
          SB3    B2                                                      DECK4
          EQ     LRS2        FINISH LISTING LINE                         DECK4
                                                                         DECK4
 LRS5     SA1    LC          CHECK LINE COUNT                            DECK4
          SA3    LL 
          SX7    X3-6 
          IX7    X1-X7
          MI     X7,LRS4     IF NOT ROOM FOR 2 LINES                     DECK4
          SX6    X3          FORCE EJECT
          SA6    A1                                                      DECK4
          EQ     LRS4                                                    DECK4
                                                                         DECK4
*         PROCESS PP LOAD ADDRESS.                                       DECK4
                                                                         DECK4
 LRS6     SA2    NM 
          LX2    3*CHAR 
          SB2    X2-3RDSD 
          NZ     B2,LRS6A    IF NOT *DSD* PPU ROUTINE 
          =X7    2           NEXT *2* RECORDS OF TYPE *COS* SPECIAL 
          SA7    DS          INDICATE PROCESSING *DEADSTART TAPE* 
 LRS6A    SA2    BUF+B3      FWA OF PROGRAM 
          SX3    10000B                                                  DECK4
          AX2    24          SET LOAD ADDRESS                            DECK4
          SX4    X2                                                      DECK4
          SA5    LRSA+B7                                                 DECK4
          ZR     X4,LRS7     IF LOCATION FREE                            DECK4
          SX4    X4+5                                                    DECK4
 LRS7     IX1    X4+X3       CONVERT LOAD ADDRESS                        DECK4
          MX0    -4*CHAR                                                 DECK4
          RJ     COD                                                     DECK4
          BX3    -X0*X6      MERGE WITH TYPE                             DECK4
          LX3    CHAR                                                    DECK4
          BX6    X5+X3                                                   DECK4
          SA6    SBUF+2                                                  DECK4
          EQ     LRS4        LIST LINE                                   DECK4
                                                                         DECK4
*         PROCESS OVERLAY LEVEL NUMBERS.                                 DECK4
                                                                         DECK4
 LRS8     SA2    BUF+B3      FETCH FIRST WORD ABTER 7700 TABLE
          MX0    -12
          BX1    X2 
          LX1    12          EXTRACT TABLE TYPE 
          BX1    -X0*X1 
          SB2    X1-7000B 
          NZ     B2,LRS8A    IF NOT 7000 (LDSET) TABLE
          LX2    -36
          BX2    -X0*X2 
          SB2    X2+B1
          SA2    A2+B2       SKIP LDSET TABLE 
 LRS8A    LX2    24 
          MX0    60-12                                                   DECK4
          SX1    X2+10000B   CONVERT LEVEL NUMBERS                       DECK4
          RJ     COD                                                     DECK4
          SA1    LRSA+B7     MERGE LEVEL AND TYPE                        DECK4
          BX2    -X0*X6                                                  DECK4
          LX2    6                                                       DECK4
          IX1    X1+X2                                                   DECK4
          AX6    12                                                      DECK4
          BX2    -X0*X6                                                  DECK4
          LX2    24                                                      DECK4
          IX6    X1+X2                                                   DECK4
          SA6    SBUF+2                                                  DECK4
          EQ     LRS4        LIST LINE                                   DECK4
  
*         CHECK FOR SPECIAL *DEADSTART RECORDS*.
  
 LRS9     SA3    DS 
          ZR     X3,LRS4     IF NOT SPECIAL DEADSTART RECORD
          RJ     LDT         PROCESS LIBRARY DIRECTORY TABLE
          NZ     B2,LRS4     IF LINE NOT PROCESSED
          EQ     LRS         EXIT 
                                                                         DECK4
*         PROCESS PPU NUMBER.                                            DECK4
                                                                         DECK4
 LRS10    SA2    BUF+B3      FIRST WORD OF PROGRAM                       DECK4
          LX2    24                                                      DECK4
          SB6    X2-100B                                                 DECK4
          SA5    LRSA+B7                                                 DECK4
          MI     B6,LRS11    IF PPU @ 77                                 DECK4
          SA5    LRSC                                                    DECK4
 LRS11    SX1    X2+10000B   CONVERT PPU NUMBER                          DECK4
          RJ     COD         CONVERT TO OCTAL 
          LX6    6                                                       DECK4
          PL     B6,LRS12    IF PPU > 77                                 DECK4
          LX6    12                                                      DECK4
 LRS12    IX6    X6+X5                                                   DECK4
          SA6    SBUF+2                                                  DECK4
          EQ     LRS4        LIST LINE                                   DECK4
                                                                         DECK4
 LRS14    SA1    BUF         GET UPDATE CONTROL CHARACTER                DECK4
          SA2    LRSA+B7                                                 DECK4
          MX0    -6                                                      DECK4
          BX3    -X0*X1                                                  DECK4
          LX3    6*6                                                     DECK4
          IX6    X3+X2                                                   DECK4
          SA6    SBUF+2                                                  DECK4
          EQ     LRS4                                                    DECK4
  
*         PROCESS 180 PP LOAD ADDRESS.
  
 LRS20    SA2    BUF+B3      PPU HEADER WORD
          MX1    -16         EXTRACT LOAD ADDRESS 
          AX2    16 
          SX3    100000B     CONVERT LOAD ADDRESS WITH LEADING ZEROS
          BX1    -X1*X2 
          MX0    -5*CHAR
          IX1    X1+X3
          RJ     COD         CONVERT TO OCTAL DISPLAY 
          BX3    -X0*X6 
          SA5    LRSA+B7     MERGE WITH TYPE
          BX6    X5+X3
          SA6    SBUF+2 
          SA1    A6+B1       ) IN UPPER CHAR OF WORD WITH LENGTH
          MX0    CHAR 
          BX6    -X0*X1 
          SX2    1R)
          LX2    -CHAR
          BX6    X6+X2
          SA6    A1 
          EQ     LRS4        GO LIST LINE 
          SPACE  1
 TYPE     SPACE  4,8
**        TYPE - GENERATE RECORD TYPE JUMP VECTOR ENTRY.
* 
*         ENTRY  *TYPES* = RECORD TYPE NAME.
*                *LISTPROC* = JUMP ADDRESS FOR *LRS* PROCESSING.
*                *CONTPROC = JUMP ADDRESS FOR *CAT* PROCESSING. 
* 
*         EXIT   *O.TYPS* SYMBOL DEFINED = COMQSRT DEFINITION.
*                JUMP VECTOR WORD GENERATED.
  
  
  
          MACRO  TYPE,RECTYP,LIST,CONT
 O.RECTYP EQU    *
          VFD    30/LIST,30/CONT
          ENDM
  
  
*         JUMP TABLE FOR *LRS* AND *CAT*.                                UTLA039
  
  
 RTJV     BSS    0           RECORD TYPE JUMP VECTOR
          LOC    0
 TEXT     TYPE   LRS9,TXT 
 6PP      TYPE   LRS6,CAT1
 OVCAP    TYPE   LRS5,CAP 
 REL      TYPE   LRS5,REL 
 OVL      TYPE   LRS8,CAT1
 ULIB     TYPE   LRS4,ULB 
 OPL      TYPE   LRS5,OPL 
 OPLC     TYPE   LRS5,OPL 
 OPLD     TYPE   LRS4,CAT1
 ABS      TYPE   LRS5,ABS 
 7PP      TYPE   LRS10,CAT1 
 UPL      TYPE   LRS14,UPL
 UCF      TYPE   LRS4,CAT1
 ACF      TYPE   LRS4,CAT1
 CAP      TYPE   LRS5,CAP 
 DATA     TYPE   LRS4,TXT 
 PROC     TYPE   LRS4,CAT1
 RES      TYPE   LRS4,CAT1
 SDR      TYPE   LRS,SDR
 UPLR     TYPE   LRS4,CAT1
 UPLRC    TYPE   LRS4,CAT1
 8PP      TYPE   LRS20,CAT1 
          LOC    *O 
  
                                                                         DECK4
 LRSA     BSS    0                                                       DECK4
          LOC    0                                                       DECK4
          DIS    1,TEXT                                                  DECK4
          CON    5L6PP (+1R)                                             DECK4
          DIS    1,OVCAP
          DIS    1,REL                                                   DECK4
          VFD    24/4LOVL ,12/0,6/1L,,12/0,6/1L                          DECK4
          DIS    1,ULIB                                                  DECK4
          DIS    1,OPL                                                   DECK4
          DIS    1,OPLC                                                  DECK4
          DIS    1,OPLD                                                  DECK4
          DIS    1,ABS                                                   DECK4
          CON    8H7PP (  )-8A100                                        DECK4
          CON    3LUPL+6R                                                DECK4
          DIS    1,UCF                                                   DECK4
          DIS    1,ACF                                                   DECK4
          DIS    1,CAP
          DIS    1,DATA 
          DIS    1,PROC 
          DIS    1,-ERR-
          DIS    1,SDR
          DIS    1,UPLR 
          DIS    1,UPLRC
          CON    5L8PP (
          LOC    *O                                                      DECK4
                                                                         DECK4
                                                                         DECK4
 LRSC     CON    10HPPU (    )-6A1                                       DECK4
                                                                         DECK4
 LRSD     CON    0                                                       DECK4
 REC      TITLE  RECORD TYPE PROCESSORS 
 ABS      SPACE  4,8
**        ABS - PROCESS ABS ENTRY POINTS.                                DECK4
*                                                                        UTLA039
*         LISTS THE ENTRIES OF EASCM(5100) AND EACPM(5400) TABLES.       UTLA039
*                                                                        UTLA039
*         CALLS  WOF,SFN.                                                UTLA039
                                                                         DECK4
                                                                         DECK4
 ABS      SA1    BUF         CHECK FIRST WORD                            DECK4
          LX1    18                                                      DECK4
          MX2    60-12                                                   DECK4
          SX6    X1-770000B                                              DECK4
          NZ     X6,CAT1     RETURN IF NO 7700 TABLE                     DECK4
          SA4    A1+B1       DECK NAME
          LX1    6           SKIP 7700 TABLE                             DECK4
          SB2    X1+B1                                                   DECK4
          SA1    A1+B2                                                   DECK4
          LX1    12                                                      DECK4
          BX3    -X2*X1                                                  DECK4
          SX6    X3-5100B                                                DECK4
          NZ     X6,ABS2     IF NO 5100 TABLE 
          LX1    60-12       SET ENTRY COUNT                             DECK4
          SX0    X1                                                      DECK4
          ZR     X0,CAT1     IF NO ENTRIES                               DECK4
          SA5    A1+B1       FIRST ENTRY                                 DECK4
 ABS1A    SA2    =1H         CLEAR SCRATCH BUFFER 
          BX6    X2                                                      DECK4
          MX7    0                                                       DECK4
          SA6    SBUF                                                    DECK4
          SA7    SBUF+3 
 ABS1     MX2    42          SPACE FILL NAME                             DECK4
          BX1    X2*X5                                                   DECK4
          RJ     SFN                                                     DECK4
          LX6    60-6                                                    DECK4
          SA6    SBUF+1                                                  DECK4
          BX1    -X2*X5      ENTRY POINT ADDRESS
          RJ     COD
          LX6    18          POSITION 
          SA6    A6+B1
          SX1    SBUF        LIST ENTRY                                  DECK4
          RJ     WOF                                                     DECK4
          SA5    A5+B1       NEXT ENTRY                                  DECK4
          SX0    X0-1                                                    DECK4
          NZ     X0,ABS1     LOOP FOR ALL ENTRYS                         DECK4
          EQ     CAT1        RETURN                                      DECK4
 ABS2     SX6    X3-5400B 
          NZ     X6,CAT1     RETURN IF NOT 5400 TABLE 
          SA5    A1+8        FIRST ENTRY
          LX1    60-12       SET ENTRY COUNT
          SX0    X1 
          EQ     ABS1A       ELSE PROCESS ENTRIES 
 LDT      SPACE  4,8
**        LDT - PROCESS LIBRARY DIRECTORY TABLE.
* 
*         CHECKS FOR SPECIAL DEADSTART RECORDS CONTAINING LIBRARY NAME
*         TABLE AND PPU NAME TABLE. 
* 
*         IF *LIBNT*, *LDT* BUILDS TABLE *DS.FD* OF ALL LIBRARY NAMES 
*         FOR USE AS HEADERS FOR SUCCESSIVE FILES AND IF *E* OPTION 
*         IS SELECTED IT LISTS ALL LIBRARY NAMES WITH THIS RECORD        UTLA039
*         LISTING.                                                       UTLA039
* 
*         IF *PPNT* - A CHANGE FROM TYPE *TEXT* TO TYPE *PPNT* IS 
*         MADE AND EXIT.
* 
*         ENTRY  (X3) = DS. 
* 
*         EXIT   (B2) = 0, LINE PROCESSED.
* 
*         USES   ALL REGISTERS. 
* 
*         CALLS  LEP, WOF.
  
  
 LDT50    SX6    0
          SA6    DS          INDICATE NOT NOS/BE DEADSTART TAPE 
  
 LDT      SUBR   0           ENTRY/EXIT 
          SA1    X3+LDTA-1
          SA4    BUF
          BX6    X1 
          LX4    18 
          SX7    X3-1 
          SB2    X4-3RNUC 
          ZR     X7,LDT3     IF NOT FIRST LIBRARY RECORD
          NZ     B2,LDT50    IF NOT *NUCLEUS* AS FIRST LIBRARY
 LDT3     SA6    SBUF+2      RESET TYPE 
          SA1    X3+LDTB-1
          LX0    X7 
          SA7    A3          RESET RECORDS PROCESSED
          BX7    X1 
          MX6    0
          SX1    SBUF 
          SA4    =10HNOS/BE 
          SA7    SBUF+5 
          SX2    7
          =A6    A7+1        END OF LINE TERMINATOR 
          BX6    X4 
          SA6    SBUF+1      REPLACE NAME OF ROUTINE
          RJ     WOF         OUTPUT INITIAL LINE
          NZ     X0,LDT8     IF NOT *PPNT* ENTRY
          RJ     CPB         COMPRESS PPNT BITS 
  
*         OUTPUT TITLE LINES. 
  
          SA2    PPL
          BX6    X2 
          SA6    FI 
          RJ     WHL         WRITE HEADER LINES.
          =B2    0
          EQ     LDTX        RETURN 
  
*         TRANSFER LIBRARY NAMES TO FILE DESCRIPTOR TABLE.
  
 LDT8     SA3    RL 
          SB4    BUF-5
          =B6    0
          SB3    X3+BUF-5 
  
 LDT10    SA2    B4+5        NEXT LIBRARY NAME
          MX3    7*CHAR 
          BX1    X3*X2
          RJ     SFN         SPACE FILL THE NAME
          SA6    B6+DS.FD 
          SB4    B4+5 
          =B6    B6+1 
          LT     B4,B3,LDT10 IF NOT END OF LIBRARY NAMES
          =X6 
          =A6    A6+1        END OF LIBRARY NAME TABLE
          SA4    LE 
          SX0    A6-DS.FD+1 
          ZR     X4,LDT11    IF ENTRY POINT NOT REQUESTED 
          SA5    DS.FD       FWA OF TABLE 
          =B2    1           INCREMENT TO *LEP* 
          MX6    7*CHAR 
          RJ     LEP         LIST LIBRARY TABLE 
 LDT11    SA3    =10HLIBRARY
          SA4    =10H 
          BX6    X3 
          =B2    0           INDICATE LINE PROCESSED
          LX7    X4 
          SA6    FI-1        RESET TITLE LINE 
          =A7    A6+1 
          =A7    A7+1 
          EQ     LDTX        EXIT 
  
 LDTA     BSS    0
          DATA   10HPPNT
          DATA   10HLIBNT 
  
 LDTB     BSS    0
          DATA   10H
          DATA   10HLIBRARIES 
 OPL      SPACE  4,8
**        OPL - PROCESS OPL LIST.                                        DECK4
*                                                                        UTLA039
*         CHECKS FOR *PRFX* (7700) TABLE AND IF THERE ARE MODIFIERS TO
*         BE LISTED,CALLS *LEP* TO LIST THEM. 
* 
*         CALLS  LEP
                                                                         DECK4
                                                                         DECK4
 OPL      SA1    BUF         CHECK FIRST WORD                            DECK4
          LX1    18                                                      DECK4
          SB2    X1-770000B                                              DECK4
          NZ     B2,CAT1     RETURN IF NO 7700 TABLE                     DECK4
          LX1    6           SKIP 7700 TABLE                             DECK4
          SB2    X1+B1                                                   DECK4
          SA1    A1+B2                                                   DECK4
          SA2    LE 
          SB2    B1          (B2) = NUMBER OF WORDS IN EACH TABLE ENTRY 
          SX0    X1          (X0) = NUMBER OF MODIFIERS 
          ZR     X0,CAT1     RETURN IF NO MODIFIERS 
          ZR     X2,CAT1     IF E OPTION NOT SET
          SA5    A1+B1       (A5) = FWA OF MODIFIERS
          MX6    42          SET NAME MASK
          RJ     LEP         LIST ENTRY POINTS
          EQ     CAT1 
 RDR      SPACE  4,8
**        RDR - READ RECORD.                                             DECK4
*                                                                        DECK4
*         EXIT   (X1) = -1 IF EOF.                                       DECK4
*                (CS) = CHECK SUM.                                       DECK4
*                (FE) = EOF WITH DATA FLAG.                              DECK4
*                (NM) = RECORD NAME.                                     DECK4
*                (RL) = RECORD LENGTH.                                   DECK4
*                (TY) = RECORD TYPE.                                     DECK4
                                                                         DECK4
                                                                         DECK4
 RDR      SUBR   0           ENTRY/EXIT                                  DECK4
 #RM      IFEQ   CP#RM,0,2
          SA1    FE                                                      DECK4
          MI     X1,RDRX     IF PREVIOUS EOF WITH DATA                   DECK4
          READW  F,BUF,BUFL                                              DECK4
          BX6    X1 
          PL     X1,RDR0     IF NOT EOF/EOI 
          SB7    B6-BUF 
          ZR     B7,RDRX     IF EOF/EOI AND NO DATA 
          SA6    FE          FLAG FUNNY EOF/EOI 
          SX1    B6          FAKE EOR 
 RDR0     SA6    RDRA        SAVE STATUS
          SX2    BUF         SET RECORD TYPE                             DECK4
          NZ     X1,RDR0.1   IF END OF RECORD IN BUFFER 
          SX1    X2+BUFL     PASS LWA+1 OF BUFFER TO SRT
 RDR0.1   BSS    0
          RJ     SRT                                                     DECK4
          SA6    TY          SET TYPE                                    DECK4
          SA7    NM          SET NAME                                    DECK4
          SA1    =60606060606060606060B                                  DECK4
          SA3    =20202020202020202020B                                  DECK4
          BX2    X1*X7       ISOLATE HI TWO BITS OF EACH CHAR            DECK4
          IX2    X2+X3       FORCE CARRY FROM ALL NON-DISPLAYABLES       DECK4
          LX3    2           =01010101010101010101B                      DECK4
          BX3    X3*X2       ISOLATE CARRY BITS                          DECK4
          LX3    -1          SHIFT BACK TO HI-ORDER OF ORIGINAL FIELDS   DECK4
          BX1    -X3*X7 
          RJ     SFN         SPACE FILL NAME
          LX6    -CHAR
          MX7    8*CHAR 
          BX6    X6*X7       TERMINATE MESSAGE WITH ZERO BYTE 
          SA6    RDRB+1 
          SX1    A6-B1
          MESSAGE  X1,CONSOLE                                            DECK4
          SA1    RDRA                                                    DECK4
          SB2    BUFL                                                    DECK4
          SB3    BUF                                                     DECK4
          ZR     X1,RDR1     IF NOT EOR                                  DECK4
          SB2    B6-BUF 
          ZR     B2,RDRX     RETURN IF ZERO LENGTH RECORD                DECK4
                                                                         DECK4
 RDR1     SA2    TY          CHECK RECORD TYPE
          SB4    X2 
          ZR     B4,RDR2     IF TEXT TYPE RECORD, NO 77 TABLE 
          SA2    B3 
          LX2    18                                                      DECK4
          SX6    X2-770000B                                              DECK4
          NZ     X6,RDR2     IF NO 7700 TABLE                            DECK4
          LX2    6           SKIP 7700 TABLE                             DECK4
          SB4    X2+B1                                                   DECK4
          SB3    B3+B4                                                   DECK4
          SB2    B2-B4                                                   DECK4
                                                                         DECK4
 RDR2     SA2    RL          ADVANCE RECORD LENGTH                       DECK4
          SA3    CS          ADVANCE CHECKSUM                            DECK4
          SX7    B2                                                      DECK4
          SA4    B3                                                      DECK4
          BX6    X3                                                      DECK4
          IX7    X2+X7                                                   DECK4
          LE     B2,B0,RDR4  IF NO DATA BEYOND 7700 TABLE 
 RDR3     BX6    X6-X4                                                   DECK4
          SB2    B2-B1                                                   DECK4
          SA4    A4+B1                                                   DECK4
          LX6    1                                                       DECK4
          NZ     B2,RDR3                                                 DECK4
 RDR4     SA6    A3 
          SA7    A2                                                      DECK4
          NZ     X1,RDRX     RETURN IF EOR                               DECK4
          READW  F,SBUF,SBUFL                                            DECK4
          SB2    SBUFL                                                   DECK4
          SB3    SBUF                                                    DECK4
          ZR     X1,RDR2     IF NOT EOR                                  DECK4
          SB2    X1-SBUF                                                 DECK4
          GT     B2,RDR2     IF NOT EMPTY BUFFER                         DECK4
          PL     X1,RDRX     IF NOT END OF FILE                          DECK4
          BX6    X1                                                      DECK4
          SA6    FE          FLAG EOF WITH DATA                          DECK4
          SX1    SBUF                                                    DECK4
          EQ     RDRX        EXIT..                                      DECK4
                                                                         DECK4
 RDRA     CON    0                                                       DECK4
 RDRB     DIS    1, ITEMIZING                                            DECK4
          CON    0                                                       DECK4
 REL      SPACE  4,8                                                     DECK4
**        REL - PROCESS RELOCATABLE LIST. 
*                                                                        UTLA039
*         CHECKS FOR PREFIX(7700), LDSET(7000), AND PIDL(3400) TABLES.   UTLA039
*         IF THESE ARE ALL PRESENT THEN THE ENTRY POINTS OF THE          UTLA039
*         ENTR(3600) TABLE ARE LISTED.                                   UTLA039
                                                                         DECK4
                                                                         DECK4
 REL      SA1    LE                                                      DECK4
          ZR     X1,CAT1     RETURN IF NO ENTRY POINT LIST DESIRED       DECK4
          SA1    BUF         CHECK FIRST WORD                            DECK4
          LX1    18                                                      DECK4
          SB2    X1-770000B                                              DECK4
          NZ     B2,CAT1     RETURN IF NO 7700 TABLE                     DECK4
          LX1    6           SKIP 7700 TABLE                             DECK4
          SB2    X1+B1                                                   DECK4
          SA1    A1+B2                                                   DECK4
          LX1    12                                                      DECK4
          SB2    X1-7000B                                                DECK4
          NZ     B2,REL2     IF NO 7000 TABLE (LDSET)                    DECK4
          LX1    12                                                      DECK4
          =B2    X1+1                                                    DECK4
          SA1    A1+B2       SKIP LDSET TABLE                            DECK4
          LX1    12                                                      DECK4
 REL2     SB2    X1-3400B                                                DECK4
          NZ     B2,CAT1     RETURN IF NO 3400 TABLE                     DECK4
          LX1    12          SKIP 3400 TABLE                             DECK4
          SB2    X1+B1                                                   DECK4
          SA1    A1+B2                                                   DECK4
          LX1    12                                                      DECK4
          SB2    X1-3600B                                                DECK4
          NZ     B2,CAT1     RETURN IF NO 3600 TABLE                     DECK4
          LX1    12                                                      DECK4
          SX0    X1          WORD COUNT                                  DECK4
          SA5    A1+B1       FIRST ENTRY POINT                           DECK4
          MX7    0                                                       DECK4
                                                                         DECK4
 REL4     =B2    2           ENTRY POINT INCREMENT                       DECK4
          AX0    1           DIVIDE BY *2*                               DECK4
          MX6    7*CHAR 
          RJ     LEP         LIST ENTRY POINTS                           DECK4
          EQ     CAT1        RETURN                                      DECK4
 SDR      SPACE  4,8
**        SDR - SPECIAL DEADSTART RECORD. 
*                                                                        UTLA039
*         IF THE RECORD BEING PROCESSED IS A NOS/BE SPECIAL DEADSTART    UTLA039
*         RECORD, THE NAME LISTED IS *CMRDC*.                            UTLA039
*                                                                        UTLA039
*         CALLS  WOF.                                                    UTLA039
  
  
 T.CMR    EQU    32B
  
  
 SDR      SA1    BUF
          SX2    50B
          LX1    CHAR 
          SB7    SBUF+10
          IX6    X2-X1
          NZ     X6,SDR10    IF NOT CMR 
          SA3    =5HCMRDC    USE FOR FILE NAME IN ITEMIZE OUTPUT         UTLA031
          LX6    X3 
          SA6    SBUF+1      RESET NAME TO CMRDECK
          SB2    SBUF+5 
          SB4    A1+T.CMR 
 SDR5     SA2    B4          CMR DESCRIPTION
          BX6    X2 
          SB4    B4+B1
          SA6    B2 
          SB2    B2+B1
          SB7    A6 
          NZ     X2,SDR5     IF ANOTHER WORD OF DESCRIPTION 
 SDR10    SX2    B7 
          SX1    SBUF 
          RJ     WOF         WRITE LINE TO OUTPUT 
          EQ     CAT1        RETURN 
 TXT      SPACE  4,8
**        TXT - PROCESS TEXT LIST.                                       DECK4
*                                                                        UTLA039
*         LISTS THE TEXT RECORD IF IT MATCHES A PATTERN IN *TXTA*.
*         FOR *OVERLAY*, ONLY THE FIRST LINE IS LISTED. 
*                                                                        UTLA039
*         CALLS  WOF.                                                    UTLA039
                                                                         DECK4
                                                                         DECK4
 TXT      SA1    NM 
          SA2    TXTA        SET TABLE
          MX4    1
          SB3    X2 
          MX0    42 
          BX6    X0*X2
 TXT1     AX3    X4,B3       SET MASK 
          BX7    X1-X6
          BX6    X3*X7
          SA2    A2+B1
          ZR     X6,TXT2     IF MATCH ON NAME 
          ZR     X2,CAT1     IF END OF TABLE
          SB3    X2 
          BX6    X0*X2
          EQ     TXT1        LOOP 
  
 TXT2     SB3    B3-24+1
          NZ     B3,TXT2.1   IF NOT 24 BITS (NOT XXXXNN)
          MX0    36 
          BX6    X0*X1
          BX6    X6-X1
          MX0    -12
          NZ     X6,CAT1     IF NOT 6 CHARACTERS (XXXXNN) 
          LX1    36 
          BX1    -X0*X1 
          ZR     X1,TXT2.1   IF NO RECORD NAME SUFFIX (XXXX ONLY) 
          SX1    X1-2R00
          NG     X1,CAT1     IF NON-NUMERIC 
          SX1    X1-2R99+2R00-1 
          PL     X1,CAT1     IF NON-NUMERIC 
 TXT2.1   SA0    BUF
          SX6    A2-TXTA1-1  SET OVERLAY FLAG 
          SA6    TXTB 
          SA1    =1H
          BX6    X1 
          SB2    B0 
          SA6    SBUF 
          MX0    -12
          SA6    A6+B1
          SA5    RL 
 TXT3     SX5    X5-1 
          NG     X5,TXT4     IF END OF COPY 
          SA1    A0          MOVE WORD
          LX6    X1 
          SA6    SBUF+2+B2
          SA0    A0+B1
          BX7    -X0*X1 
          SB2    B2+1 
          NZ     X7,TXT3     LOOP TO  END OF LINE 
          BX7    X5 
          SX1    SBUF        LIST LINE
          SA7    TXTC        SAVE RECORD LENGTH ACROSS PRINT
          RJ     WOF
          SA2    TXTB 
          SA5    TXTC 
          ZR     X2,CAT1     IF *OVERLAY* RECORD
          SB2    B0+
          EQ     TXT3        LOOP 
  
 TXT4     SX1    =C*  * 
          RJ     WOF
          EQ     CAT1        RETURN 
  
  
****      TABLE OF SPECIAL *TEXT* RECORD NAMES. 
* 
*         ENTRY FORMAT -
* 
*         42/ SPECIAL RECORD NAME SKELETON, 18/ BITS-1 IN MASK
* 
*         TABLE IS TERMINATED BY A ZERO WORD. 
  
  
 TXTA     BSS    0
  
*         DEADSTART TEXT DECK PATTERNS. 
  
          VFD    42/0LAPRD,18/24-1
          VFD    42/0LAPR0,18/24-1
          VFD    42/0LCMRD,18/24-1
          VFD    42/0LDDSDC,18/30-1 
          VFD    42/0LDDSDECK,18/42-1 
          VFD    42/0LEQPD,18/24-1
          VFD    42/0LIPRD,18/24-1
          VFD    42/0LLIBD,18/24-1
*         MISCELLANEOUS PATTERNS. 
          VFD    42/0LCOMMENT,18/42-1 
 TXTA1    VFD    42/0LOVERLAY,18/42-1  (ONLY FIRST LINE LISTED) 
          CON    0           END OF TABLE 
***** 
  
 TXTB     CON    0
 TXTC     DATA   0
 ULB      SPACE  4,8                                                     DECK4
*         ULB - PROCESS USER LIBRARY.                                    UTLA039
                                                                         DECK4
                                                                         DECK4
 ULB      SA1    UL                                                      DECK4
          NZ     X1,CAT1     RETURN IF USER LIBRARY LIST                 DECK4
          SX6    B1          SET NO LIST                                 DECK4
          SA6    A1+B1                                                   DECK4
          EQ     CAT1        RETURN                                      DECK4
 UPL      SPACE  4,8                                                     DECK4
**        UPL - PROCESS UPDATE PROGRAM LIBRARY.                          DECK4
*                                                                        UTLA039
*         IF AN EXPANDED LIST IS REQUESTED THEN THE CORRECTION HISTORY   UTLA039
*         IS LISTED, ELSE JUST THE DECKS ARE LISTED FROM AN UPDATE       UTLA039
*         LIBRARY.                                                       UTLA039
*                                                                        UTLA039
*         CALLS  WOF,LEP.                                                UTLA039
                                                                         DECK4
                                                                         DECK4
 UPL      SA3    BUF+1       FETCH DECK COUNT 
          SX0    X3          = DECK COUNT                                DECK4
          AX3    18                                                      DECK4
          SA1    LE 
          ZR     X0,CAT1     IF NO DECKS                                 DECK4
          MI     X0,UPLERR   IF NEG. DECK COUNT, GARBAGE. 
  
          ZR     X1,UPL1     IF EXPANDED LIST NOT SET 
  
          SX0    X3 
          SA5    BUF+2       PRELOAD FIRST CORRECTION NAME               DECK4
          SX1    UPL.COR                                                 DECK4
          SX2    7           LENGTH OF MESSAGE
          RJ     WOF         OUTPUT HEADER FOR *CORRECTIONS*             DECK4
          SA1    LEPC        PLUG TEST FOR PURGED IDENT 
          BX6    X1 
          SA6    LEP5.5 
          =B2    1                                                       DECK4
          MX6    9*CHAR 
          RJ     LEP         LIST CORRECTION HISTORY                     DECK4
          SA1    LEPD        UNPLUG TEST FOR PURGED IDENT 
          BX6    X1 
          SA6    LEP5.5 
 UPL1     BSS    0
          SX1    UPL.DK                                                  DECK4
          SX2    7
          RJ     WOF         OUTPUT HEADER FOR *DECKS*                   DECK4
          SA3    BUF+1                                                   DECK4
          =B2    1                                                       DECK4
          SX0    X3                                                      DECK4
          AX3    18                                                      DECK4
          MX6    45          MASK FOR GARBAGE 
          BX5    X6*X3       ISOLATE GARBAGE
          NZ     X5,UPLERR   IF GARBAGE PRESENT 
          SX6    X3-BUFL+4   CHECK FOR DIRECTORY WITHIN BUFFER
          PL     X6,UPLERR   IF DIRECTORY TOO LONG
          SA5    X3+BUF+2                                                DECK4
          MX6    9*CHAR 
          RJ     LEP         LIST DECK NAMES                             DECK4
          EQ     CAT1        RETURN 
                                                                         DECK4
UPLERR    SX1    UPL.GAR     LOCATION OF ERROR MESSAGE
          SX2    7           LENGTH OF ERROR MESSAGE
          RJ     WOF         OUTPUT *GARBAGE* MESSAGE 
          EQ     CAT1        RETURN 
  
 UPL.COR  DATA   10H
          DIS    ,/CORRECTION IDENTS LISTED IN ORDER OF INSERTION./      DECK4
          BSSZ   1
 UPL.DK   DATA   10H0 
          DIS    ,/DECK LIST./                                           DECK4
          BSSZ   4
 UPL.TR   DATA   10H
          DIS    ,/TRUNCATED - REQUESTED LIST TOO LONG./
          BSSZ   1
  
UPL.GAR   DATA   10H
          DIS    ,/BAD DATA IN OLDPL HEADER./ 
          BSSZ   3
 CPB      TITLE   SUBROUTINES.
 CPB      SPACE  4,8
**        CPB - COMPRESS PPNT BITS. 
* 
*         ENTRY  (BUF) = PPNT RECORD. 
* 
*         EXIT   (PPBUF) = NUMBER OF PPNT ENTRIES.
*                (PPBUF+1,...) = LOWER FOUR BITS (WORD1) OF EACH PPNT 
*                                ENTRY, PACKED 15 ENTRIES/WORD. 
  
  
 CPB      EQ     *+1S17      ENTRY/EXIT...
          SA1    RL          RECORD LENGTH
          AX1    1           TWO TABLE WORDS PER PP PROGRAM 
          BX6    X1 
          SA6    PPBUF       NUMBER OF PP PROGRAMS
          SA2    BUF
          SB2    X1          COUNTER
          MX1    -4 
 CPB5     SB3    60 
          =X6    0
 CPB1     SB3    B3-4 
          BX3    -X1*X2      EXTRACT LOWER FOUR BITS
          =B2    B2-1 
          LX4    B3,X3       SHIFT TO CORRECT POSITION
          BX6    X6+X4       MERGE
          ZR     B2,CPB10    IF NO MORE PPNT ENTRIES
          SA2    A2+2 
          NZ     B3,CPB1     WORD NOT FILLED YET
          =A6    A6+1        STORE FULL WORD
          EQ     CPB5        START NEW STORAGE WORD 
          SPACE  1
 CPB10    =A6    A6+1 
          EQ     CPB         RETURN 
 CAP      SPACE  4,8
**        CAP - PROCESS CAPSULE 
*                                                                        UTLA039
*         VERIFYS THAT ITS PROCESSING A CAPSULE TABLE AND IF SO CALLS    UTLA039
*         *LEP* TO LIST THE ENTRY POINTS OF THAT TABLE.                  UTLA039
  
  
 CAP      SA1    LE 
          ZR     X1,CAT1     RETURN IF NO ENTRY PT LIST DESIRED 
          SA1    BUF         CH(CK FIRST WORD 
          LX1    18 
          SB2    X1-770000B 
          NZ     B2,CAT1     RETURN IF NO 7700 TABLE
          LX1    6           SKIP 7700 TABLE
          SB2    X1+B1
          SA1    A1+B2
          MX7    12 
          BX2    X1*X7
          LX2    12 
          SB2    X2-6000B 
          NZ     B2,CAT1     RETURN IF NO 6000 TABLE
          LX1    24 
          SX0    X1          WORD COUNT(NO OF ENTRIES)
          SA2    A1+B1
          SB2    X2-BUFL
          GT     B2,B0,CAP1  IF ENTRY PT LIST IS NOT IN BUFFER. 
          SB2    X2          POINTS TO ENTRY PT LIST
          SA5    A1+B2       FIRST ENTRY PT 
          MX7    0
  
          =B2    1           ENTRY PT INCREMENT 
          MX6    7*CHAR 
          RJ     LEP         LIST ENTRY PTS.
          EQ     CAT1        RETURN 
  
 CAP1     SX1    UPL.TR 
          SX2    5
          RJ     WOF
          EQ     CAT1 
  
 LEP      SPACE  4,8
**        LEP - LIST ENTRY POINTS WITHIN GIVEN RECORD AT A               DECK4
*                MAXIMUM OF *ELL* PER LINE.                              DECK4
*                                                                        DECK4
*         ENTRY  (X0) = NUMBER OF ENTRY POINTS TO PROCESS.
*                (A5) = FWA OF ENTRY POINTS.
*                (X5) = FIRST ENTRY POINT NAME. 
*                (X6) = NAME MASK.
*                (B2) = LENGTH OF ENTRY POINT IN WORDS. 
*                                                                        DECK4
*         EXIT   ALL ENTRY POINTS PRINTED.
*                                                                        DECK4
*         USES   ALL REGISTERS. 
* 
*         CALLS  SFN, WOF.
                                                                         DECK4
                                                                         DECK4
 LEP      SUBR   0           ENTRY/EXIT 
  
*         IF ENTRY POINT LIST EXCEEDS LENGTH OF BUF, A TRUNCATED LIST 
*         IS PROCESSED.  WITH A *UPL* THEN, THE TRUNCATED CORRECTION
*         IDENT LIST WILL APPEAR, BUT NO DECK LIST WILL FOLLOW. 
  
          SA6    LEPB        SAVE NAME MASK 
          SB6    BUFL-3 
          SB7    X0 
          LE     B7,B6,LEP1  IF ALL ENTRY POINTS ARE IN BUF 
          SX0    B6          TRUNCATE LIST
 LEP1     SB3    X0 
          SB5    A5+B3
          SB4    BUF+BUFL-1 
          LE     B5,B4,LEP2  IF TOTAL ENTRY POINT LIST IN BUF 
          SX1    UPL.TR 
          SX2    7
          RJ     WOF
          EQ     LEPX        RETURN 
 LEP2     SA2    =1H
          SX6    B2                                                      DECK4
          =B6    0                                                       DECK4
          SA1    FW          GET LIMITED WIDTH FLAG 
          SB3    8           NUMBER OF ENTRIES / LINE 
          MI     X1,LEP3     IF FULL WIDTH
          SB3    4
 LEP3     LX7    X2 
          SB7    B2          INCREMENT REGISTER                          DECK4
          SA7    SBUF                                                    DECK4
          SA6    LEPA        SAVE INCREMENT                              DECK4
          =A7    A7+1                                                    DECK4
          SA4    LEPB 
                                                                         DECK4
*         SPACE FILL ALL NAMES. 
                                                                         DECK4
 LEP5     SX0    X0-1 
          BX1    X4*X5       EXTRACT NAME 
          ZR     X1,LEP6     IF PURGED IDENT
          LX5    59-4 
 LEP5.5   BSS    0           NG X5,LEP6 IF *UPL* HISTORY IDENT LIST 
          SB6    B6+1 
 +        RJ     SFN         SPACE FILL NAME
          SA6    B6+SBUF+1
 LEP6     SA5    A5+B7
          ZR     X0,LEP7     IF ALL IDENTS PROCESSED
          LT     B6,B3,LEP5  IF LINE NOT FULL 
  
 LEP7     ZR     X6,LEPX     EXIT 
          SX2    B6+2 
          MX7    0
          SX1    SBUF 
          SA7    A6+1 
          RJ     WOF         OUTPUT LINE
          SA2    LEPA 
          SA5    A5 
          SB3    8
          SA1    FW          GET FULL WIDTH FLAG
          MI     X1,LEP8     IF FULL WIDTH
          SB3    4           LIMITED WIDTH LINE LENGTH
 LEP8     SB6    B0 
          MX6    0
          SB7    X2          RELOAD  INCREMENT
          ZR     X0,LEPX     EXIT.. 
          SA4    LEPB 
          EQ     LEP5        IF MORE ENTRY POINTS TO PROCESS
                                                                         DECK4
 LEPA     DATA   0           SAVE INCREMENT                              DECK4
 LEPB     DATA   0           NAME MASK
* 
*         THE FOLLOWING TWO WORDS ARE USED FOR PLUGGING AND 
*         UNPLUGGING A TEST FOR PURGED IDENT AT LEP5.5. 
* 
 LEPC     VFD    15/03350B,15/LEP6,30/6166000001B   NG X5,LEP6
 LEPD     VFD    30/6166000001B,30/6100046000B      SB6 B6+1
 MPC      SPACE  4,8
**        MPC - MAKE PP CHANGES.
* 
*         ENTRY  (PPBUF) = NUMBER OF PPNT ENTRIES.
*                (PPBUF+1,...) = 15 FOUR-BIT SECTIONS PER PPNT ENTRY
*                                CONTAINING THE TEST INFORMATION. 
*                (PPCOUNT) = POINTER INTO PPBUF.                         UTLA039
*                                                                        UTLA039
*         SAVES  B2, B3.
  
 MPC0     SA1    LRSD 
          ZR     X1,MPC 
          SX6    1
          SA6    MPCB        INDICATE NO PROCESSING NEXT TIME IN. 
 MPC      SUBR   0           ENTRY/EXIT 
          SA1    MPCB 
          NZ     X1,MPC3     IF CONTINUATION OF LONG 77-TABLE COMMENT.
          SA1    PPBUF
          SA2    PPCOUNT
          MX0    -4 
          ZR     X1,MPC      IF PPNT NOT YET PROCESSED
          MX7    18 
          SA3    PPPOS
          SA5    SBUF+1 
          SB5    X2 
          =X6    X3-1 
          SA1    A1+B5
          LX1    4
          BX3    -X0*X1      EXTRACT FOUR TEST BITS 
          AX3    2
          SA4    MPCA+X3     INDEX INTO TABLE 
          BX5    X7*X5
          BX7    X5+X4       MERGE INTO SBUF+1
          SA7    A5 
          SX7    X2+B1
          NZ     X6,MPC1     IF MORE ENTRIES IN PPBUF WORD
          SX6    15          RESET FOR START OF NEXT WORD 
          SA7    A2 
          SA6    A3 
          EQ     MPC0 
 MPC1     SA6    A3          SAVE POSITION IN WORD
          BX7    X1 
          SA7    A1 
          EQ     MPC0 
  
 MPC3     MX6    0
          SA6    MPCB 
          EQ     MPC         EXIT IMMEDIATELY IF LONG 77-TABLE. 
  
 MPCA     DATA   7R 
          DATA   7R CM       CENTRAL MEMORY RESIDENT
          DATA   7R    CC    CONTROL CARD CALLABLE
          DATA   7R CM CC    BOTH 
 MPCB     BSSZ   1           LONG LINE FLAG 
 WHL      SPACE  4,8
**        WHL - WRITE HEADER LINES. 
* 
*         ENTRY  PROPER HEADER LINE STORED IN TITLE BUFFER. 
  
  
 WHL1     BX6    X3 
          SA6    A2 
  
 WHL      SUBR   0           ENTRY/EXIT 
          SA1    EO 
          SA2    LC 
          SA3    LL 
          SB6    0
          MI     X1,WHL1     IF EJECT BETWEEN FILES 
          SX1    X2+8 
          IX4    X3-X1
          MI     X4,WHL1     IF NOT ENOUGH ROOM 
          SX6    X2+6 
          SA6    A2          UPDATE LINE COUNT
          SA3    TT 
          SA1    =1H         BLANK LINE FOR CONNECTED FILE
          ZR     X3,WHL0     IF CONNECTED FILE
          SA1    =1H0        DOUBLE SPACE 
  
 WHL0     BX6    X1 
          SA6    TITL 
          SA1    FW          GET FULL WIDTH FLAG
          MI     X1,WHL2     IF FULL WIDTH
  
          WRITEC O,(=2L  ),1
          WRITEC O,TITL,SHORTTL 
          WRITEC O,SBTL,PWSBTL
          EQ     WHL3 
 WHL2     WRITEC O,(=2L  ),1
          WRITEC O,TITL,TITLL 
          WRITEC O,SBTL,SBTLL 
 WHL3     WRITEC O,(=2L  ),1
          EQ     WHL
 WOF      SPACE  4,8                                                     DECK4
**        WOF - WRITE LINE TO OUTPUT.                                    DECK4
* 
*         ENTRY  (X1) = FWA LINE.                                        DECK4
* 
*         USES ALL REGISTERS EXCEPT A0,X0.
                                                                         DECK4
                                                                         DECK4
 WOF1     SB6    X1-1        FWA-1 OF STRING TO BE PRINTED
          MX4    -12         *EOL* MASK 
          SA3    B6          INITIALIZE LOOP TO FIND LINE LENGTH
  
 WOF1.2   SA3    A3+B1       NEXT WORD IN LINE
          BX6    -X4*X3 
          NZ     X6,WOF1.2   IF NOT YET *EOL* 
  
          SX2    A3-B6       (X2) = LINE LENGTH 
          SA3    FW          GET FULL WIDTH FLAG
          MI     X3,WOF2     IF FULL WIDTH
  
          SA4    FW+2        GET *EOL* WORD NUMBER
          IX7    X4-X2
          PL     X7,WOF2     IF LINE IS SHORTER THAN CUT-OFF
  
          SX2    X4+B1       LENGTH OF LINE AFTER CUT-OFF 
          IX6    X1+X4
          SA3    FW+1        GET CUT-OFF MASK 
          SA4    X6          GET *EOL* WORD 
          BX7    X3*X4
          SA7    A4 
  
 WOF2     WRITEC O,X1,X2     WRITE LINE 
                                                                         DECK4
 WOF      SUBR   0           ENTRY/EXIT                                  DECK4
          SA3    LC          ADVANCE LINE COUNT                          DECK4
          SA4    LL 
          SX6    X3+B1                                                   DECK4
          SA6    A3                                                      DECK4
          SX4    X4-4 
          IX7    X6-X4
          MI     X7,WOF1     IF BOTTOM OF PAGE NOT REACHED               DECK4
          BX6    X1          SAVE REQUEST                                DECK4
          SA6    WOFA                                                    DECK4
          SA1    PN          ADVANCE PAGE NUMBER                         DECK4
          =X6                RESET LINE COUNT                            DECK4
          SX7    X1+B1                                                   DECK4
          SA6    A3                                                      DECK4
          SA7    A1                                                      DECK4
          RJ     CDD         CONVERT PAGE NUMBER                         DECK4
          MX1    -4*6                                                    DECK4
          LX6    4*6         STORE PAGE NUMBER                           DECK4
          BX6    X1*X6                                                   DECK4
          SA6    PAGE                                                    DECK4
          SA3    TT 
          SA1    =1H         BLANK LINE FOR CONNECTED FILE
          ZR     X3,WOF0     IF CONNECTED FILE
          SA1    =1H1        PAGE EJECT 
  
 WOF0     BX6    X1 
          SA6    TITL 
          SA3    FW          GET FULL WIDTH FLAG
          MI     X3,WOF3     IF LONG LINE 
  
          WRITEC O,TITL,SHORTTL 
          WRITEC O,SBTL,PWSBTL
          EQ     WOF3A
  
 WOF3     WRITEC O,TITL,TITLL 
          WRITEC O,SBTL,SBTLL 
 WOF3A    WRITEC O,(=2L  ),1
          SA1    WOFA 
          EQ     WOF1                                                    DECK4
                                                                         DECK4
 WOFA     DATA   0                                                       DECK4
 I/O      EJECT                                                          DECK4
          LIST   -F                                                      DECK4
                                                                         DECK4
*CALL COMCCDD                                                            DECK4
*CALL COMCCOD                                                            DECK4
*CALL COMCMVE                                                            DECK4
                                                                         DECK4
 #RM      IFEQ   CP#RM,0                                                 DECK4
                                                                         DECK4
*CALL COMCSYS                                                            DECK4
*CALL COMCCIO                                                            DECK4
*CALL COMCRDW                                                            DECK4
*CALL COMCWTW                                                            DECK4
*CALL COMCWTC                                                            DECK4
*CALL COMCGFL                                                            DECK4
                                                                         DECK4
 #RM      ELSE                                                           DECK4
                                                                         DECK4
*CALL COMFRIO                                                            DECK4
*CALL COMFRDW                                                            DECK4
*CALL COMFWTW                                                            DECK4
*CALL COMFWTC                                                            DECK4
*CALL COMFGFL                                                            DECK4
                                                                         DECK4
 #RM      ENDIF                                                          DECK4
                                                                         DECK4
*CALL COMCSFN                                                            DECK4
*CALL COMCSRT 
                                                                         DECK4
          LIST   *                                                       DECK4
 INIT     TITLE  INITIALIZATION -- OVERLAID BY BUFFERS.                  DECK4
          IDENT              INITIALIZATION.                             DECK4
                                                                         DECK4
                                                                         DECK4
 BUF      BSS    0                                                       DECK4
 SBUF     EQU    BUF+BUFL                                                DECK4
 OBUF     EQU    SBUF+SBUFL                                              DECK4
 FBUF     EQU    OBUF+OBUFL                                              DECK4
 ENDX     EQU    FBUF+FBUFL                                              DECK4
 ENDY     EQU    ENDX+77B                                                DECK4
 MIN.FL   OCTMIC ENDY/1S9*1S9+1S9,5 
 RFL=     EQU    "MIN.FL"B                                               DECK4
 ITEM     SPACE  4,8                                                     DECK4
**        ITEM - ENTRY AND INITIALIZATION.                               DECK4
*                                                                        UTLA039
*         THIS IS THE PROGRAM ENTRY.  AFTER ENTRY, FIELD LENGTH IS       UTLA039
*         DETERMINED, FLAGS ARE SET TO INDICATE WHETHER PROGRAM CALL WAS UTLA039
*         MADE FROM A TTY DEVICE OR NOT AND THE CALL TO THE MAIN PROGRAM UTLA039
*         IS MADE.                                                       UTLA039
*                                                                        UTLA039
*         CALLS  ARG,CAT1,GFL.                                           UTLA039
                                                                         DECK4
                                                                         DECK4
 ITEMIZE  SB1    1           (B1)1
                                                                         DECK4
 #RM      IFEQ   CP#RM,0                                                 DECK4
          SX4    A0                                                      DECK4
                                                                         DECK4
 #RM      ELSE                                                           DECK4
                                                                         DECK4
          MEMORY  SCM,ITEMB                                              DECK4
          SA4    ITEMB       PICK UP CURRENT FIELD LENGTH                DECK4
          AX4    30                                                      DECK4
                                                                         DECK4
 #RM      ENDIF                                                          DECK4
                                                                         DECK4
          SX3    RFL=        MINIMUM FIELD LENGTH                        DECK4
          IX7    X4-X3                                                   DECK4
          PL     X7,ITEM1    IF ENOUGH FIELD LENGTH FOR *CAT*            DECK4
          MEMORY  SCM,ITEMA,RCL  REQUEST MORE FIELD LENGTH               DECK4
          BX4    X3                                                      DECK4
                                                                         DECK4
 ITEM1    SX7    X4-10                                                   DECK4
          SA7    F+4                                                     DECK4
                                                                         DECK4
          DATE   DATE 
          CLOCK  TIME                                                    DECK4
                                                                         DECK4
          GETPAGE ITEMC      GET PAGE PARAMETERS
  
          SA1    ITEMC       GET JOB DEFAULTS 
          MX3    -8 
          AX1    12          POSITION FOR PRINT WIDTH *PW*
          BX6    -X3*X1 
          SA6    PW 
          AX1    8           POSITION FOR PAGE SIZE *PS*
          BX6    -X3*X1 
          SA6    LC 
          SA6    LL 
          AX1    8           POSITION FOR PRINT DENSITY *PD*
          MX3    -4 
          BX6    -X3*X1 
          SA6    PD 
          RJ     ARG         PROCESS ARGUMENTS                           DECK4
                                                                         DECK4
          SX2    O           OUTPUT FET ADDRESS 
 RM       IFNE   CP#RM,7
          RJ     STF         SET TERMINAL FILE
          SA6    TT          (TT) = 0 IF TTY
          ZR     X6,ITEM2    IF TTY FILE
 RM       ELSE
          OPEN   X2,ALTERNR,R 
 RM       ENDIF 
  
*         SET UP PROPER PRINT DENSITY.
  
          SA1    PD 
          AX3    B1,X1
          SA2    X3-3+ITEME  GET PROPER *PD*
          BX6    X2 
          SA6    ITEMD       INITIAL PRINT DENSITY IMAGE *PD* 
  
          WRITEC O,ITEMD,1    INITIALIZE FILE WITH *PD* 
  
          SA1    PD          GET ACTUAL *PD*
          SA3    ITEMC       GET JOB DEFAULT
          MX0    -4 
          AX3    12+8+8 
          BX4    -X0*X3 
          IX7    X4-X1
          ZR     X7,ITEM2    IF SAME *PD* AS DEFAULT
          AX4    1
          SA3    X4-3+ITEME 
          BX6    X3 
          SA6    PD.R        *PD* RESTORE FLAG
  
 ITEM2    SA1    TT 
          NZ     X1,ITEM3    IF NOT TTY FILE
  
          SA3    =1H
          BX6    X3 
          SA6    UPL.DK      REMOVE CARRIAGE CONTROL
          SA6    TITL        REMOVE PAGE EJECT
          SX7    77777B      FAKE LARGE LINE COUNT
          SA7    LL          SET INFINITE LINE LIMIT
          SA7    LC          LINE COUNT 
  
 ITEM3    SA2    PW 
          SX7    .FPW        PRESET FULL PRINT WIDTH
          SX6    -.FPW       PRESET FULL PRINT WIDTH FLAG 
          MI     X2,ITEM4    IF GARBAGE FROM USER 
  
          BX6    -X2         FULL WIDTH FLAG WITH ACTUAL VALUE
          BX7    X2          ACTUAL PRINT WIDTH 
          SX4    X2-.FPW
          PL     X4,ITEM4    IF .GE. MINIMUM FOR FULL WIDTH 
  
          BX6    X2          NOT FULL WIDTH 
  
 ITEM4    SA3    TT 
          NZ     X3,ITEM5    IF NOT TTY/CONNECTED FILE
  
          SA4    PWS         GET USER SPECIFICATION FLAG
          NZ     X4,ITEM5    IF USER HAS SPECIFIED THIS PRINT WIDTH 
  
          SX7    .TPW        USE DEFAULT CONNECTED FILE WIDTH 
          SX6    .TPW        SET LIMITED WIDTH FLAG 
  
 ITEM5    SA6    FW 
          SA7    PW 
  
*         DETERMINE ACTUAL LINE LENGTH DESIRED. 
  
          SA2    PW 
          SX4    10D
          IX7    X2/X4
          SA2    PW 
          SX4    10D
          IX1    X7*X4
          IX4    X2-X1
          SX1    6D 
          IX1    X4*X1
          SX6    0           CLEAR EOL MASK 
          MX0    1
          SB6    X1-1 
          ZR     X1,ITEM6    IF MULTIPLE OF 10
  
          AX6    B6,X0
 ITEM6    SA6    FW+1        SAVE EOL MASK
          SA7    FW+2        SAVE EOL WORD
  
          SA1    FW 
          MI     X1,ITEM7    IF FULL WIDTH
  
          SA2    TITL+5 
          SA3    SBTL+5 
          MX4    6*8
          BX6    X4*X2
          SA6    A2 
          BX7    X4*X3
          SA7    A3 
  
 ITEM7    SX2    F
 OPTIC    IFEQ   CP#RM,0
          SA3    ITEMF
          RJ     SOE         SET OPTICAL EXTENSION
          SX2    F
 OPTIC    ENDIF 
          SA1    RW          GET REWIND FLAG
          RJ     GFL         GET FILE LABEL                              DECK4
          ZR     X6,CAT1     IF NO LABEL                                 DECK4
          SA6    FI                                                      DECK4
          =A7    A6+1                                                    DECK4
          EQ     CAT1        BEGIN MAIN PROGRAM..                        DECK4
                                                                         DECK4
                                                                         DECK4
 ITEMA    VFD    30/RFL=,30/0                                            DECK4
 ITEMB    DATA   0                                                       DECK4
 ITEMC    BSSZ   2           GETPAGE PARAMETER BLOCK
 ITEMD    CON    0           INITIAL *PD* IMAGE 
  
 ITEME    BSS    0           PRINT DENSITY TEMPLATES
 PD.6     DATA   8LS  6LPI
 PD.8     DATA   8LT  8LPI
          IFEQ   CP#RM,0,1
 ITEMF    VFD    36/0,6/16,18/F.ODE  OPTICAL FET EXTENSION POINTER
 ABT      SPACE  4,8                                                     DECK4
**        ABT -  ABORT INITIALIZATION.                                   DECK4
*                                                                        DECK4
*         ENTRY  (X1) _ DAYFILE MESSAGE.                                 DECK4
                                                                         DECK4
                                                                         DECK4
 ABT      MESSAGE X1,,RCL                                                DECK4
          ABORT  ,NODUMP                                                 DECK4
 ARG      SPACE  4,8                                                     DECK4
**        ARG - PROCESS ARGUMENTS.                                       DECK4
*                                                                        UTLA039
*         WILL CAUSE AN ABORT IF THE NAME OF THE FILE TO BE ITEMIZED IS  UTLA039
*         THE SAME NAME OF THE OUTPUT FILE.  ALSO CRACKS THE CONTROL     UTLA039
*         CARD PARAMETERS.  THE FOLLOWING PROCESSORS ARE CALLED ONLY IF  UTLA039
*         THE INDICATED OPTIONS WERE SELECTED ON THE CONTROL CARD:       UTLA039
*                *SFC* - SETS THE UPPER LIMIT ON THE NUMBER OF FILES     UTLA039
*                            TO BE PROCESSED IF *N* IS SELECTED.         UTLA039
*                *SLF* - SETS THE NAME OF THE FILE ON WHICH THE OUTPUT   UTLA039
*                            IS TO BE LISTED IF *L* IS SELECTED.         UTLA039
*                *SUL* - SETS A FLAG TO INDICATE THAT THE USER LIBRARY   UTLA039
*                            IS TO BE LISTED IF *U* IS SELECTED.         UTLA039
*                *SEL* - FLAGS THAT ENTRY POINTS ARE TO BE LISTED IF *E* UTLA039
*                            IS SELECTED.                                UTLA039
*                *SEO* - SETS THE PAGE EJECT OPTION IF *BL* IS SELECTED. UTLA039
*                *SRO* - FLAGS THAT FILES ARE NOT TO BE REWOUND BEFORE   UTLA039
*                            OR AFTER PROCESSING IF *NR* IS SELECTED.    UTLA039
*                *SL8* - PRINT DENSITY IS SET TO 8 LINES PER INCH IF     UTLA039
*                            *PD* IS SELECTED.                           UTLA039
*                *SPW* - SETS THE PRINT WIDTH ACCORDING TO THE VALUE     UTLA039
*                            SELECTED WITH THE *PW* OPTION.              UTLA039
*                                                                        UTLA039
*         CALLS  SFC,SLF,SUL,SEL,SEO,SRO,SL8,SPW                         UTLA039
                                                                         DECK4
                                                                         DECK4
 ARG      SUBR   0           ENTRY/EXIT...                               DECK4
          RJ     SES         SET EQUAL SIGNS
          SA1    RA.ACT      CHECK ARGUMENT COUNT                        DECK4
          SB7    X1                                                      DECK4
          MX0    7*6                                                     DECK4
          ZR     B7,ARG4     IF NO ARGUMENTS                             DECK4
          =A1    RA.ARG      SET FILE NAME                               DECK4
          MX2    -2          = -3                                        DECK4
          BX1    X0*X1                                                   DECK4
          ZR     X1,ARG1     IF FILE NAME BLANK                          DECK4
                                                                         DECK4
 #RM      IFEQ   CP#RM,0                                                 DECK4
                                                                         DECK4
          IX6    X1-X2                                                   DECK4
          SA6    F                                                       DECK4
                                                                         DECK4
 #RM      ELSE                                                           DECK4
                                                                         DECK4
          STORE  FI.LGO,LFN=X1                                           DECK4
                                                                         DECK4
 #RM      ENDIF                                                          DECK4
                                                                         DECK4
 ARG1     SB7    B7-B1                                                   DECK4
          ZR     B7,ARG4     IF END OF ARGUMENTS                         DECK4
          SA1    A1+B1       NEXT ARGUMENT                               DECK4
          SB4    X1-1R=                                                  DECK4
          SB2    B0                                                      DECK4
          NZ     B4,ARG2     IF NOT *=*                                  DECK4
          ZR     B7,ARG3     IF NO EQUIVALENCE VALUE                     DECK4
          SB7    B7-B1                                                   DECK4
 ARG2     SA2    ARGA+B2     NEXT OPTION                                 DECK4
          ZR     X2,ARG3     IF END OF TABLE                             DECK4
          SB2    B2+B1                                                   DECK4
          BX6    X1-X2                                                   DECK4
          SB3    X2          SET JUMP ADDRESS                            DECK4
          BX7    X0*X6                                                   DECK4
          NZ     X7,ARG2     LOOP IF NO MATCH                            DECK4
          JP     B3          PROCESS OPTION                              DECK4
                                                                         DECK4
 ARG3     SX1    =C* ERROR IN ARGUMENTS.*                                DECK4
          EQ     ABT                                                     DECK4
                                                                         DECK4
 ARG4     SA1    F           ENTER FILE NAME IN TITLE                    DECK4
                                                                         DECK4
 #RM      IFEQ   CP#RM,0                                                 DECK4
                                                                         DECK4
          BX1    X0*X1                                                   DECK4
                                                                         DECK4
 #RM      ELSE                                                           DECK4
                                                                         DECK4
          SA1    X1          PICK UP FILE NAME FROM FIT                  DECK4
                                                                         DECK4
 #RM      ENDIF                                                          DECK4
                                                                         DECK4
          RJ     SFN                                                     DECK4
          LX6    -CHAR                                                   DECK4
          SA6    TITL+2                                                  DECK4
                                                                         DECK4
          SA1    O           CHECK FILE NAMES                            DECK4
          SA2    F                                                       DECK4
                                                                         DECK4
 #RM      IFNE   CP#RM,0                                                 DECK4
                                                                         DECK4
          SA1    X1          PICK UP FILE NAMES FROM FIT                 DECK4
          SA2    X2                                                      DECK4
                                                                         DECK4
 #RM      ENDIF                                                          DECK4
                                                                         DECK4
          BX6    X1-X2                                                   DECK4
          BX7    X0*X6                                                   DECK4
          NZ     X7,ARG      RETURN IF DIFFERENT                         DECK4
          SX1    =C* FILE NAME CONFLICT.*                                DECK4
          EQ     ABT                                                     DECK4
                                                                         DECK4
 ARGA     BSS    0           TABLE OF CONTROL STATEMENT OPTIONS          DECK4
          VFD    42/0LN,18/SFC                                           DECK4
          VFD    42/0LL,18/SLF                                           DECK4
          VFD    42/0LU,18/SUL                                           DECK4
          VFD    42/0LE,18/SEL                                           DECK4
          VFD    42/0LBL,18/SEO 
          VFD    42/0LNR,18/SRO                                          DECK4
          VFD    42/0LPD,18/SL8 
          VFD    42/0LPW,18/SPW 
          CON    0           END OF TABLE                                DECK4
 SEL      SPACE  4,8                                                     DECK4
*         SEL - SET ENTRY LIST                                           UTLA039
                                                                         DECK4
                                                                         DECK4
 SEL      ZR     B4,ARG3     IF E=                                       DECK4
          SX6    B1                                                      DECK4
          SA6    LE          SET FOR ENTRY POINT LIST                    DECK4
          EQ     ARG1        PROCESS NEXT ARGUMENT
 SFC      SPACE  4,8                                                     DECK4
*         SFC - SET FILE COUNT                                           UTLA039
                                                                         DECK4
                                                                         DECK4
 SFC      NZ     B4,SFI      IF NO EQUIVALENCE
          SA2    FC          CHECK FOR INFINITE FILE COUNT               DECK4
          SA1    A1+B1       FILE COUNT 
          MI     X2,ARG1     EOI OVERRIDES N=X                           DECK4
          SX6    B0          CLEAR ASSEMBLY                              DECK4
          MX7    60-6                                                    DECK4
          BX1    X0*X1                                                   DECK4
          SB2    B1+B1                                                   DECK4
 SFC1     LX1    6           CHECK NEXT CHARACTER                        DECK4
          BX2    -X7*X1                                                  DECK4
          ZR     X2,SFC2     IF 00                                       DECK4
          SX3    X2-1R0                                                  DECK4
          MI     X3,SFC3     IF ALPHA                                    DECK4
          LX2    X6,B2       ASSEMBLY * 10                               DECK4
          IX4    X2+X6                                                   DECK4
          LX4    1                                                       DECK4
          IX6    X4+X3                                                   DECK4
          EQ     SFC1        LOOP                                        DECK4
                                                                         DECK4
 SFC2     SA6    FC          SET FILE COUNT                              DECK4
          EQ     ARG1        PROCESS NEXT ARGUMENT                       DECK4
                                                                         DECK4
 SFC3     SX1    =C* FILE COUNT PARAM NOT NUMERIC.* 
          EQ     ABT                                                     DECK4
 SFI      SPACE  4,8                                                     DECK4
*         SFI - SET FILE COUNT INFINITE                                  UTLA039
                                                                         DECK4
                                                                         DECK4
 SFI      MX6    -1                                                      DECK4
          EQ     SFC2                                                    DECK4
 SLF      SPACE  4,8
*         SLF - SET LIST FILE.                                           UTLA039
                                                                         DECK4
                                                                         DECK4
 SLF      NZ     B4,ARG3     IF NO EQUIVALENCE                           DECK4
          SA1    A1+B1       LIST FILE NAME                              DECK4
          MX2    42                                                      DECK4
          BX1    X2*X1                                                   DECK4
                                                                         DECK4
 #RM      IFEQ   CP#RM,0                                                 DECK4
                                                                         DECK4
          SX6    B1                                                      DECK4
          BX6    X1+X6                                                   DECK4
          SA6    O                                                       DECK4
                                                                         DECK4
 #RM      ELSE                                                           DECK4
                                                                         DECK4
          STORE  FI.OUT,LFN=X1                                           DECK4
                                                                         DECK4
 #RM      ENDIF                                                          DECK4
          EQ     ARG1        PROCESS NEXT ARGUMENT                       DECK4
 SEO      SPACE  4,8                                                     DECK4
*         SEO - SET EJECT OPTION.                                        UTLA039
                                                                         DECK4
                                                                         DECK4
 SEO      SX6    -1 
          SA6    EO          SET BL OPTION
          EQ     ARG1        PROCESS NEXT ARGUMENT
 SL8      SPACE  4,8
*         SL8 - SET 8 LINES/INCH OUTPUT FILE OPTION.                     UTLA039
  
  
 SL8      SX6    .8LPI       FORCE 8LPI 
          SA6    PD 
          SA6    PDS         USER SPECIFIED 8LPI
          SX6    .8LPILC     SET PAGE SIZE FOR 8LPI 
          SA6    LC 
          SA6    LL 
          EQ     ARG1        PROCESS NEXT ARGUMENT
 SRO      SPACE  4,8                                                     DECK4
*         SR0 - SET REWIND OPTION.                                       UTLA039
                                                                         DECK4
                                                                         DECK4
 SRO      SX6    B0                                                      DECK4
          SA6    RW          INHIBIT REWIND                              DECK4
          EQ     ARG1        PROCESS NEXT ARGUMENT                       DECK4
 SUL      SPACE  4,8
*         SUL - SET USER LIBRARY LIST.                                   UTLA039
                                                                         DECK4
                                                                         DECK4
 SUL      SX6    B1          SET USER LIBRARY LIST                       DECK4
          SA6    UL                                                      DECK4
          EQ     ARG1        PROCESS NEXT ARGUMENT                       DECK4
                                                                         DECK4
 SPW      SPACE  4,8                                                     UTLA039
*         SPW - SET PRINT WIDTH.                                         UTLA039
  
 SPW      SX6    72 
          NZ     B4,SPW3     IF NO EQUIVALENCE
          SA1    A1+B1
          SX6    B0 
          MX7    60-6 
          BX1    X0*X1
          SB2    B1+B1
 SPW1     LX1    6           CHECK NEXT CHARACTER 
          BX2    -X7*X1 
          ZR     X2,SPW3     IF 00
          SX3    X2-1R0 
          MI     X3,SPW2     IF ALPHA 
          LX2    X6,B2
          IX4    X2+X6
          LX4    1
          IX6    X4+X3
          EQ     SPW1        LOOP 
 SPW2     SX1    =C* ILLEGAL PW SPECIFICATION - IGNORED * 
          MESSAGE X1,,RCL 
          SX6    -1          IF GARBAGE 
 SPW3     SA6    PW 
          SA6    PWS         INDICATE USER SPECIFIED PW ON CONTROL CD 
          EQ     ARG1 
  
                                                                         DECK4
 OPTIC    IFEQ   CP#RM,0
 SOE      SPACE  4,20 
**        SOE - SET OPTICAL EXTENSION.
* 
*         SOE ISSUES A *FILINFO* REQUEST ON THE FET SPECIFIED IN (X2).
*         IF THE FILE IS AN OPTICAL DISK FILE (NOS ONLY), THE POINTER 
*         (X3) TO THE OPTICAL FET EXTENSION IS PLACED INTO THE FET. 
* 
*         ENTRY  (X2) = FET ADDRESS.
*                (X3) = POINTER TO APPROPRIATE FET EXTENSION. 
* 
*         EXIT   (X1) = 0, OPTICAL DISK POINTER SET IN FET. 
* 
*         USES   X - 1, 6.
*                A - 1, 6.
*                B - 7. 
* 
*         MACROS FILINFO. 
  
 SOE      SUBR               ENTRY/EXIT 
          MX6    42 
          SA1    X2          GET NEWPL NAME 
          BX1    X6*X1       ZERO OUT REST OF WORD
          SB7    X2 
          SX6    50000B      ADD LENGTH OF REQUEST BUFFER 
          BX6    X1+X6
          SA6    SOEA        STORE NAME AND STORAGE LENGTH. 
          FILINFO A6
          SA1    SOEA+1 
          AX1    48          ISOLATE DEVICE TYPE
          SX1    X1-2ROD
          NZ     X1,SOEX     IF NOT OPTICAL DISK
          BX6    X3          SET POINTER INTO FET 
          SA6    B7+11B 
          EQ     SOEX        RETURN 
  
 SOEA     BSSZ   5
 OPTIC    ENDIF 
*CALL     COMCSTF 
 #RM      IFEQ   CP#RM,0
*CALL     COMCCPM 
 #RM      ENDIF 
*CALL COMCSES                                                            DECK4
                                                                         DECK4
          DIS    ,*COPYRIGHT CONTROL DATA CORP. 1971, 1972, 1973, 1974, 
,1975,1976,1977,1978,1979,1980,1981,1982.*
                                                                         DECK4
 FIN      END    LIST        MIN.FL = "MIN.FL"B 
