*DECK FFSUFCE 
USETEXT TEXTFFS 
      FUNC FFSUFCE B; 
*CALL COPYRITE
# TITLE FFSUFCE - UTILITY TO FIND FILE SERVER CONNECTION ENTRY         #
  
      BEGIN                            # FFSUFCE                       #
# 
**    FFSUFCE  UTILITY TO FIND FILE SERVER CONNECTION ENTRY 
* 
*     A. LIM                           88/01/15 
* 
*     THIS PROCEDURE GIVEN THE CURRENT CONNECTION NUMBER SEARCHES FOR 
*     THE CORRESPONDING FILE SERVER CONNECTION ENTRY. 
* 
*     FUNC FFSUFCE
* 
*     ENTRY    P<ACN> = PTR TO FILE SERVER CONNECTION LIST. 
*              CURACN = FILE SERVER CONNECTION NUMBER.
* 
*     EXIT     FFSUFCE = TRUE IF ENTRY FOUND. 
*                        FALSE IF ENTRY NOT FOUND.
* 
*              ACNX    = ORDINAL OF ENTRY IF ENTRY FOUND. 
*              ACNX    = UNDEFINED IF ENTRY NOT FOUND.
* 
# 
  
  
      ITEM I             I;            # LOOP INDUCTION VARIABLE       #
      CONTROL EJECT;
  
#     START MAIN PROCEDURE                                             #
  
      FFSUFCE = FALSE;                 # RETURN FALSE BY DEFAULT       #
      FOR I = 0 STEP 1                 # LOOP THRU ALL ENTRIES UNTIL   #
        WHILE I LQ NCONNECT$           # NO MORE CONNECTION ENTRIES OR #
      DO
        BEGIN                          # MATCHING ENTRY FOUND          #
        IF ACN$ACN[I] EQ CURACN 
        THEN                           # MATCHING CONNECTION NUMBER    #
          BEGIN 
          FFSUFCE = TRUE;              # FOUND MATCHING ENTRY          #
          ACNX    = I;                 # RETURN ORDINAL OF ENTRY       #
          RETURN;                      # EXIT ANY MORE SEARCHING       #
          END;
        END;
  
  
      RETURN;                          # RETURN TO CALLER              #
  
      END                              # FFSUFCE                       #
  
      TERM
