*DECK FFSUTBZ 
USETEXT TEXTFFS 
      FUNC FFSUTBZ (STRING, LENGTH) C(240) ;
*CALL COPYRITE
      BEGIN  # FFSUTBZ #
  
# 
**    FFSUTBZ - CHANGE TRAILING BLANKS TO ZEROS.
* 
*     'FFSUTBZ' CHANGES TRAILING BLANKS IN A STRING TO DISPLAY CODE 
*     ZEROS.
* 
*     FUNC FFSUTBZ (STRING, LENGTH) C(240)
* 
*     ENTRY  (STRING)  = STRING OF DISPLAY CODE CHARACTERS. 
*                        THE STRING MUST BEGIN ON A WORD BOUNDARY.
*            (LENGTH)  = LENGTH OF STRING IN CHARACTERS.
* 
*     EXIT   (FFSUTBZ) = STRING WITH TRAILING BLANKS CHANGED TO ZEROS 
*            (STRING)  = STRING WITH TRAILING BLANKS CHANGES TO ZEROS 
* 
*     DESCRIPTION.
* 
*     FOR EACH TRAILING BLANK IN THE STRING 
*       CHANGE THE CHARACTER TO A DISPLAY CODE 00B. 
* 
*     RETURN. 
# 
  
      ITEM STRING  C(240) ;          # DISPLAY CODE CHARACTER STRING  # 
                                     # BEGINNING ON A WORD BOUNDARY # 
      ITEM LENGTH  U;                # LENGTH OF STRING IN CHARACTERS # 
  
      ITEM CHARNDX I; 
      ITEM REPEAT  B; 
                                               CONTROL EJECT; 
      REPEAT = TRUE;
  
      FOR CHARNDX = LENGTH-1 STEP -1
        WHILE REPEAT AND CHARNDX GQ 0 
      DO
        BEGIN 
        IF C<CHARNDX, 1> STRING EQ " "
        THEN
          BEGIN 
          C<CHARNDX, 1> STRING = O"00"; 
          END 
        ELSE
          BEGIN 
          REPEAT = FALSE; 
          END 
        END 
  
      FFSUTBZ = STRING; 
  
      RETURN; 
  
      END  # FFSUTBZ #
  
      TERM
