*DECK S$LOADS 
          IDENT  S$LOADS
          TITLE  S$LOADS -  LOAD AND EXECUTE S$ERR FROM STATIC
          COMMENT  LOAD AND EXECUTE S$ERR FROM STATIC 
          SPACE  4
**        S$LOADS -  LOAD AND EXECUTE S$ERR FROM STATIC 
* 
*     CALLING SEQUENCE- 
*         S$LOADS("<NAME>");
*         S$LOADS(ENUM, STRING$, VAL);
*     DOES- 
*         LOADS AND EXECUTES CAPSULE S$ERR. 
* 
  
          ENTRY  S$LOADS
 S$LOADS  SUBR
  
          SX6    A1          SAVE ADDRESS OF ACTUAL PARAMETER LIST
          SA6    APLIST 
  
*     NOTE ELAPSED TIME AND CP TIME   (OPTION)
  
          IFPERFM              IF PERF MEASUREMENT WANTED 
            SX6    1           CODE FOR STARTING TO LOAD A CAPSULE
            SX1    =10HS$ERR
            CALL   S$P         WRITE INFO TO *ZZZZZ3U*, *ZZZZZ3V* 
            ENDIF 
  
*     LOAD THE CONTROL ROUTINE FOR RELOCATABLE SORTS
  
          SA1    GROUP       42/0L_GROUP-NAME, 18/GROUP-SIZE
          SA2    =0LS$ERR    42/0L_CAPSULE-NAME, 18/0 
          SX3    LIBLIST     ADDRESS OF LIST OF LIBRARIES 
          SX4    S$PASS      ADDRESS OF LIST OF ADDRESSES OF PASSLOCS 
          CALL   FDL.LDC     LOAD THE MAIN CAPSULE
  
*     MAKE SURE THE CAPSULE WAS LOADED
  
          SB7    X6          LOOK AT FDL ERROR NUMBER 
          SB6    6           (ERROR NUMBER FOR *ALREADY LOADED*)
          IFTHEN B7"0        IF NOT NORMAL LOAD 
           ANDIF B7"B6        AND NOT ALREADY LOADED, 
            MESSAGE (=C$ SORT-  SYSTEM ERROR$),,RECALL
            MESSAGE (=C$ SORT-  BAD SRT5LIB$),,RECALL 
            ABORT 
            ENDIF.
  
*     NOTE ELAPSED TIME AND CP TIME   (OPTION)
  
          IFPERFM              IF PERF MEASUREMENT WANTED 
            SX6    2           CODE FOR FINISHING LOADING A CAPSULE 
            SX1    =10HS$ERR
            CALL   S$P         WRITE INFO TO *ZZZZZ3U*, *ZZZZZ3V* 
            ENDIF 
  
*     EXECUTE S$ERR 
  
          SA1    APLIST 
          SA1    X1          ADDRESS OF (ENUM, STRING$, VAL)
          SA2    S$ERR$+1    ADDRESS OF S$ERR 
          SB7    X2 
          SA3    S$LOADS     RETURN INSTRUCTION 
          BX6    X3 
          SA6    B7          STORE RETURN INSTRUCTION FROM S$ERR
          JP     B7+1        EXECUTE S$ERR, RETURNING TO CALLER OF S$LOADS
          SPACE  4
  
 APLIST   BSS    1           ADDRESS OF ACTUAL PARAMETER LIST 
  
*CALL CAPLIB
  
 S$ERR$   EXTERNAL
  
          SPACE  4
          END 
