*COMDECK,FA=FLSH
          CTEXT  FA=FLSH - FLUSH FILE HOLDING BUFFER
 FLSH     SPACE  4
          IF     -DEF,QUAL$,1 
          QUAL   FA=FLSH
  
  
**        FA=FLSH - FLUSH FILE HOLDING BUFFER.
* 
*         SEQUENTIAL BINARY FILE -
*           CALLS RECORD MANAGER TO EMPTY THE HOLDING BUFFER. 
*           SETS (IN) = (OUT) = (FIRST) IN PSEUDO-FET.
*           TURNS SPILL FLAG ON IN PSEUDO-FET.
* 
*         OTHER FILE TYPE - 
*           EXITS WITHOUT ACTION (HOLDING BUFFER DOES NOT EXIST). 
* 
* 
*         ENTRY  (X2) = PSEUDO-FET WORD 1 
*                (A2) = PSEUDO-FET ADDRESS
* 
*         EXIT   (X2) = PSEUDO-FET WORD 1 
*                (A2) = PSEUDO-FET ADDRESS
*                (B1) = 1 
* 
*         USES   X - 1, 3, 4, 6, 7
*                A - 1, 3, 4, 6, 7
*                B - 7
* 
*         CALLS  PUTW 
  
  
 FA=FLSH  JP     *+4S15      ** ENTRY/EXIT ** 
          IF     -DEF,B1=1,1
          SB1    1
  
          PL     X2,FA=FLSH  IF NO HOLDING BUFFER, EXIT 
          SA1    A2+B1       (X1) = HOLDING BUFFER -FIRST-
          MX7    1
          SA3    A1+B1       (X3) = HOLDING BUFFER -IN- 
          LX7    -59D+58D 
          SX6    X1 
          BX7    X7+X2
          SA6    A3          RESET -IN- = -FIRST- 
          IX3    X3-X1       NR WORDS IN BUFFER 
          SA7    A2          TURN SPILL FLAG ON 
          SA6    A6+B1       RESET -OUT- = -FIRST-
          ZR     X3,FA=FLSH  IF HOLDING BUFFER EMPTY, EXIT
          FETCH  X2,RT,X4,4 
          SB7    X4-#ST#
          ZR     B7,FLSH1    IF S TYPE RECORD 
          PUTW   X2,X1,X3 
          JP     FA=FLSH     EXIT 
  
 FLSH1    PUTWP  X2,X1,X3 
          JP     FA=FLSH     EXIT 
  
  
          IF     -DEF,QUAL$,2 
          QUAL   *
 FA=FLSH  EQU    /FA=FLSH/FA=FLSH 
          ENDX
