*DECK SM5E
PROC SM5E(FILE);
#**       SM5E -  SET RAW PARAMETER OF EXC                             #
#                                                                      #
#     CALLING SEQUENCE-                                                #
#         CALL SM5E(FILE)                                              #
#                                                                      #
#     GIVEN-                                                           #
#         FILE = FILE TO WHICH ERROR MESSAGES AND THEIR ASSOCIATED     #
#                 SUGGESTED CORRECTIVE CODE WILL BE WRITTEN.           #
#                                                                      #
#     DOES-                                                            #
#         IF CALLED IN THE WRONG ORDER,                                #
#             ISSUE A DIAGNOSTIC, AND                                  #
#             RETURN.                                                  #
#         SAVE RAW PARAMETER OF TYPE "E".                              #
  
  
          BEGIN 
          ITEM FILE C(10);
  
          XREF
              BEGIN 
              PROC  S$ERROR;           # HANDLE A USER ERROR           #
              FUNC  S$INSEQ  B;        # TRUE IFF CALL IN SEQUENCE     #
              PROC  S$SVREL;           # SAVE RAW PARAM. FROM RELOC.   #
              ITEM S$EFNAM; 
              END 
  
  
*CALL A 
  
*CALL E$
  
*CALL RP$ 
  
*CALL SQ$ 
  
CONTROL DISJOINT; 
  
CONTROL INERT;
  
CONTROL EJECT;
  
  
#     IF CALLED IN THE WRONG ORDER,                                    #
#             ISSUE A DIAGNOSTIC, AND                                  #
#             RETURN.                                                  #
  
  
          IF NOT S$INSEQ(SQ$"SM5E")  THEN 
              BEGIN 
              S$ERROR(E$110);          # CALL OUT OF SEQUENCE          #
#***#         RETURN; 
              END 
  
#     SET FILE OF ERROR MESSAGE AND ASSOCIATED SUG. CORRECTIVE CODE    #
  
          IF FILE EQ "$NULL" THEN 
              S$EFNAM = "0";           # SIGNAL FOR NULL               #
          ELSE
              S$EFNAM = FILE; 
  
  
          END # SM5E #
          TERM
