*DECK FCSISRP 
          IDENT  FCSISRP
*CALL COPYRITE
          ENTRY  FCSISRP
          SST 
          SYSCOM B1 
  
 OPL      XTEXT  COMSRPV
  
          TITLE  FCSISRP - SETUP REPRIEVE PROCESSING. 
          COMMENT  FCSISRP - SETUP REPRIEVE PROCESSING. 
          SPACE  4,10 
***       FCSISRP - SETUP REPRIEVE PROCESSING.
* 
*         FCSISRP IS CALLED AT INITIALIZATION OF FTP TO DAYFILE A 
*         MESSAGE CONTAINING THE BUILD DATE AND TIME, AND TO
*         ESTABLISH REPRIEVE ERROR CONDITIONS AND A REPRIEVE TRANSFER 
*         ADDRESS. THE *REPRIEVE* MACRO INTERFACE IS USED TO SETUP
*         THIS INTERFACE AND TO PROCESS ABNORMAL TERMINATION. 
* 
*         ENTRY  INITIALIZATION CALL (ENTRY POINT IS FCSISRP):  
*                  NONE.
*                REPRIEVE TRANSFER (ENTRY POINT IS FCSRPV): 
*                  NONE.
* 
*         EXIT   INITIALIZATION CALL (ENTRY POINT IS FCSISRP):  
*                  THE MESSAGE MACRO HAS BEEN CALLED TO ISSUE A DAYFILE 
*                  MESSAGE CONTAINING THE BUILD DATE AND TIME.
*                  REPRIEVE (SETUP TYPE) HAS BEEN CALLED TO REPRIEVE
*                  ALL CONDITIONS EXCEPT NORMAL TERMINATION.
* 
*                ABNORMAL TERMINATION TRANSFER (ENTRY POINT IS FCSRPV): 
*                  USER BREAK 1 SEQUENCE IS IGNORED.
*                  FILE ZZZZDMB HAS BEEN CREATED CONTAINING THE 
*                  BINARY DUMP. 
*                  SYMPL ROUTINE *FCSEPES* HAS BEEN CALLED TO GRACEFULLY
*                  EXIT THE FTP CONTROL STATEMENT.
*                  REPRIEVE (RESET TYPE) HAS BEEN CALLED TO RESET THE 
*                  ERROR CONDITION AND RETURN CONTROL TO THE
*                  OPERATING SYSTEM.
* 
          SPACE  4,10 
          USE    /POINTBL/   GLOBAL POINTER TABLE FOR DEBUG 
 RPVPT    VFD    42/7HREPRIEV,18/RPVPRM 
          BSSZ   8D 
          USE    *
  
          USE    /CSBUILD/   BUILD DATE AND TIME
 BLDMSG   DIS    ,* FTP BUILT"DATE""TIME"*
          USE    *
  
 RPVPRM   VFD    48/25,12/0  REPRIEVE PARAMETER BLOCK 
          VFD    60/FCSRPV   REPRIEVE TRANSFER ADDRESS
          BSSZ   23 
  
 SYS$EQ   BSS    1           CONTENTS OF SYS EQUALS 
          EJECT 
 FCSISRP  EQ     *+1S17D     ENTRY/EXIT FOR INITIALIZATION
          SB1    1
          MESSAGE   BLDMSG,0,R         DAYFILE BUILD DATE AND TIME
          REPRIEVE  RPVPRM,SETUP,277B  INITIALIZE REPRIEVE PROCESSING 
          EQ     FCSISRP
  
  
 FCSRPV   BSS    0           REPRIEVE TRANSFER ADDRESS
          SB1    1
          MX0    -24
          SA1    RPVPRM+/COMSRPV/ERCL 
          LX1    -12
          BX1    -X0*X1      GET ERROR CLASS
          SX1    X1-/COMSRPV/TICL 
          NZ     X1,FCSRPV1  IF NOT TERMINAL INTERRUPT
          MX0    -12
          SA1    RPVPRM+/COMSRPV/OSEF 
          BX1    -X0*X1      GET OPERATING SYSTEM ERROR FLAG
          SX2    X1-TIET
          NZ     X2,FCSRPV1  IF NOT USER BREAK 1
          REPRIEVE  RPVPRM,RESUME,/COMSRPV/TICL  RESUME PROCESSING
  
  
FCSRPV1   BSS    0
          SA1    =XSYS= 
          BX6    X1          SAVE LAST CALL TO SYS EQUALS 
          SA6    SYS$EQ 
          SYSTEM DMB,R,0     DUMP FIELD LENGTH
          RJ     =XFCSEPES   EXIT PROGRAM EXECUTION SEQUENCER 
  
          REPRIEVE  RPVPRM,RESET,277B  RESET ERROR WITH NO RETURN 
  
          END 
