*DECK S$LOAD
          IDENT  S$LOAD 
          TITLE  S$LOAD  -  LOAD A CAPSULE
          COMMENT  LOAD A CAPSULE 
          SPACE  4
**        S$LOAD  -  LOAD A CAPSULE 
* 
*     CALLING SEQUENCE- 
*         S$LOAD ("<NAME>") ; 
* 
*     DOES- 
*         LOADS CAPSULE NAMED <NAME>. 
* 
  
          ENTRY  S$LOAD 
  
*     NOTE ELAPSED TIME AND CP TIME   (OPTION)
  
 S$LOAD   SUBR               ENTRY/EXIT WORD
  
*     NOTE CP AND ELAPSED TIME  (OPTION)
  
          IFPERFM              IF PERF MEASUREMENT WANTED 
            SX6    X1          SAVE ORIGINAL VALUE OF X1 FOR LATER
            SA6    SAVEX1 
            SX6    1           CODE FOR STARTING TO LOAD A CAPSULE
                               X1 = ADDRESS OF (10H_CAPSULE-NAME) 
            CALL   S$P         WRITE INFO TO *ZZZZZ3U*, *ZZZZZ3V* 
           *SAVES  AX1
            ENDIF 
  
*CALL ZFN 
  
*     LOAD THE CONTROL ROUTINE FOR RELOCATABLE SORTS
  
          SA1    GROUP       42/0L_GROUP-NAME, 18/GROUP-SIZE
*                     X2 HAS 42/0L_CAPSULE-NAME, 18/0 
          SX3    LIBLIST     ADDRESS OF LIST OF LIBRARIES 
          SX4    S$PASS      ADDRESS OF LIST OF ADDRESSES OF PASSLOCS 
          CALL   FDL.LDC     LOAD THE MAIN CAPSULE
  
*     MAKE SURE THE CAPSULE WAS LOADED
  
          SB7    X6          LOOK AT FDL ERROR NUMBER 
          SB6    6           (ERROR NUMBER FOR *ALREADY LOADED*)
          IFTHEN B7"0        IF NOT NORMAL LOAD 
           ANDIF B7"B6        AND NOT ALREADY LOADED, 
            MESSAGE (=C$ SORT-  SYSTEM ERROR$),,RECALL
            MESSAGE (=C$ SORT-  BAD SRT5LIB$),,RECALL 
            ABORT 
            ENDIF.
  
*     NOTE CP AND ELAPSED TIME   (OPTION) 
  
          IFPERFM              IF PERF MEASUREMENT WANTED 
            SX6    2           CODE FOR FINISHING LOADING A CAPSULE 
            SA1    SAVEX1      X1 = ADDRESS OF (10H_CAPSULE-NAME) 
            CALL   S$P         WRITE INFO TO *ZZZZZ3U*, *ZZZZZ3V* 
            ENDIF 
  
*     EXIT FROM S$LOAD
  
          EXIT
          SPACE  4
          IFPERFM              IF PERF MEASUREMENT WANTED 
 SAVEX1   BSS    1           FOR ORIGINAL VALUE OF X1 
          ENDIF 
  
*CALL CAPLIB
          SPACE  4
          END 
