*DECK FFSUPAR 
USETEXT TEXTFFS                      # FS  SYSTEM DEFINITIONS         # 
PROC FFSUPAR (UNPAKDEST, UNPAKSRC, PACKDDEST, PACKDSRC);
*CALL COPYRITE
# TITLE FFSUPAR - FS PACK TCP ADDRESS RECORDS.                       #
  
      BEGIN  # FFSUPAR #
  
# 
**    FFSUPAR - FS PACK TCP ADDRESS RECORDS.
* 
*     CMP    02/88
* 
*     'FFSUPAR' PACKS THE TCP ADDRESS RECORDS INTO THE GATEWAY HEADER.
* 
*     PROC FFSUPAR (UNPAKDEST, UNPAKSRC, PACKDDEST, PACKDSRC) 
* 
*     ENTRY (UNPAKDEST) = POINTER TO UNPACKED DEST ADDRESS RECORD.
*           (UNPAKSRC)  = POINTER TO UNPACKED SOURCE ADDRESS RECORD.
* 
*     EXIT  (PACKDDEST) = POINTER TO PACKED DEST ADDRESS RECORD.
*           (PACKDSRC)  = POINTER TO PACKED SOURCE ADDRESS RECORD.
* 
*     DESCRIPTION.
* 
*     POINT NAM AND GATEWAY TEMPLATES.
*     CLEAR GATEWAY BUFFERS.
*     PACK THE TCP ADDRESS RECORDS INTO THE GATEWAY HEADER. 
*     RETURN. 
# 
  
      ITEM UNPAKDEST  U; # POINTER TO UNPACKED DEST ADDRESS RECORD    # 
      ITEM UNPAKSRC   U; # POINTER TO UNPACKED SOURCE ADDRESS RECORD  # 
      ITEM PACKDDEST  U; # POINTER TO PACKED DEST ADDRESS RECORD      # 
      ITEM PACKDSRC   U; # POINTER TO PACKED SOURCE ADDRESS RECORD    # 
  
      XREF
        BEGIN 
        PROC FFSUCLR;    # CLEAR MEMORY                               # 
        END 
  
                                                         CONTROL EJECT; 
# 
*     POINT NAM AND GATEWAY TEMPLATES.
# 
  
      P<T$DADR$REC> = UNPAKDEST;
      P<T$SADR$REC> = UNPAKSRC; 
      P<GW$TCP$DAD> = PACKDDEST;
      P<GW$TCP$SAD> = PACKDSRC; 
  
# 
*     CLEAR GATEWAY BUFFERS.
# 
  
      FFSUCLR (PACKDDEST, GW$TAD$SZ); 
      FFSUCLR (PACKDSRC, GW$TAD$SZ);
  
# 
*     PACK THE TCP ADDRESS RECORDS INTO THE GATEWAY HEADER. 
# 
  
      P<I$DADR$REC> = LOC (T$DADR$IPA);         # DESTINATION ADDRESS # 
        P<GW$IP$DAD> = LOC (GW$TDAD$AD);
          GW$IDAD$FU = I$DADR$FIU;
          GW$IDAD$NW = I$DADR$NET;
          GW$IDAD$HS = I$DADR$HST;
        GW$TDAD$PI = T$DADR$PIU;
        GW$TDAD$PT = T$DADR$PRT;
  
      P<I$SADR$REC> = LOC (T$SADR$IPA);         # SOURCE ADDRESS      # 
        P<GW$IP$SAD> = LOC (GW$TSAD$AD);
          GW$ISAD$FU = I$SADR$FIU;
          GW$ISAD$NW = I$SADR$NET;
          GW$ISAD$HS = I$SADR$HST;
        GW$TSAD$PI = T$SADR$PIU;
        GW$TSAD$PT = T$SADR$PRT;
  
      RETURN; 
  
      END  # FFSUPAR #
  
      TERM
