*COMDECK  COMPCUA 
 CUA      CTEXT  COMPCUA - CHECK USER ACCESS. 
          SPACE  4,10 
          IF     -DEF,QUAL$,1 
          QUAL   COMPCUA
*         COMMENT COPYRIGHT CONTROL DATA CORPORATION. 1976. 
 CUA      SPACE  4,10 
**        CUA - CHECK USER ACCESS.
* 
*         CUA CHECKS THE ORIGIN OF A JOB AND VERIFIES THAT A GIVEN
*         FUNCTION CAN BE PERFORMED.
* 
*         ENTRY  (D.CPAD) = CONTROL POINT ADDRESS.
* 
*         EXIT   (A) = 0  IF SYSTEM ACCESS ALLOWED. 
*                (D.T0) = 0  IF ENGINEERING ACCESS ALLOWED. 
* 
*         USES   D.T0 - D.T0+4. 
  
 CUA1     LDN    1
 CUA2     STD    D.T0        SET ENGINEERING ACCESS 
  
 CUA      ENM    X           ENTRY/EXIT 
  
          LDD    D.CPAD 
          ADN    W.CPSCH
          CRD    D.T0 
          LDD    D.T0+C.CPJDA 
          LPN    77B
          ADD    D.T0+C.CPJDA+1 
          ZJN    CUA2        IF CONSOLE ORIGIN
  
          LDD    D.CPAD 
          ADN    W.CPLDR1 
          CRD    D.T0 
          LDD    D.T0+C.CPLW LOADER FLAG BYTE 
          SHN    17D-S.CPLP 
          MJN    CUA1        IF PROGRAM NOT LOADED FROM SYSTEM LIBRARY
  
          LDN    T.ENGR 
          CRD    D.T0 
          LDD    D.T0+C.ENGR ENGINEERING MODE BYTE
          LPN    1           ENGINEERING MODE BIT 
          LMN    1
          UJN    CUA2 
  
          SPACE  4,10 
 QUAL$    IF     -DEF,QUAL$ 
          QUAL   *
 CUA      EQU    /COMPCUA/CUA 
 QUAL$    ENDIF 
          ENDX
