*DECK,GETCSP
          IDENT  GET$CSP
*CALL COPYRITE
          ENTRY  GET$CSP
          SST 
          SYSCOM B1 
          TITLE  GET$CSP - RETRIEVE *CSPW* FROM *CPA*.
          COMMENT  GET$CSP - RETRIEVE *CSPW* FROM *CPA*.
          COMMENT - COPYRIGHT CONTROL DATA SYSTEMS INC. 1994. 
 GET$CSP  SPACE  4,10 
**        GET$CSP - RETRIEVE *CSPW* FROM *CPA*. 
* 
*         *GET$CSP* RETRIEVES THE JOB-S CONTROL STATEMENT POINTER WORD
*         FROM THE JOB-S CONTROL POINT AREA USING THE *RSB* MONITOR 
*         FUNCTION. 
* 
*         *SYMPL* CALL -
* 
*         GET$CSP (CSPW); 
* 
*         ENTRY  JOB MUST HAVE AN SSJ= ENTRY POINT. 
* 
*         EXIT   (CSPW) = CONTENTS OF JOB-S CONTROL STATEMENT POINTER 
*                         WORD *CSPW*, AS DEFINED IN NOS DECK *PPCOM*.
* 
*         USES   X - 2, 6.
*                A - 2, 6.
*                B - 1. 
* 
*         MACROS SYSTEM.
  
  
 GET$CSP  SUBR               ENTRY/EXIT 
          SB1    1
          SX6    CSPW        SET UP BUFFER FOR *CSPW* READ FROM *CPA* 
          SA6    X1 
          SA2    CSPA        GET *RSB* REQUEST TEMPLATE 
          BX6    X2+X1       MERGE USER PARAMETER ADDRESS WITH REQUEST
          SA6    CSPB        SET *RSB* REQUEST
          SYSTEM RSB,R,CSPB,0  READ *CSPW* WORD INTO USER PARAMETER 
          EQ     GET$CSPX    RETURN 
  
 CSPA     VFD    12/0,12/1,18/0,18/0  *RSB* REQUEST TEMPLATE
 CSPB     BSSZ   1           *RSB* REQUEST WORD 
  
          END 
