*COMDECK  COMCSES 
          CTEXT  COMCSES - SET EQUAL SIGNS IN PARAMETER LIST. 
          IF     -DEF,QUAL$,1 
          QUAL   COMCSES
          BASE   D
 SES      SPACE  4
***       SES - SET EQUAL SIGNS IN PARAMETER LIST.
*         R.S. HORECK        71/05/04.
          SPACE  4
***              SES INSERTS EQUAL SIGNS IN THE CONTROL CARD ARGUMENTS
*         FROM *ARGR* THROUGH THE END OF THE LIST BASED ON THE CONTROL
*         CARD IMAGE FOUND AT *CCDR*. 
* 
*         ENTRY  (B1) = 1.
*                (ACTR) = ARGUMENT COUNT. 
*                (ARGR - ARGR+(ACTR)) = ARGUMENT LIST.
*                (CCDR) = CONTROL CARD IMAGE IN *C* FORMAT. 
* 
*         EXIT   EACH EQUIVALENCED PARAMETER CONTAINS THE *=* IN THE LOW
*                6 BITS OF THE ITEM TO THE LEFT OF THE EQUAL SIGN.
* 
*         USES   X - 1, 2, 3, 4, 6, 7.
*                B - 3, 4, 5, 6, 7. 
*                A - 1, 2, 3, 6.
* 
*         CALLS  NONE.
  
  
 SES1     LX1    6           CHECK CHARACTER
          BX6    -X2*X1 
          SB7    B7-B1       DECREMENT CHARACTER COUNT
          SB6    X6 
          NZ     B7,SES2     IF NOT END OF WORD 
          SA1    A1+B1       READ NEXT WORD 
          SB7    X7          RESET CHARACTER COUNT
 SES2     LE     B6,B4,SES1  IF CHARACTER IS ALPHANUMERIC 
          SX3    B6-1R*      CHECK FOR *
          ZR     X3,SES1
          SA3    A3+B1       ADVANCE PARAMETER
          SB3    B3-B1       DECREMENT ARGUMENT COUNT 
          BX6    X2*X3       CLEAR LOW ORDER BITS 
          NE     B6,B5,SES3  IF SEPARATOR NOT *=* 
          BX6    X6+X4       SET *=*
 SES3     SA6    A3+
          GT     B3,SES1     LOOP TO END OF ARGUMENTS 
  
 SES      PS     0           ENTRY/EXIT 
          SA4    ACTR        ARGUMENT COUNT 
          SB3    X4 
          MX2    60-6 
          SA1    CCDR        STATEMENT BUFFER 
          BX6    X2*X4       CHECK FOR NULL PROGRAM NAME
          SX7    10 
          ZR     X6,SES      IF NULL PROGRAM NAME 
          SB4    1R9
          SX4    1R=
          SB7    X7          SET CHARACTER COUNT
          BX6    X6-X6       CLEAR LAST WORD OF LIST FOR *ARG*
          SB5    1R=
          SA6    B3+ARGR
          SA3    A6-B1       LAST PARAMETER 
          MX6    42 
          BX6    X6*X3       CLEAR LOWER 18 BITS
          SA6    A3 
          SA3    B0          INITIALIZE PARAMETER ADDRESS 
          EQ     SES1        PROCESS LIST 
          SPACE  4
 QUAL$    IF     -DEF,QUAL$ 
          QUAL
 SES      EQU    /COMCSES/SES 
 QUAL$    ENDIF 
          ENDX
