*DECK FCSUCRC 
USETEXT TEXTFCS;
      FUNC FCSUCRC B; 
*CALL COPYRITE
# TITLE FCSUCRC - UTILITY TO CHECK FOR A REMOTE CONNECTION.            #
  
      BEGIN                            # FCSUCRC                       #
  
# 
**    FCSUCRC - UTILITY TO CHECK FOR A REMOTE CONNECTION. 
* 
*     C. J. RAMSAY                     87/11/03 
* 
*     THIS PROCEDURE CHECKS IF A CONNECTION TO A REMOTE HOST EXISTS.
* 
*     FUNC FCSUCRC
* 
*     ENTRY   FTPSTATE   = FTP CURRENT STATE. 
* 
*     EXIT    FCSUCRC    = TRUE IF REMOTE CONNECTION EXISTS.
*             FCSUCRC    = FALSE IF REMOTE CONNECTION DOES NOT EXIST. 
*             FTPUSERE   = TRUE IF REMOTE CONNECTION DOES NOT EXIST.
* 
*     METHOD  CHECK FOR REMOTE HOST CONNECTION. 
*             WRITE ERROR MESSAGE IF REMOTE HOST CONNECTION DOES
*             NOT EXIST.
* 
# 
  
# 
****  FUNC FCSUCRC - XREF LIST
# 
      XREF
        BEGIN 
        PROC FCSOWOF;                  # WRITE TO OUTPUT FILE          #
        END 
# 
****
# 
      ARRAY NRCMSG [00:00] S(6);
        BEGIN 
        ITEM NRC$TEXT    C(00,00,52) =
       ["--ERROR--  CONNECTION TO REMOTE HOST DOES NOT EXIST."];
        ITEM NRC$ZBYTE   U(05,12,48) = [0]; 
        END 
      CONTROL EJECT;
# 
*     START MAIN PROCEDURE
# 
      FCSUCRC = TRUE;                  # RETURN TRUE BY DEFAULT        #
  
      IF FTPSTATE LAN FTPUOPEN  EQ 0
      THEN
        BEGIN                          # NO REMOTE CONNECTION          #
        FCSOWOF (NRCMSG[0], INTERNAL$);# WRITE MESSAGE TO OUTPUT FILE  #
        FTPUSERE = TRUE;               # SET USER ERROR FLAG           #
        FCSUCRC  = FALSE;              # RETURN FALSE TO CALLER        #
        END 
  
      RETURN;                          # RETURN TO CALLER              #
  
      END                              # FCSUCRC                       #
  
      TERM
