*COMDECK PUTIL
          TITLE  NTILN - NOTE CURRENT POSITION OF ILN 
**        NTILN - RETURN CURRENT FILE POSITION OF ILN 
* 
*         THIS IS THE INTERFACE ROUTINE CALLED BY A SYMPL PROGRAM 
*         WANTING TO KNOW THE CURRENT POSITION OF THE INTERMEDIATE
*         LANGUAGE FILE (ILN).
* 
*         THE SYMPL CALLING SEQUENCE IS 
*                XREF NTILN;
*                NTILN (FILPOS);
*                WHERE
*                FILPOS = WORD TO RETURN FILE POSITION IN 
*         HENCE THE REGISTER SETUP ON ENTRY IS
*                A1 = FWA OF APLIST 
*                X1 = ADDRESS OF FILPOS 
* 
  
 NTILN    ENTRY. ** 
          SA2    =XILN-4     CURRENT FILE POSITION
          BX6    X2 
          SA6    X1          RETURN TO CALLER 
          EQ     NTILN
          SPACE  4
**        PTILN - PUT TO INTERMEDIATE LANGUAGE FILE (ILN) 
* 
*         THIS IS THE INTERFACE ROUTINE THROUGH WHICH A SYMPL PROGRAM 
*         WRITES FROM A WORKING STORAGE BUFFER TO ILN.
*         THE SYMPL CALLING SEQUENCE TO THIS ROUTINE IS-
*                XREF PTILN;
*                PTILN (BUF); 
*                WHERE
*                BUF = WORKING STORAGE BUFFER 
*                NOTE - FIRST WORD OF BUF CONTAINS COUNT OF WORDS IN BUF
* 
*         HENCE THE REGISTER SETUP ON ENTRY IS- 
*                A1 = POINTER TO APLIST 
*                X1 = FWA OF BUF
* 
  
 PTILN    ENTRY. ** 
          SA2    X1          A WORD-COUNT WORD PRECEEDS IL-ENTRY. 
          SA3    =XILN-4     NUMBER OF WORDS ON IL FILE 
          SX2    X2 
          ZR     X2,PTILN 
          IX6    X3+X2       BUMP TO REFLECT THIS WRITE 
          SA6    A3 
          MX6    0
          SX1    X1+1        BUMP FWA WS TO OMIT RECORD SIZE
          SA6    A2          ZERO WORD COUNT
          WRITEW =XF.ILN,X1,X2
          EQ     PTILN
