*DECK S$TO2 
          IDENT  S$TO2
          TITLE  S$TO2 -  SECONDARY PROCESS FOR SM5TO 
          COMMENT  SECONDARY PROCESS FOR SM5TO
          SPACE  4
**        S$TO2 -  SECONDARY PROCESS FOR SM5TO
* 
*     CALLING SEQUENCE- 
*         S$TO2(FILE,TMP);
* 
*     GIVEN-
*         FILE = SPECIFICATION OF A FILE NAME.
*         TMP  = A TEMPORARY VARIABLE TO HOLD THE GOOD FILE NAME
* 
*     DOES- 
*         MAKES SURE THAT FILE IS LEFT-ALIGNED AND BLANK
*         FILLED WITHIN THE NEW VARIABLE TMP. ALLOWS FOR
*         PART-WORD PARAMETERS A LA FORTRAN CHAR ARRAYS 
  
  
          ENTRY  S$TO2
 S$TO2    SUBR
          SB1    1           CONSTANT 1 
          SA2    A1          GET ADDRESS OF PARAMETER IN X2 
          MX4    -18
          BX0    X4*X2       SEE IF WE HAVE PART-WORD INFORMATION 
          ZR     X0,OK
* FETCH BEGINNING CHARACTER POSITION IN BITS 24-27
          LX0    36 
          MX2    -4 
          BX2    -X2*X0      BCP IN X2
          SX3    6
          IX2    X3*X2       BCP IN BITS
          SB2    X2          FOR MNS= 
          SB4    0           FOR MNS= 
* FETCH LENGTH IN CHARACTERS FROM BITS 30-47
          LX0    -6 
          MX2    -18
          BX2    -X2*X0      LENGTH IN X2 
          IX0    X2*X3       LENGTH IN BITS, FOR MNS= 
          SA2    A1          SOURCE FIRST WORD ADDRESS IN X2
          SA4    A1+B1
          SX7    B6 
          SA7    SAVEB6 
          SX7    A1 
          SA7    SAVEA1 
          SA3    =10R 
          BX7    X3 
          SA3    A1+B1
          SA7    X3 
          CALL   MNS= 
          SA1    SAVEA1 
          SA1    X1 
          SA2    SAVEB6 
          SB6    X2 
          EQ     NOTOK
OK        SA3    A2+B1
          SA2    X2          GET VALUE INTO X2
          BX7    X2 
          SA7    X3          SET TMP := FILE
NOTOK     EXIT
  
 SAVEB6   BSS    1
 SAVEA1   BSS    1
  
          END 
