*DECK,PHASE10 
          IDENT  PHASE10
          TITLE  PHASE10 - LOAD ANALYZER AND ALLOCATOR
          COMMENT  PHASE10 - LOAD ANALYZER AND ALLOCATOR
          SST 
          LIST   F
                                                                         PHASE10
 THISOVL  MICRO  1,, X0      OVLY THIS DECK IS (FOR CCON MACRO)          21FEB77
*CALL COMSTUF                                                            PHASE10
          SPACE  4
          ENTRY  PHASE10
 PHASE10  BSSZ   0
          SAVELWA            SAVE LWA OF (1,0) OVERLAY IN LWAX0 
          SPACE  4
*         LOAD SECONDARY OVERLAY FOR INITIALIZER
  
          LOAD   OV15,MES15 
  
          ENTRY  AFTPH15
 AFTPH15  BSS    0
          SA0    BP.INT 
          RJ     =XADDCTBP   ACCUMULATE TIME FOR START THRU INITS 
          SPACE  4
*         LOAD SECONDARY OVERLAY FOR SYNTAX ANALYZER
  
          LOAD   OV16,MES16 
  
          ENTRY  AFTPH16
 AFTPH16  BSS    0
          SA0    BP.PS1 
          RJ     =XADDCTBP   ACCUMULATE TIME FOR (1,6) (BY ITSELF)
                                                                         21FEB77
*         RESET AFREE TO ALL AVAILABLE CORE NOW THAT CODE BUFFERS ARE    21FEB77
*         FINI...                                                        21FEB77
                                                                         21FEB77
          SA2    NXTAV                                                   PHASE10
          SA1    SYMCP                                                   PHASE10
          IX6    X1-X2                                                   PHASE10
          SX6    X6-1                                                    PHASE10
          SA6    AFREE                                                   PHASE10
          SPACE  4
*         CHECK FOR ACTIVATION OF SYMPL TEXT GENERATION PROCESS 
  
          SA1    =XGENTXTF   IF GENTXTF = 0,
          ZR     X1,END14    SKIP TO END14 TO BYPASS TEXT GENERATION; 
          SA2    =XOPTION    ELSE 
          MX0    59          IF T OPTION " 0, 
          LX0    1RT
          BX3    -X0*X2 
          NZ     X3,END14    SKIP TO END14 TO BYPASS TEXT GENERATION; 
          SA2    MEL         ELSE 
          SX2    X2-EL.F     IF MEL = FATAL,
          ZR     X2,TXT1     SKIP TO TXT1 TO ISSUE DIAGNOSTIC;
*                            ELSE 
*         LOAD SECONDARY OVERLAY FOR SYMPL TEXT GENERATION
  
          LOAD   OV14,MES14 
  
          ENTRY  AFTPH14
 AFTPH14  BSS    0
  
          SA2    MEL
          SX2    X2-EL.F     IF MEL " FATAL,
          NZ     X2,END14    SKIP TO END14; 
*                            ELSE ISSUE DIAGNOSTICS.
          MESSAGE (=C* -SYMPL-  ERRORS IN TEXT GENERATION*),,R
          SA1    EITGMSG
          RJ     =XPTLSTV 
 TXT1     BSS    0
          MESSAGE (=C* -SYMPL-  SYMPL TEXT NOT WRITTEN*),,R 
          SA1    STNWMSG
          RJ     =XPTLSTV 
  
 END14    BSS    0
          SPACE  4
*         LOAD SECONDARY OVERLAY FOR DIAGNOSTIC PROCESSOR 
  
          SA1    MEL         IF MEL (MAX ERROR LEVEL FOR CURRENT
          SA2    =XHMEL      COMPILATION UNIT) IS GREATER THAN
          IX2    X2-X1       HMEL (HIGHEST MAX ERROR LEVEL FOR
          PL     X2,BEGIN17  COMPILER RUN), SET HMEL TO MEL.
          BX6    X1 
          SA6    A2 
  
 BEGIN17  BSS    0
          LOAD   OV17,MES17 
  
          ENTRY  AFTPH17
 AFTPH17  BSS    0
          SPACE  4
          SA1    =XGENTXTF   IF GENTXTF " 0,
          NZ     X1,AFTPH13  SKIP TO AFTPH13 TO BYPASS ALOCATOR.
  
  
*         LOAD SECONDARY OVERLAY FOR ALOCATOR 
  
          LOAD   OV13,MES13 
  
          ENTRY  AFTPH13
 AFTPH13  BSS    0
          EQ     =XAFTPH10   RETURN TO CONTROL
          TITLE  PHASE10 - DATA AREA
 .T       IFNE   TEST,0 
 MES13    DIS    0,+*CALL ALOCTR             CLOCK+ 
 MES14    DIS    0,+*CALL GENTEXT            CLOCK+ 
 MES15    DIS    0,+*CALL INITS              CLOCK+ 
 MES16    DIS    0,+*CALL ANZS               CLOCK+ 
 MES17    DIS    0,+*CALL DIAGIV             CLOCK+ 
 .T       ENDIF 
 DCNTUNS  ENTRY. 0           COUNT OF UNSUPPRESSED DIAG PER MODULE       PHASE10
          ENTRY  DMSGA
 DMSGA    DATA   10H ***
          BSS    11 
 DIAGNOS  ENTRY. 0
          BSSZ   4
 EXCODE   ENTRY. 0           EXECUTABLE CODE IN IL
                             SET BY CODE, USED BY GENTEXT 
 MEL      ENTRY. 0           MAX ERROR LEVEL ISSUED BY PASS1
                             FOR THE CURRENT COMPILATION UNIT.
  
 EITGMSG  VFD    60/=C+ ***  ERRORS IN TEXT GENERATION+ 
          VFD    60/=4
 STNWMSG  VFD    60/=C+ ***  SYMPL TEXT NOT WRITTEN+
          VFD    60/=3
          END    PHASE10
