*DECK SETCHG
          IDENT  SETCHG 
*CALL COPYRITE          CDCNET - COPYRIGHT CONTROL DATA. 1985.
          ENTRY  SETCHG 
          EXT    SSJ= 
          SYSCOM B1 
          TITLE  SETCHG - SET NEW CHARGE/PROJECT NUMBERS. 
          COMMENT  SETCHG - SET NEW CHARGE/PROJECT NUMBERS. 
          COMMENT - COPYRIGHT CONTROL DATA SYSTEMS INC. 1994. 
 SETCHG   SPACE  4,10 
**        SETCHG - SET NEW CHARGE/PROJECT NUMBERS.
* 
*         *SETCHG* CALLS *COMCCHG* ROUTINE *CHG* TO VALIDATE CHARGE 
*         NUMBER AND SWITCH ACCOUNT TO NEW CHARGE IF VALIDATED. 
* 
*         *SYMPL* CALL -
* 
*         SETCHG (CHARGE,PROJECT,USER,DEFAULT,ERRADDR); 
* 
*         ENTRY  (CHARGE)  = CHARGE NUMBER. 1-10 ZERO-FILLED
*                            CHARACTERS.
*                (PROJECT) = PROJECT NUMBER.  TWO WORD ARRAY CONTAINING 
*                            1-20 ZERO-FILLED CHARACTERS. 
*                (USER)    = USER NAME.  1-7 ZERO-FILLED CHARACTERS.
*                (DEFAULT) = DEFAULT CHARGE FLAG.  MUST BE TRUE 
*                            (NON-ZERO) IF SUPPLIED CHARGE NUMBER IS
*                            THE USER DEFAULT CHARGE. 
*                SSJ=      = *SSJ=* ENTRY POINT AND PARAMETER BLOCK 
*                            IS REQUIRED. 
* 
*         EXIT   (ERRADDR) = ADDRESS OF ERROR MESSAGE IF ERROR.  ZERO 
*                            IF CHARGE VALIDATED AND ESTABLISHED. 
* 
*         USES   X - 1, 2, 3, 6.
*                A - 1, 2, 3, 6.
*                B - 1. 
* 
*         CALLS  CHG. 
  
  
 OPL      XTEXT  COMSPFM
 OPL      XTEXT  COMSPRO
 OPL      XTEXT  COMSSRU
 OPL      XTEXT  COMSSSJ
 OPL      XTEXT  COMCCHG
  
          ORG    CHGL+1 
  
 OPL      XTEXT  COMCSNM
  
 SETCHG   SUBR               ENTRY/EXIT 
          SB1    1           DEFINE B1=1
          SX6    0           CLEAR SRU INDEX/RANDOM ADDRESS 
          SA6    SRUM+1 
          SA3    X1          GET CHARGE NUMBER
          BX6    X3          SET CHARGE IN ACCOUNT BLOCK
          SA6    CGN
          SA1    A1+B1       GET PROJECT NUMBER 
          SA3    X1          FIRST HALF OF PROJECT NUMBER 
          BX6    X3          SET PROJECT NUMBER IN ACCOUNT BLOCK
          SA6    PRN
          SA3    A3+B1       SECOND HALF OF PROJECT NUMBER
          BX6    X3 
          SA6    PRN1 
          SA1    A1+B1       GET USER NUMBER
          SA3    X1          X3 HAS USER NUMBER (REQUIRED BY CHG) 
          SA1    A1+B1       GET DEFAULT CHARGE FLAG
          SA2    X1          X2 HAS DEFAULT CHARGE FLAG (CHG) 
          SA1    A1+B1       SAVE ERROR PARAMETER ADDRESS 
          BX6    X1 
          SA6    SCHA 
          RJ     CHG         VALIDATE CHARGE/PROJECT
          SA1    SCHA        GET ERROR PARAMETER ADDRESS
          SX6    B6          RETURN ERROR MESSAGE ADDRESS 
          SA6    X1 
          EQ     SETCHGX     RETURN 
  
 SCHA     BSSZ   1           USER PARAMETER LIST ADDRESS
*                            ACCOUNT INFORMATION BLOCK
 SRUM     BSSZ   2           CONTROL POINT SRU WORDS
 CGN      BSSZ   1           CHARGE NUMBER
 PRN      BSSZ   1           FIRST HALF OF PROJECT NUMBER 
 PRN1     BSSZ   1           SECOND HALF OF PROJECT NUMBER
 ACCM     BSSZ   5           ACCOUNT FILE MESSAGE BUFFER
  
          END 
