*DECK S$GTRES 
          PROC S$GTRES(LINE$);
#**       S$GTRES -  GETS RESPONSE FROM INTERACTIVE USER               #
#                                                                      #
#     CALLING SEQUENCE-                                                #
#         S$GTRES(LINE$):                                              #
#                                                                      #
#     GIVEN-                                                           #
#         LINE$ = ONE LINE CONSISTING OF A CHARACTER AND A STRING OF   #
#                 CHARACTERS WITH A TERMINATOR OF SOME KIND.           #
#     DOES-                                                            #
#         GETS A LINE FROM A INTERACTIVE USER                          #
  
          BEGIN 
  
          DEF  COM           #CONTROL NOLIST;#; 
          DEF  ENDCOM        #CONTROL LIST;#; 
  
#LINE$#   COM   # LINE MADE UP OF LINES IN QUERY$ THAT IS P/OUT TO USER#
  
          ARRAY LINE$ [1:1] S(9); 
              BEGIN 
              ITEM LINE$LINE     C(1, 0,80);     # LEFT-JUSTIFIED LINE #
              ITEM LINE$LENGTH   I(0,30,30);     # LENGTH IN CHARACTERS#
              END 
  
#LINE$#   ENDCOM
  
          XREF
              BEGIN 
              PROC S$GTWRD;            # GET WORD FROM TERMINAL        #
              PROC S$PRMPT;            # PUT PROMPT TO TERMINAL        #
              END 
          ITEM  I           I;         # SCRATCH VARIABLE              #
          ITEM  II          I;         # SCRATCH VARIABLE              #
          ITEM  WORD         C(10);    # VALUE PASSED TO S$PUTWD       #
  
CONTROL DISJOINT; 
  
CONTROL INERT;
  
CONTROL EJECT;
  
          LINE$LENGTH = 80; 
          LINE$LINE = " ";
          S$PRMPT;   #  PUT PROMPT ON NOSBE IF NECESSARY               #
          FOR I=0 STEP 10 UNTIL 70  DO
              BEGIN 
              S$GTWRD(WORD);
              C<I,10>LINE$LINE = WORD;
              IF B<48,12>WORD EQ 0  THEN
                  BEGIN 
                  FOR I = I+9 WHILE C<I,1>LINE$LINE EQ 0 DO 
                      BEGIN 
                      C<I,1>LINE$LINE = " ";  # CHANGE : TO BLANK # 
                      I = I - 1;
                      END 
#***#             RETURN; 
                  END 
              END 
          FOR I=I WHILE B<48,12>WORD NQ 0  DO 
              S$GTWRD(WORD);
  
          END # S$GTRES # 
          TERM
