*DECK FCSFUSS 
USETEXT TEXTFCS;
      FUNC FCSFUSS B; 
*CALL COPYRITE
# TITLE FCSFUSS - PROCESS FTP USER SPECIFIED SEQUENCE.                 #
  
      BEGIN                            # FCSFUSS                       #
  
# 
**    FCSFUSS - PROCESS FTP USER SPECIFIED SEQUENCE.
* 
*     C. J. RAMSAY                     87/11/03 
* 
*     THIS PROCEDURE PROCESSES AN FTP USER SPECIFIED SEQUENCE.
* 
*     FUNC FCSFUSS
* 
*     ENTRY   PARMS[1]   = FTP COMMAND. 
*             PARMS[2]   = PARAMETERS ASSOCIATED WITH FTP COMMAND.
* 
*     EXIT    FCSFUSS    = TRUE IF COMMAND SEQUENCE COMPLETED OK. 
*             FCSFUSS    = FALSE IF COMMAND SEQUENCE NOT COMPLETED OK.
*             FTPERROR   = TRUE IF PROTOCOL ERROR DETECTED. 
*             FTPFAIL    = TRUE IF COMMAND FAILURE DETECTED.
* 
*     METHOD  SEND FTP COMMAND WITH PARAMETERS TO REMOTE HOST.
*             WAIT FOR RESPONSE FROM REMOTE HOST. 
* 
# 
  
# 
****  FUNC FCSFUSS - XREF LIST
# 
      XREF
        BEGIN 
        PROC FCSNODB;                  # OUTPUT DATA BLOCK             #
        PROC FCSNWFR;                  # WAIT FOR FTP REPLY            #
        PROC MESSAGE;                  # DISPLAY / DAYFILE A MESSAGE   #
        PROC NETUCAC;                  # COPY AN ASCII CHARACTER       #
        PROC NETUCAS;                  # COPY AN ASCII STRING          #
        END 
# 
****
# 
      ITEM SPACE         U = X"200000000000000";
  
      ARRAY BEGUSS [00:00] S(5);
        BEGIN 
        ITEM  BUS$TEXT   C(00,00,40) =
       [" FTP PROCESSING USER SPECIFIED SEQUENCE."];
        ITEM  BUS$ZBYTE  U(04,00,60) = [0]; 
        END 
  
      ARRAY ENDUSS [00:00] S(4);
        BEGIN 
        ITEM  EUS$TEXT   C(00,00,38) =
       [" FTP USER SPECIFIED SEQUENCE COMPLETE."];
        ITEM  EUS$ZBYTE  U(03,48,12) = [0]; 
        END 
      CONTROL EJECT;
# 
*     START MAIN PROCEDURE
# 
      MESSAGE (BEGUSS[0], 1);          # DISPLAY START MESSAGE         #
      FCSFUSS = TRUE;                  # DEFAULT TO SEQUENCE OKAY      #
# 
*     SEND FTP COMMAND TO REMOTE HOST AND WAIT FOR REPLY. 
# 
      OUTLEN = AIPIHDR$;               # INITIALIZE OUTPUT LENGTH      #
      NETUCAS (PARMS[1], 0, PARAMSZ[1], 
               OUTBUF, OUTLEN);        # COPY FTP COMMAND              #
      IF PARAMSZ[2] NQ 0
      THEN
        BEGIN                          # PARAMETERS WITH FTP COMMAND   #
        NETUCAC (SPACE, 0,
                 OUTBUF, OUTLEN);      # COPY ASCII SPACE              #
        NETUCAS (PARMS[2], 0, PARAMSZ[2], 
                 OUTBUF, OUTLEN);      # COPY THE PARAMETERS           #
        END 
      FCSNODB (AIPISC, REMOTEID);      # SEND TO REMOTE HOST           #
      FCSNWFR (REMOTEID);              # WAIT FOR RESPONSE             #
  
      MESSAGE (ENDUSS[0], 1);          # DISPLAY COMPLETE MESSAGE      #
  
      RETURN;                          # RETURN TO CALLER              #
  
      END                              # FCSFUSS                       #
  
      TERM
