*DECK S$GTJCR 
          IDENT   S$GTJCR 
          TITLE  S$GTJCR -  GET JOB CONTROL REGISTERS 
          COMMENT  GET JOB CONTROL REGISTERS
          SPACE  4
**        S$GTJCR -  GET JOB CONTROL REGISTERS
* 
*     CALLING SEQUENCE- 
*         S$GTJCR(R1, R2, R3, R1G, EFG, EF);
* 
*     GIVEN-
*         R1, R2, R3, R1G, EFG AND EF = INTEGER VARIABLES.
* 
*     DOES- 
*         SETS R1, R2, R3, R1G, EFG AND EF TO THE UNSIGNED VALUE
*          OF THE ASSOCIATED JOB CONTROL REGISTERS. 
  
  
          ENTRY  S$GTJCR
 S$GTJCR  SUBR
          SA0    A1          SAVE ADDRESS OF ACTUAL PARAMETER LIST
  
          LIST   F
          IFNOS              IF NOS OPERATING SYSTEM
            GETJCI  ADDR
          ELSE               IF NOS/BE OPERATING SYSTEM 
            MX6    0           CLEAR COMPLETE BIT 
            SA6    ADDR 
            GETJCI  ADDR
            ENDIF 
  
          SA2    R3R2R1      6/EF, 18/R3, 18/R2, 18/R1
          LX2    6
          MX0    -6          77777777777777777700B
          BX6    -X0*X2 
          SA1    A0+5 
          SA6    X1          EF 
  
          MX0    -18         77777777777777000000B
          LX2    18 
          BX6    -X0*X2 
          SA1    A0+2 
          SA6    X1          R3 
  
          LX2    18 
          BX6    -X0*X2 
          SA1    A0+1 
          SA6    X1          R2 
  
          LX2    18 
          BX6    -X0*X2 
          SA1    A0 
          SA6    X1          R1 
  
          SA2    ADDR        6/EFC, 18/R1G, 36/...
          LX2    6
          MX0    -6 
          BX6    -X0*X2 
          SA1    A0+4 
          SA6    X1          EFG
  
          LX2    18 
          MX0    -18
          BX6    -X0*X2 
          SA1    A0+3 
          SA6    X1          R1G
  
          EXIT
  
  
 ADDR     BSS    1
 R3R2R1   BSS    1
  
  
          END 
