*DECK GETCHG
          IDENT  GET$CHG
*CALL COPYRITE          CDCNET - COPYRIGHT CONTROL DATA. 1985.
          ENTRY  GET$CHG
          SYSCOM B1 
          TITLE  GET$CHG - GET CURRENT CHARGE/PROJECT NUMBERS.
          COMMENT  GET$CHG - GET CURRENT CHARGE/PROJECT NUMBERS.
          COMMENT - COPYRIGHT CONTROL DATA SYSTEMS INC. 1994. 
 GET$CHG  SPACE  4,10 
**        GET$CHG - GET CURRENT CHARGE/PROJECT NUMBERS. 
* 
*         *GET$CHG* RETURNS THE CURRENT CHARGE AND PROJECT NUMBERS IF 
*         SPECIFIED.
* 
*         *SYMPL* CALL -
* 
*         GET$CHG (CHARGE,PROJECT,VALID)
* 
*         EXIT   (CHARGE)  = CURRENT CHARGE, IF DEFINED.  ONE WORD
*                            CONTAINING 1-10 ZERO-FILLED CHARACTERS.
*                (PROJECT) = CURRENT PROJECT, IF DEFINED.  A 2-WORD 
*                            ARRAY CONTAINING 1-20 ZERO-FILLED
*                            CHARACTERS.
*                (VALID)   = VALIDATED CHARGE INDICATOR SET TO TRUE 
*                            IF CHARGE HAS BEEN VALIDATED.
* 
*         USES   X - 1, 2, 5, 6.
*                A - 1, 2, 6. 
*                B - 1. 
* 
*         MACROS GETCN. 
  
  
 GET$CHG  SUBR               ENTRY/EXIT 
          SB1    1           DEFINE B1=1
          SX5    A1          SAVE PARAMETER LIST ADDRESS
          GETCN  CHGA        GET CHARGE INFORMATION 
          SA1    X5          GET ADDRESS OF *CHARGE* PARAMETER
          SA2    CHGA        GET CHARGE NUMBER
          BX6    X2          RETURN CHARGE NUMBER TO USER 
          SA6    X1 
          SA1    A1+B1       GET ADDRESS OF *PROJECT* PARAMETER 
          SA2    A2+B1       GET FIRST HALF OF PROJECT NUMBER 
          BX6    X2          RETURN FIRST HALF OF PROJECT TO USER 
          SA6    X1 
          SA2    A2+B1       GET SECOND HALF OF PROJECT NUMBER
          BX6    X2          RETURN SECOND HALF OF PROJECT TO USER
          SA6    X1+B1
          SA1    A1+B1       GET ADDRESS OF *VALID* PARAMETER 
          SA2    A2+B1       GET VALIDATION FLAG
          AX2    59-0        SIGN-EXTEND FOR SYMPL BOOLEAN
          BX6    X2          RETURN VALIDATION FLAG TO USER 
          SA6    X1 
          EQ     GET$CHGX    RETURN 
  
 CHGA     BSSZ   4           REQUEST BLOCK FOR *GETCN* MACRO
          END 
