*DECK FFSUSMS 
USETEXT TEXTFFS 
PROC FFSUSMS(RSPCN, MSG, WORDCNT);
                                                                       #
*     CDCNET - COPYRIGHT CONTROL DATA SYSTEMS INC. 1994.
                                                                       #
# TITLE FFSUSMS - SEND MESSAGE                                         #
  
      BEGIN                            # FFSUSMS                       #
  
# 
**    FFSUSMS - SEND MESSAGE. 
* 
*     TET TRAN                         05/04/88 
* 
*     THIS PROCEDURE CONVERTS (TO ASCII) A BLOCK (POSSIBLY MULTILINE
*     ONE), AND SENDS IT OUT ON THE DESTINATED CONNECTION, *RSPCN*. 
* 
*     PROC FFSUSMS(RSPCT, MSGNO, WORDCNT) 
* 
*     ENTRY   RSPCN   = CONNECTION FOR RESPONSES. 
*             MSG     = AN ARRAY CONTAINING THE MESSAGE IN DISPLAY CODE.
*             WORDCNT = LEN OF THE MESSAGE IN CM WORD.
* 
*     EXIT      *FFSLCRP* CALLED TO SEND THE MESSAGE. 
* 
# 
  
      ITEM RSPCN    S:CTYPE;           # RESPONSE CONNECTION           #
      ARRAY MSG[00:00] S(1);;          # THE MESSAGE TO SEND           #
      ITEM WORDCNT        U;           # LEN OF THE MESSAGE IN CM WORD #
  
# 
***   PROC FFSUSMS - XREF LIST BEGIN. 
# 
  
      XREF
        BEGIN 
        PROC FFSLCRP;                  # CN MGMENT REQUEST PROCESSOR   #
        PROC FFSUCDA;                  # CONVERT DISPLAY MSG TO ASCII  #
        END 
  
# 
*** 
# 
  
      ITEM CHARCNT           U;        # ASCII CHARS IN CONVERTED MSG  #
  
      CONTROL EJECT;
# 
*     START MAIN PROCEDURE. 
# 
  
      FFSUCDA(MSG, WORDCNT, SENDBUF, CHARCNT);    # CONVERT TO  ASCII  #
  
      REQ$RCODE[RFTPCM$]  = RCM"RCSENDAT";
      REQ$CTYPE[RFTPCM$]  = RSPCN;
      REQ$ADDR[RFTPCM$]   = LOC(SENDBUF); 
      REQ$LEN[RFTPCM$]    = CHARCNT;
  
      FFSLCRP;                         # SEND THE RESPONSE MESSAGE     #
  
      RETURN; 
  
      END                              # FFSUSMS                       #
  
      TERM
