*DECK             GTFW
USETEXT   TSOURCE 
USETEXT   TCEXECQ 
USETEXT   TSYMCNS 
USETEXT   TCOM37Q 
USETEXT   TCOM39Q 
USETEXT   TCOM78Q 
USETEXT   TCEXEC
USETEXT   TC7DECS 
FUNC GTFW((I));    # I=TRIAD POINTER #
                                        #RETURNS FULL WORD OVERLAY OF  #
                                        # INDEXED PART-WORD ITEM.      #
    BEGIN 
  
  
  
  
*CALL COMEX 
  
  
  
  
    ITEM I,J,K,L,M,N; 
    XREF PROC POST; 
    J=MEMR[I];
    IF AC$S[I] EQ S"EQ" THEN
         BEGIN #FULL-WORD#
         GTFW=J;
         RETURN;
         END
    IF AC$S[I] EQ S"LS" AND ICOACS[CLAS[J]] THEN
         BEGIN #FIND/GENERATE FULL-WORD OVERLAY FOR CLAS"STRG,TITM# 
         K=MAMA[J]; #CLAS"TABL" ENTRY#
         L=LOCN[J]; 
         M=BABY[K]; #FIRST STRG/TITM/OVER ENTRY#
GT00:    IF CLAS[M] EQ S"OVER" THEN 
              BEGIN 
              M=ASEQ[M];
              GOTO GT00;
              END 
GT05:    IF M NQ J THEN 
              BEGIN #NOT ITSELF#
              IF LOCN[M] EQ L AND #WORD OFFSETS SAME# 
                 BITATR[TYPE[M]] AND #VALIDATES NBIT# 
                 NBIT[M] EQ 60 THEN 
                   BEGIN #FULL-WORD OVERLAY FOUND#
                   GTFW=M;
                   RETURN;
                   END
GT10:         M=ASEQ[M];
              IF M NQ 0 THEN GOTO GT05; 
              #NO FULL-WORD OVERLAY EXISTS-CREATE ONE#
              POST(NONAM,TITM$W,N); 
              CLAS[N]=S"TITM";
             LEVL[N] = LEVL[J];   # RETAIN LEVL FOR NEWTITM  #           LARRY-R
              MAMA[N]=K;
              LOCN[N]=L;
              TYPE[N]=S"IGR"; 
              NBIT[N]=60; 
              FPRI[N]=FPRI[K];
              ASEQ[N]=BABY[K];
              BABY[K]=N;
              SBEG[N]=SBEG[J];
              GTFW=N; 
              RETURN; 
              END 
         GOTO GT10; 
         END
    GTFW=J; #CURRENT DEFAULT# 
    END 
TERM
