*DECK S$STRPV 
          IDENT  S$STRPV
          TITLE  S$STRPV - SET REPRIEVE PROCESSING
          COMMENT SET REPRIEVE PROCESSING 
          SPACE  4
**        S$STRPV - SET ADDRESSES FOR REPRIEVE PROCESSING 
* 
*    CALLING SEQUENCE-
*         S$STRPV;
* 
*    GIVEN- 
*         NOTHING 
* 
*    DOES-
*         SETS REPRIEVE PROCESSING TO RETURN SORT 5'S INTERNAL
*         FILES FOR ALL  INTERRUPT/ERROR CONDITIONS 
* 
  
  
          ENTRY  S$STRPV
S$STRPV   SUBR
          IFNOS 
  
***************************************************** 
* 
* PLEASE CONSULT THE NOS R.M. PAGES 2-10-6 THRU 2-10-10 
* (VOLUME TWO) FOR A GUIDE TO THE BIT FORMATS 
* 
***************************************************** 
  
          REPRIEVE  ST5BLOK,SET,277B
*         ALL DONE
  
          EXIT
******************************* 
* HERE IS THE REPRIEVE BLOCK -- 
******************************* 
  
ST5BLOK   VFD    36/0,12/25,2/0,9/1,1/0 
          VFD    42/0,18/CHOICE 
          DATA   0
          VFD    24/277B,36/0       ALL ERROR EXITS - MASK 277B 
          BSSZ   21 
  
  
**********************************************
* THIS IS THE CODE EXECUTED WHENEVER AN ERROR 
* OCCURS. THE LABEL IS -CHOICE- BECAUSE IT TURNS
* OUT THAT A TERMINAL INTERRUPT IS AN ERROR WHEN
* HANDED FROM RPV TO YOU, BUT IF YOU TRY TO DO A RESET
* ON RPV AFTER A TERMINAL INTERRUPT, IT CHANGES ITS 
* MIND AND DECIDES THAT IT WASN'T AN ERROR AND THEREFORE
* A RESET IS ILLEGAL AND IT GIVES YOU THE NICE MESSAGE
* 'RPV - ILLEGAL CALL' IN THE DAYFILE. THEREFORE, THE 
* CODE BELOW INTERCEPTS THE ERROR CODE FROM RPV AND 
* EXAMINES IT TO SEE IF IT IS A TERMINAL INTERRUPT OR NOT 
************************************************* 
  
CHOICE    SA1    ST5BLOK+3   WORD WITH ERROR CODE 
          MX2    -10         COMPLEMENT OF 10-BIT MASK
          BX3    -X2*X1      X3 = ERROR CODE
          SX4    37B
          IX5    X4-X3
          PL     X5,FLINGEM 
*  IF WE GET HERE, WE HAVE A TERMINAL INTERRUPT - 40B 
          CALL   S$RTNFL     RETURN INTERNAL FILES
  
*  "ABORT" ALLOWS SYSTEM TO CONTINUE JOB PROCESSING WITH THE CONTROL
*  STATEMENT THAT IMMEDIATELY FOLLOWS THE EXIT STATEMENT. 
*  "ENDRUN" REQUESTS NORMAL TERMINATION; JOB IS TERMINATED WHEN THERE 
*  ARE NO MORE CONTROL STATEMENTS OR THE NEXT STATEMENT IS AN EXIT. 
          MESSAGE (=C$SORT5 - TERMINAL INTERRUPT$)
          ABORT 
  
  
FLINGEM   CALL   S$RTNFL     RETURN INTERNAL FILES
          REPRIEVE  ST5BLOK,RESET,277B
          ENDRUN
  
          ELSE               *IF NOS-BE INSTALLATION
* 
*         ALL SORTS OF GOOD CODE FOR NOS-BE SHOULD GO HERE
* 
          EXIT
* 
* 
          ENDIF 
          END 
