*DECK FFSURFF 
USETEXT TEXTFFS;
      PROC FFSURFF (RESULT);
*CALL COPYRITE
# TITLE FFSURFF - READ FROM FILE.                                      #
  
      BEGIN                            # FFSURFF                       #
  
# 
**    FFSURFF - READ FROM FILE. 
* 
*     C. J. RAMSAY                     87/11/03 
* 
*     THIS PROCEDURE READS THE NEXT LINE FROM THE SPECIFIED FILE
*     AND CONVERTS IT FROM 6/12 ASCII TO 8/8 ASCII. 
* 
*     PROC FFSURFF (RESULT) 
* 
*     ENTRY   MBT        = FET AND CIO BUFFER FOR FILE TO READ. 
*             MBHX       = INDEX INTO MBT.
* 
*     EXIT    RESULT     = RESULT RETURN BY *READC* MACRO.
*             OUTBUF     = BUFFER CONTAINING 8/8 ASCII DATA.
*             OUTLEN     = NUMBER OF OCTETS IN OUTPUT BUFFER. 
* 
*     METHOD  READ A CODED LINE FROM THE SPECIFIED FILE.
*             IF DATA TRANSFERRED THEN CONVERT THE DATA FROM 6/12 
*             ASCII TO 8/8 ASCII AND PLACE IN THE OUTPUT BUFFER.
* 
# 
  
# 
****  PROC FFSRRFF - XREF LIST
# 
      XREF
        BEGIN 
        PROC NETUC6A;                  # CONVERT 6/12 ASCII TO ASCII   #
        PROC READC;                    # READ A CODED LINE             #
        END 
# 
****
# 
      ITEM RESULT        I;            # RESULT RETURNED BY *READC*    #
  
      ITEM NUMC          I;            # NUMBER OF CHARACTERS          #
      ITEM SIND          I;            # SOURCE INDEX                  #
      CONTROL EJECT;
# 
*     START MAIN PROCEDURE
# 
      OUTLEN = 0;                      # INITIALIZE LENGTH             #
      READC (MBT[MBHX], WORKBUF,
             WORKSIZ$+1, RESULT);      # READ CODED LINE               #
  
      IF RESULT EQ 0
      THEN
        BEGIN                          # DATA TRANSFERRED              #
        SIND = 0;                      # INITIALIZE SOURCE INDEX       #
        NETUC6A (WORKBUF, SIND, NUMC, 
                 OUTBUF, OUTLEN);      # CONVERT TO 8/8 ASCII          #
        OUTLEN = OUTLEN - 1;           # STRIP UNIT SEPARATOR          #
        END 
  
      RETURN;                          # RETURN TO CALLER              #
  
      END                              # FFSRRFF                       #
  
      TERM
