*DECK DELAYTM 
          IDENT  DELAYTM
*CALL COPYRITE          CDCNET - COPYRIGHT CONTROL DATA. 1985.
          ENTRY  DELAYTM
          SYSCOM B1 
          TITLE  DELAYTM - DELAY FOR SPECIFIC AMOUNT OF TIME
          COMMENT  DELAYTM - DELAY FOR SPECIFIC AMOUNT OF TIME
          COMMENT - COPYRIGHT CONTROL DATA SYSTEMS INC. 1994. 
 DELAYTM  SPACE  4,10 
**        DELAYTM - DELAY FOR SPECIFIC AMOUNT OF TIME 
* 
*         *DELAYTM* WILL USE RECALL TO DELAY FOR A SPECIFIC AMOUNT
*         OF TIME.
* 
*         *SYMPL* CALL -
*         DELAYTM 
* 
*         ENTRY 
* 
*         EXIT   A DELAY OF ATLEAST 400 MILLISECONDS HAS
*                ELAPSED. 
* 
*         USES   X - 1, 2, 3, 6, 7. 
*                A - 1, 2, 6. 
*                B - 1
* 
*         CALLS  RECALL, RTIME
  
  
 DELAY    EQU    400         MINIMUM NUMBER OF MILLI SEC. TO DELAY
  
  
 DELAYTM  SUBR               ENTRY/EXIT 
          SB1    1           DEFINE B1=1
          RTIME  CURTIME     GET THE CURRENT TIME 
          SA1    CURTIME
          SA2    DLYTIME
          MX3    -36
          BX6    -X3*X1      USE MILLI SECONDS ONLY 
          IX6    X6+X2       ENDING TIME
          SA6    ENDTIME
 DT00     RECALL
          RTIME  CURTIME
          SA1    CURTIME     CURRENT TIME 
          SA2    ENDTIME     ENDING TIME
          MX3    -36
          BX6    -X3*X1      USE MILLI SECONDS ONLY 
          IX6    X6-X2
          NG     X6,DT00     IF TIME NOT EXPIRED
          EQ     DELAYTMX    RETURN 
  
 CURTIME  BSS    1           CURRENT TIME 
 DLYTIME  CON    DELAY       AMOUNT TO DELAY
 ENDTIME  BSS    1           ENDING TIME
  
          END 
