*DECK FCSCDCL 
USETEXT TEXTFCS;
      PROC FCSCDCL; 
*CALL COPYRITE
# TITLE FCSCDCL - PROCESS DISPLAY_COMMAND_LIST_ENTRY COMMAND.          #
  
      BEGIN                            # FCSCDCL                       #
  
# 
**    FCSCDCL - PROCESS DISPLAY_COMMAND_LIST_ENTRY COMMAND. 
* 
*     C. J. RAMSAY                     87/11/03 
* 
*     THIS PROCEDURE PROCESSES THE DISPLAY_COMMAND_LIST_ENTRY COMMAND.
* 
*     PROC FCSCDCL
* 
*     ENTRY   PARMS[1]   = STATUS VARIABLE (IGNORED). 
* 
*     EXIT    FTPERROR   = TRUE IF PROTOCOL ERROR DETECTED. 
*             FTPFAIL    = TRUE IF COMMAND FAILURE DETECTED.
*             FTPUSERE   = TRUE IF USER ERROR DETECTED. 
* 
*     METHOD  DISPLAY ALL COMMANDS IN COMMAND NAME TABLE. 
* 
# 
  
# 
****  PROC FCSCDCL - XREF LIST
# 
      XREF
        BEGIN 
        PROC FCSOWOF;                  # WRITE TO OUTPUT FILE          #
        PROC MOVE;                     # MOVE AN AREA OF MEMORY        #
        PROC NETUCAS;                  # COPY AN ASCII STRING          #
        END 
# 
****
# 
      DEF TSIZ$          # 10 #;       # SIZE OF TEMPLATE IN WORDS     #
  
      ITEM I             I;            # LOOP INDUCTION VARIABLE       #
      ITEM CRLF          U = X"0D0A00000000000";
      ITEM SPACING       U = O"55550000000000000000"; 
  
      ARRAY HEADING [00:00] S(1); 
        BEGIN 
        ITEM HEAD$TEXT   C(00,00,08) =
       ["COMMANDS"];
        ITEM HEAD$ZBYTE  U(00,48,12) = [0]; 
        END 
  
      ARRAY TEMPLATE [00:00] S(TSIZ$); # COMMAND FORMAT TEMPLATE       #
        BEGIN 
        ITEM TEMP1       U(00,00,60) = [X"202020202020202"];
        ITEM TEMP2       U(01,00,60) = [X"020202020202020"];
        ITEM TEMP3       U(02,00,60) = [X"202020202020202"];
        ITEM TEMP4       U(03,00,60) = [X"020202020202020"];
        ITEM TEMP5       U(04,00,60) = [X"202020202020202"];
        ITEM TEMP6       U(05,00,60) = [X"020202020202020"];
        ITEM TEMP7       U(06,00,60) = [X"202020202020202"];
        ITEM TEMP8       U(07,00,60) = [X"020202020202020"];
        ITEM TEMP9       U(08,00,60) = [X"202020202020202"];
        ITEM TEMP10      U(09,00,60) = [X"020202020202020"];
        END 
      CONTROL EJECT;
# 
*     START MAIN PROCEDURE
# 
      FCSOWOF (HEADING, INTERNAL$);    # WRITE HEADING LINE            #
      FCSOWOF (SPACING, INTERNAL$);    # WRITE A BLANK LINE            #
# 
*     DISPLAY COMMANDS IN COMMAND NAME TABLE, TWO COMMANDS PER LINE.
# 
      FOR I = 1 STEP 1
        WHILE I LQ CNTSIZ$ DO 
        BEGIN                          # LOOP COMMAND NAME TABLE       #
        OUTLEN = 33;                   # ASSUME SECOND COMMAND ON LINE #
        IF I NQ ((I/2)*2) 
        THEN
          BEGIN                        # FIRST COMMAND ON LINE         #
          OUTLEN = 0;                  # INITIALIZE INDEX              #
          MOVE (TSIZ$, TEMPLATE,
                OUTBUF);               # STORE ALL SPACES IN BUFFER    #
          END 
  
        P<TBUF> = LOC(CNT$NAME[I]); 
        NETUCAS (TBUF, 0, CNT$SIZE[I],
                 OUTBUF, OUTLEN);      # COPY COMMAND NAME             #
  
        IF (I EQ ((I/2)*2)) OR
           (I EQ CNTSIZ$) 
        THEN
          BEGIN                        # LINE FULL OR LAST LINE        #
          NETUCAS (CRLF, 0, 2,
                   OUTBUF, OUTLEN);    # COPY CR + LF                  #
          FCSOWOF (OUTBUF, OUTLEN);    # WRITE LINE TO OUTPUT FILE     #
          END 
        END 
  
      FCSOWOF (SPACING, INTERNAL$);    # WRITE A BLANK LINE            #
  
      RETURN;                          # RETURN TO CALLER              #
  
      END                              # FCSCDCL                       #
  
      TERM
