*DECK,CHEKPT
**DOCK    EJECT  4,10                                                   01251096
**DOCK    TITLE  SPACE,4,10                                             01251097
         IDENT     CHEKPT 
          TITLE  CHEKPT                                                 01251099
* DESIGNER
*        R. L. GUERTIN  (PROJECT MANAGER) 
* 
* DATE   NOV. 5,1968
          SPACE 4                                                       01251101
**                                                                      01251102
* CALLING SEQUENCE FOR CHEKPTR
*        SB1       PARAD               B1=PARAD 
*        SB2       SP              SP INCICATOR ADDRESS 
*                                  (NZ IMPLIES SPECIFIC)
*        RJ        CHEKPTR
* 
         ENTRY     CHEKPTR
 CHEKPTR DATA      0                   RUN COMPILER ENTRY/EXIT
* ENTER WITH B1=PARAD 
         SA1       B1                  A1=PARAD 
         SA2       B2              SP INDICATOR 
         RJ        CHEKPT              CALL FOR CHECKPOINT PROCEDURE
         EQ        CHEKPTR
         SPACE     3
**                                                                      01251104
* CALLING SEQUENCE FOR CHEKPTX
*        SA1       POINTER             X1=PARAD  (POINTER)
*        RJ        CHEKPTX
* 
         ENTRY     CHEKPTX
 CHEKPTX DATA      0                   FORTRAN EXTENDED ENTRY/EXIT
* ENTER WITH X1=PARAD 
         SA2       A1+1            SP IND ADDRESS 
         SA2       X2              SP INDICATOR 
         SA1       X1                  A1=PARAD 
         RJ        CHEKPT              CALL FOR CHECKPOINT PROCEDURE
         EQ        CHEKPTX
         EJECT
**                                                                      01251106
* CALLING SEQUENCE FOR CHEKPT 
*        SA1       PARAD               A1=PARAD 
*        SX2       B0              IF ALL FILES 
*                  OR 
*        SX2       1               IF SPECIFIC FILES
*        RJ        CHEKPT 
* 
         ENTRY     CHEKPT 
CHEKPT   DATA      0                    ENTRY/EXIT
CHEKPT1  SB1       1                    CONSTANT 1
         SX6       A1-100B              CHECK IF PARAD IN RANGE 
         NG        X6,ERROR             IF NOT, ERROR 
         MX6       59                   MASK LOWEST BIT TO ZERO 
         BX6       X6*X1
         SA6       A1                   RESTORE WORD WITH BIT 0 CLEARED 
         SX6       A1                   PARAD ADDRESS TO X6 
         SA1       CHEKREQ              FETCH REQUEST PROTO-TYPE
         BX6       X6+X1                PLACE REQUEST IN X6 
         MX1       12              SP MASK
         LX1       12 
         BX2       X1*X2           ISOLATE
         LX2       35-11           POSITION 
         BX6       X6+X2           COMBINE
         SYSTEM                         ISSUE CALL FOR CKP
         SA1       X6                   FETCH PARAD AGAIN 
         MX6       59 
         BX6       X1*X6                MASK OUT COMPLETION BIT 
  
  
  
  
         BX6       X1*X6                MASK OUT COMPLETION BIT 
         SA6       A1                   AND RESTORE IN PARAD
         EQ        CHEKPT               THEN EXIT 
ERROR    SA1       PARAD                CHECK IF FIRST TIME ERROR 
         NG        X1,CHEKPT1           IF NOT, CALL CKP WITH PARAD 
         SA1       CHEKERR              ELSE, FETCH MSG REQUEST 
         BX6       X1                   PLACE REQUEST IN X6 
         SYSTEM                        ISSUE CALL FOR MSG 
         SA1       B0                   FETCH RA
         SX6       10000B               SELECT PAUSE BIT
         BX6       X1+X6                SET PAUSE BIT 
         SA6       B0                    AT RA
CHEKPT2  SA1       CHEKRCL              SELECT RECALL REQUEST 
         BX6       X1 
         SYSTEM                         ISSUE CALL FOR RCL
         SA1       B0                   CHECK IF PAUSE GIVEN A GO 
         LX1       47 
         NG        X1,CHEKPT2           IF NOT, GO TO RECALL AGAIN
         MX6       1                    SET FIRST TIME BIT
         SA6       PARAD                 IN PARAD 
         SA1       A6 
         EQ        CHEKPT1              JUMP TO ISSUE CKP CALL
PARAD    DATA      0
CHEKREQ  VFD       18/3LCKP,2/1,22/0,18/0 
CHEKRCL  VFD       18/3LRCL,42/0
CHEKERR  VFD       18/3LMSG,24/0,18/ERRMSG
ERRMSG   DIS       ,*CKP PARAD INVALID, GO OR DROP.*
          END                                                           01251108
