*DECK FCSRSPM 
USETEXT TEXTFCS;
      PROC FCSRSPM (PROMPT, MBTIDX);
*CALL COPYRITE
# TITLE FCSRSPM - SEND PROMPT MESSAGE.                                 #
  
      BEGIN                            # FCSRSPM                       #
  
# 
**    FCSRSPM - SEND PROMPT MESSAGE.
* 
*     C. J. RAMSAY                     87/11/03 
* 
*     THIS PROCEDURE SENDS A PROMPT MESSAGE TO THE PROMPT FILE. 
* 
*     PROC FCSRSPM (PROMPT, MBTIDX) 
* 
*     ENTRY   PROMPT     = PROMPT MESSAGE REQUIRED. 
*             MBTIDX     = MBT ENTRY INDEX OF FILE TO BE READ FROM. 
*             MBMX       = MBT ENTRY INDEX OF PROMPT FILE.
* 
*     EXIT    PROMPT MESSAGE WRITTEN TO PROMPT FILE.
* 
*     METHOD  THE PROMPT MESSAGE IS ONLY WRITTEN IF THE FILE TO BE
*             READ FROM IS ASSIGNED TO THE TERMINAL.
* 
# 
  
# 
****  PROC FCSRSPM - XREF LIST
# 
      XREF
        BEGIN 
        PROC WRITEC;                   # WRITE CODED LINE              #
        PROC WRITER;                   # WRITE END OF RECORD           #
        END 
# 
****
# 
      ITEM PROMPT        I;            # PROMPT MESSAGE REQUIRED       #
      ITEM MBTIDX        I;            # MBT ENTRY INDEX OF FILE READ  #
      CONTROL EJECT;
  
      ARRAY CURS$OFF [0:0] S (1);      # TURN OFF CURSOR POSITIONING   #
        BEGIN 
        ITEM CU$WDOFF    U(00,00,60) =
                          [O"00164107400000000000"];
        END 
  
      ARRAY PROMPTS [PRFIRST:PRLAST] S(3);
        BEGIN 
        ITEM PR$WORD1    U(00,00,60) =
                          [O"06242050000100000000",      # FTP/        #
                           O"00074007062420500001",      # FTP/ + BELL #
                           O"06242057575000010000",      # FTP../      #
                           O"25762376057622715555",      # USER?       #
                           O"20760176237623762776",      # PASSWORD?   #
                           O"01760376037617762576"];     # ACCOUNT?    #
        ITEM PR$WORD2    U(01,00,60) =
                          [O"00000000000000000000", 
                           O"00000000000000000000", 
                           O"00000000000000000000", 
                           O"00010000000000000000", 
                           O"17762276047155550001", 
                           O"16762471555500010000"];
        ITEM PR$WORD3    U(02,00,60) =
                          [O"00000000000000000000", 
                           O"00000000000000000000", 
                           O"00000000000000000000", 
                           O"00000000000000000000", 
                           O"00000000000000000000", 
                           O"00000000000000000000"];
        END 
      CONTROL EJECT;
# 
*     START MAIN PROCEDURE
# 
      IF MBT$DT[MBTIDX] EQ "TT" 
      THEN
        BEGIN                          # FILE ASSIGNED TO TERMINAL     #
        IF PROMPT EQ PRPASS            # TURN OFF CURSOR FOR PASS PRMT #
        THEN
          BEGIN 
          WRITEC (MBT[MBMX],
                 CURS$OFF[0]);
          END 
        WRITEC (MBT[MBMX],
                PROMPTS[PROMPT]);      # WRITE TO PROMPT FILE          #
        WRITER (MBT[MBMX]);            # FLUSH PROMPT FILE             #
        END 
  
      RETURN;                          # RETURN TO CALLER              #
  
      END                              # FCSRSPM                       #
  
      TERM
