*DECK,GETVP 
          IDENT  GET$VP 
*CALL COPYRITE
          ENTRY  GET$VP 
          SYSCOM B1 
          TITLE  GET$VP - FETCH NOS VERSION AND PSR LEVELS*.
          COMMENT  GET$VP - FETCH NOS VERSION AND PSR LEVELS*.
          COMMENT - COPYRIGHT CONTROL DATA SYSTEMS INC. 1994. 
 GET$VP   SPACE  4,10 
**        GET$VP - FETCH NOS VERSION AND PSR LEVELS.
* 
*         *GET$VP* PROVIDES AN INTERFACE BETWEEN THE NOS COMMON DECK
*         COMSVER (VIA NOSTEXT) AND SYMPL.  THIS IS NECESSARY BECAUSE 
*         COMSVER IS A MODIFY DECK AND FTP IS AN UPDATE PRODUCT.
* 
*         *SYMPL* CALL -
* 
*         GET$VP (ARRAY); 
* 
*         EXIT   (ARRAY(1)) = 10 CHARACTER STRING " NOS V.W.X", 
*                             NOS VERSION.
*                (ARRAY(2)) = 10 CHARACTER STRING "          ", 
*                             BLANKS. 
*                (ARRAY(3)) = 10 CHARACTER STRING "YYY       ", 
*                             NOS PSR LEVEL.
*                (ARRAY(4)) = 10 CHARACTER STRING "ZZZ       ", 
*                             NOS PRODUCT SET PSR LEVEL.
* 
*         USES   X -
*                A -
*                B - 1. 
  
  
 .NOSVER1 MICRO  1,10,*"NOSVER"*
 .NOSVER2 MICRO  11,11,*"NOSVER"* 
 .NOSLVL  MICRO  1,3,*"NOSLVL"* 
 .PRDLVL  MICRO  1,3,*"PRDLVL"* 
  
 GET$VP   SUBR               ENTRY/EXIT 
          SB1    1
          SA2    =10H".NOSVER1" 
          SA3    =10H".NOSVER2" 
          SA1    A1          ADDRESS OF ARRAY PARAMETER 
          BX6    X2 
          BX7    X3 
          SA6    X1          SET FIRST 10 CHARACTERS
          SA7    A6+B1       SET ELEVENTH (W/ BLANK FILL) 
          SA2    =10H".NOSLVL"
          BX6    X2 
          SA6    A7+B1       SET 3 CHARACTER PSR LEVEL (W/ BLANK FILL)
  
          SA2    =10H".PRDLVL"
          BX6    X2 
          SA6    A6+B1       SET 3 CHARACTER PSR LEVEL (W/ BLANK FILL)
  
          EQ     GET$VPX     RETURN 
  
          END 
