*DECK FCSCQUI 
USETEXT TEXTFCS;
      PROC FCSCQUI; 
*CALL COPYRITE
# TITLE FCSCQUI - PROCESS QUIT COMMAND.                                #
  
      BEGIN                            # FCSCQUI                       #
  
# 
**    FCSCQUI - PROCESS QUIT COMMAND. 
* 
*     C. J. RAMSAY                     87/11/03 
* 
*     THIS PROCEDURE PROCESSES THE QUIT COMMAND.
* 
*     PROC FCSCQUI
* 
*     ENTRY   PARMS[1]   = ABORT MODE.
*             PARMS[2]   = STATUS VARIABLE (IGNORED). 
* 
*     EXIT    FTPERROR   = TRUE IF PROTOCOL ERROR DETECTED. 
*             FTPFAIL    = TRUE IF COMMAND FAILURE DETECTED.
*             FTPUSERE   = TRUE IF USER ERROR DETECTED. 
*             FTPSTATE   = *FTPUQUIT*.
* 
*     METHOD  IF NOT ABORTING AND REMOTE CONNECTION EXISTS THEN 
*               SEND *QUIT* FTP COMMAND TO REMOTE HOST. 
*               WAIT FOR RESPONSE FROM REMOTE HOST. 
*             UPDATE FTP USER STATE.
* 
# 
  
# 
****  PROC FCSCQUI - XREF LIST
# 
      XREF
        BEGIN 
        FUNC FCSFSCS B;                # FTP SINGLE COMMAND SEQUENCE   #
        END 
# 
****
# 
      CONTROL EJECT;
# 
*     START MAIN PROCEDURE
# 
      IF (FTPSTATE LAN FTPUOPEN NQ 0) AND 
         (PARAMNB[1] NQ OPTON$) 
      THEN                             # USER STATE OPEN AND           #
        BEGIN                          # NOT ABORTING SESSION          #
        PARAMSZ[1] = 0;                # NO PARAMETERS WITH FTP *QUIT* #
        IF FCSFSCS (FTPCQUIT, PARMS[1], REMOTEID) 
        THEN
          BEGIN                        # FTP SEQUENCE COMPLETED OK     #
          END 
        END 
# 
*     SET USER STATE TO QUITTING. 
# 
      FTPSTATE = FTPUQUIT;             # UPDATE USER STATE             #
  
      RETURN;                          # RETURN TO CALLER              #
  
      END                              # FCSCQUI                       #
  
      TERM
