*DECK S$STFIT 
          IDENT  S$STFIT
          TITLE  S$STFIT -  SET FIT 
          COMMENT  SET FIT
          SST                ACCESS #IO#
          B1=1
          SPACE  4
**        S$STFIT -  SET FIT
* 
*     CALLING SEQUENCE- 
*         S$STFIT(<ADDRESS FOR FIT>, <FILE NAME>);
* 
*     DOES- 
*         LEAVES BFS=0 UNLESS BFS IS SPECIFIED ON THE FILE CONTROL STMT.
****      SETS PROCESSING DIRECTION.
  
  
          ENTRY  S$STFIT
 S$STFIT  SUBR
          SB1    1           CONSTANT 1 
          SA2    X1          ADDRESS OF FIT 
          BX6    X2          SAVE ADDRESS LOCALLY 
          SA6    FITADDR
          SA3    A1+B1       ADDRESS OF FILE NAME 
          SA3    X3          FILE NAME
          MX0    42          77777777777777000000B
          BX3    X0*X3       KEEP ONLY LEFT 7 CHARACTERS
          MX6    0           ZERO 
          SB7    41-1        FITSIZE-1
 STFIT1   SA6    X2+B7       CLEAR ANOTHER WORD IN FIT
          SB7    B7-B1       DECREMENT INDEX
          GE     B7,B0,STFIT1    IF MORE WORDS,LOOP 
  
  
* SET DEFAULT BT=C, RT=Z, FL=150
* WILL BE OVERRIDDEN BY ANY FILE CONTROL CARD.
  
          STORE  X2,BT=C
          STORE  X2,RT=Z
          STORE  X2,FL=150
          STORE  X2,MRL=150 
  
          STORE  X2,LFN=X3
          STORE  X2,BFS=2001B 
          STORE  X2,ERL=1 
          SETFIT X2 
          SA2    FITADDR     ADDRESS OF FIT 
          FETCH  X2,BFS,X6
          SX5    X6-1 
          IFTHEN X5=0        IF USER DID NOT SET BFS, 
            STORE  X2,BFS=0    LEAVE BFS=0
            ENDIF.
          FETCH  X2,PD,X6 
          SX5    X6-#IO#
          IFTHEN X5"0        IF PROCESSING DIRECTION NOT INPUT-OUTPUT,
            STORE  X2,PD=INPUT
            ENDIF.
          STORE  X2,DFC=3    DAYFILE CONTROL = EVERYTHING 
          STORE  X2,EFC=3    ERROR FILE CONTROL = EVERYTHING
  
          EXIT
 FITADDR  BSS    1           ADDRESS OF FIT 
  
  
          EXIT
  
  
          END 
