*COMDECK  SSYS
          CTEXT  SSYS   - SYSTEM CONTROL POINT DEFINITIONS
          SPACE  3,9
***       SSYS    - DEFINITIONS OF SUBSYSTEM SYMBOLS AND MACROS 
* 
*         THE SYMBOLS AND MACROS ARE REQUIRED FOR - 
* 
*         1.  THE SUPPORTING CODE FOR THE SYSTEM CONTROL POINT FEATURE. 
*                (CPMTR, SSC AND SSF) 
* 
*         2.  SUBSYSTEMS THAT REQUEST SYSTEM CONTROL POINT STATUS.
* 
*         3.  USER JOBS THAT CALL SUBSYSTEMS. 
  
  
*         SPECIAL WORDS USED BY A SCP 
  
RA.SSID   = 50B              SUBSYSTEM IDENTIFICATION WORD
RA.SSC    = 51B              POINTER TO SSC INPUT AREA
  
*         DIFINE SUBSYSTEM CODES
  
SS.SYS    = 0                REQUEST TO SCOPE TO ENTER SCP STATUS 
SS.CDCS   = 1                CYBER DATA CONTROL SYSTEM
SS.NAM    = 2                NETWORK ACCESS METHOD
SS.MCS    = 3                MESSAGE CONTROL SYSTEM 
  
*         SUBSYSTEM FUNCTIONS 
  
SF.REGR   = 2                REGRETS -- MESSAGE AND/OR ABORT TO UCP 
SF.TIME   = 4                ACCOUNTING DATA FOR SCP
SF.ENDT   = 6                COMPLETES AN SSC TASK AT A UCP 
SF.READ   = 10B              TRANSFER DATA FROM UCP TO SCP
SF.STAT   = 12B              REQUEST THE STATUS OF A UCP
SF.WRIT   = 14B              TRANSFER DATA FROM SCP TO UCP
SF.EXIT   = 16B              TERMINATE SCP STATUS 
SF.INUF   = 20B              INTERLOCK USER FILE
SF.RTUF   = 22B              RETURN USER FILE 
SF.SWPO   = 24B              RELEASE UCP FOR SWAPOUT
SF.SWPI   = 26B              CALL FOR THE UCP TO BE SWAPPED IN AGAIN
SF.SLTC   = 30B              SET LONG TERM CONNECTION 
SF.CLTC   = 32B              CLEAR LONG TERM CONNECTION 
SF.LIST   = 34B              A LIST OF OTHER SF.XXXX FUNCTIONS
  
*         FUNCTION PARAMETERS FOR SF.REGR 
  
F.SYCP    = 0                TO SYSTEM DAYFILE AND CTL PT DAYFILE 
F.NMSN    = 3                SYSTEM DAYFILE ONLY
F.JNMN    = 43B              SYSTEM DAYFILE ONLY, DONT ADD JOB NAME 
F.CPON    = 4                CONTROL POINT DAYFILE ONLY 
F.ACFN    = 13B              ACCOUNTING TO SYSTEM DAYFILE ONLY
F.AJNN    = 53B              ACCOUNTING TO SYS DF ONLY, DONT ADD JOB N. 
F.ERLN    = 20B              CE ERROR FILE
F.EJNN    = 60B              CE ERROR FILE, DONT ADD JOB NAME 
  
*         ERROR FLAGS ALLOWED IN UCPA FIELD OF SF.REGR
  
F.SEXX    = 1                GENERAL SUBSYSTEM ERROR
F.SEHU    = 2                HOSTILE USER ERROR 
  
*         LENGTH OF BLOCK OF ACCOUNTING DATA USED BY SF.TIME AND SF.ENDT
  
L.SACT    = 6 
          SPACE  4,13 
**        CALLSS             MACRO USED TO CALL A SUBSYSTEM 
* 
*         CALLSS SS,AD,R
* 
*         SS     THE SUBSYSTEM CODE TO IDENTIFY WHICH SUBSYSTEM.
*         AD     ADDRESS OF THE PARAMETER BLOCK FOR THIS REQUEST. 
*         R      IF NONBLANK, THIS REQUEST IS MADE WITH AUTO-RECALL.
  
          PURGMAC  CALLSS 
  
CALLSS    MACRO  SS,AD,R
  SYSTEM SSC,R,AD,SS
  ENDM
 SETMFL   SPACE  4,10 
**        SETMFL - SET MAXIMUM FIELD LENGTH FOR SYSTEM ORIGIN JOB.
* 
*         SETMFL VALUE
* 
*         ENTRY  *VALUE* = REQUESTED MAXIMUM FIELD LENGTH (CONSTANT OR
*                          REGISTER NAME).  REQUEST IS MADE WITH
*                          AUTO-RECALL. 
* 
*         EXIT   MAXIMUM FIELD LENGTH FOR JOB SET TO VALUE (ROUNDED UP
*                TO NEXT 100B) IF MAXIMUM FIELD LENGTH WAS ZERO.
* 
*         USES   X1, X6, A6.
* 
*         CALLS  SYS=.
  
  PURGMAC SETMFL
  
 SETMFL MACRO V 
  LOCAL P 
  EQ P+1
 P BSS 1
  SX1 V 
  MX6 42D 
  BX6 -X6*X1
  LX6 30D 
  SA6 P 
  SYSTEM STS,R,P,700B 
  ENDM
          SPACE  4,12 
**        SFCALL             PRIVILEGED SYSTEM CALL FROM SUBSYSTEM
* 
*         SFCALL AD,R 
* 
*         AD     ADDRESS OF THE PARAMETER BLOCK FOR THIS REQUEST. 
*         R      IF NONBLANK, THIS REQUEST IS MADE WITH AUTO-RECALL.
  
          PURGMAC  SFCALL 
  
SFCALL    MACRO  AD,R 
  SYSTEM SSF,R,AD 
  ENDM
          SPACE  4,1
SSYS      ENDX
