*DECK SM5TO 
          PROC SM5TO(FILE); 
#**       SM5TO -  SET RAW PARAMETER OF TO                             #
#                                                                      #
#     CALLING SEQUENCE-                                                #
#         CALL SM5TO(FILE)                                             #
#                                                                      #
#     GIVEN-                                                           #
#         FILE = FILE TO WHICH ORDERED RECORDS WILL BE WRITTEN, IF     #
#                 ANY RECORDS ARE LEFT AFTER OWNCODE PROCESSING.       #
#                  (MAY BE QUOTED LITERAL OR INTEGER VALUE)            #
#                                                                      #
#     DOES-                                                            #
#         IF CALLED IN THE WRONG ORDER,                                #
#             ISSUE A DIAGNOSTIC, AND                                  #
#             RETURN.                                                  #
#         SAVE RAW PARAMETER OF TYPE "TO".                             #
  
  
          BEGIN 
          ITEM  FILE         I;        # FILE OF EXCESS REC AFTER OWN/P#
          ITEM TMP     I;              #TEMP STORAGE OF RP$VALUE       #
  
          XREF
              BEGIN 
              PROC  S$ERROR;           # HANDLE A USER ERROR           #
              FUNC  S$INSEQ  B;        # TRUE IFF CALL IN SEQUENCE     #
              PROC  S$SVREL;           # SAVE RAW PARAMETER FROM RELOC.#
              PROC S$TO2;    # HANDLE PART-WORD FILE PARAMETERS        #
              END 
  
  
*CALL A 
  
*CALL E$
  
*CALL RP$ 
  
*CALL SQ$ 
  
CONTROL DISJOINT; 
  
CONTROL INERT;
  
CONTROL EJECT;
  
          S$TO2(FILE,TMP);
  
#     IF CALLED IN THE WRONG ORDER,                                    #
#         ISSUE A DIAGNOSTIC, AND                                      #
#         RETURN.                                                      #
  
  
          IF NOT S$INSEQ(SQ$"SM5TO")  THEN
              BEGIN 
              S$ERROR(E$110);          # CALL OUT OF SEQUENCE          #
#***#         RETURN; 
              END 
  
#     SET FILE OF EXCESS RECORDS LEFT AFTER OWNCODE PROCESSING         #
  
              RP$TYPE = RP$T"OUTFILE";
          RP$VALUE = TMP; 
              IF ( RP$VALUE GQ 1 ) AND ( RP$VALUE LQ 99 ) THEN
                  BEGIN 
                  IF RP$VALUE LQ 9 THEN 
                      BEGIN 
                      C<0,10>RP$VALUE = "TAPE*     "; 
                      B<24,6>RP$VALUE = O"33" + TMP;
                      B<30,30>RP$VALUE =0;
                      END 
                  ELSE
                      BEGIN 
                      C<0,10>RP$VALUE = "TAPE*     "; 
                      B<24,6>RP$VALUE = O"33" + TMP/10; 
                      B<30,6>RP$VALUE = O"33" + 
                          ( TMP - (( TMP/10)*10));
                      B<36,24>RP$VALUE = 0; 
                      END 
                  END 
          S$SVREL(RP$); 
  
          END # SM5TO # 
          TERM
