*COMDECK,COMCWTC
          CTEXT  COMCWTC - WRITE CODED LINE, -C- FORMAT.
 WTC      SPACE  4
          IF     -DEF,QUAL$,1 
          QUAL   COMCWTC
          BASE   D
*         COMMENT COPYRIGHT CONTROL DATA CORP. 1970.
 WTC      SPACE  4
***       WTC - WRITE CODED LINE, -C- FORMAT. 
*         G. R. MANSFIELD.  70/10/09. 
 WTC      SPACE  4
***              WTC TRANSFERRS 1 CODED LINE IN -C- FORMAT FROM A 
*         WORKING BUFFER TO A CIO BUFFER. 
*         IF THE BUFFER BECOMES SUFFICIENTLY FULL TO REQUIRE WRITING, 
*         WTC WILL PERFORM A *WRITE* FUNCTION UNLESS THE SYMBOL *WRIF$* 
*         IS DEFINED. IN THIS CASE, THE CIO FUNCTION THAT IS IN THE FET 
*         WILL BE RE-ISSUED.
* 
*         ENTRY  (X2) = ADDRESS OF FET FOR FILE.
*                (B6) = FWA WORKING BUFFER. 
* 
*         EXIT   (X2) = ADDRESS OF FET FOR FILE.
* 
*         USES   X - 1, 2, 3, 4, 6, 7.
*                B - 1, 2, 3, 4, 5, 6.
*                A - 1, 2, 3, 4, 6, 7.
* 
*         CALLS  DCB=, WTX=.
  
  
 +        EQ     WTC1 
  
 WTC=     PS                 ENTRY/EXIT 
          SA4    *-1
  
          IF     -DEF,B1=1,1
          SB1    1
  
          SA1    X2+4        (B5) = LIMIT 
          SA3    X2+B1       (X3) = FIRST 
          MX4    -12         (X4) = BYTE MASK 
          SB5    X1 
  
*         INITIALIZE REGISTERS FOR TRANSFER.
  
 WTC1     SA1    A3+2        (B4) = OUT 
          SA2    A3+B1       (X2) = IN
          SB4    X1 
  
*         TRANSFER DATA FROM WORKING BUFFER TO CIRCULAR BUFFER. 
  
 WTC2     SB3    X2+B1       (IN+1) 
          NE     B3,B5,WTC3  IF (IN+1) " LIMIT
          SB3    X3          (IN+1) = FIRST 
 WTC3     SA1    B6          NEXT WORD
          EQ     B3,B4,=XDCB= DUMP CIRCULAR BUFFER IF (IN+1) = OUT
          LX6    X1 
          SB6    B6+B1       ADVANCE WORKING BUFFER 
          BX7    -X4*X1 
          SA6    X2          STORE WORD 
          SX2    B3          IN = IN+1
          NZ     X7,WTC2     LOOP TO END OF LINE
          EQ     =XWTX=      EXIT 
          SPACE  4
          BASE   *
 QUAL$    IF     -DEF,QUAL$ 
          QUAL   *
 WTC=     EQU    /COMCWTC/WTC=
 QUAL$    ENDIF 
          ENDX
