*DECK S$GTIKD 
          PROC S$GTIKD(RP$);
#**       S$GTIKD -  INTERACTIVELY INFORMS USER ABOUT MISC. DEFAULTS   #
#                                                                      #
#     CALLING SEQUENCE-                                                #
#         S$GTIKD(RP$):                                                #
#                                                                      #
#     DOES-                                                            #
#         INFORMS USER IN REGARDS TO MISCELLANEOUS DEFAULTS SUCH AS    #
#         FILE BLOCK TYPE, RECORD TYPE AND FL                          #
  
          BEGIN 
  
  
*CALL A 
  
*CALL QUERY$
  
*CALL RP$ 
  
*CALL RSFLAGS 
  
          XREF
              BEGIN 
              PROC  S$ABORT;           # HANDLE INTERNAL ABORT ERROR   #
              PROC  S$ANSYN;           # GETS Y/N ANSWER FROM I/U      #
              PROC  S$DTCLK;           # GET SYSTEM DATE & TIME        #
              PROC  S$PTQUE;           # PUT QUERY TO USER             #
              PROC  S$QUIT;            # SORT/MERGE TERMINATION        #
  
              ITEM S$HLP   I;    # DETERMINE WHAT HELP IS GIVEN        #
              END 
  
          ITEM  YES          B;        # INDICATE RESPONSE TO S$ANSYN  #
          ITEM  GDSW         I; 
          ITEM  DATE         C(10);    # YEAR/MONTH/DATE               #
          ITEM  TIME         C(10);    # HOUR.MINUTE.SECOND            #
  
CONTROL DISJOINT; 
  
CONTROL INERT;
  
CONTROL EJECT;
  
#      CHECK FLAG, IF FIRST TIME OR RESTART THEN RESET SWITCH          #
  
          IF B<58,1>S$FLAGS EQ 0 THEN 
              BEGIN 
              GDSW = 1;                # RESET SWITCH FOR GTIKD        #
              B<58,1>S$FLAGS = 1;      # CHANGE FLAG                   #
              END 
  
# GET SYSTEM DATE AND TIME TO PRINT OUT HEADER                         #
  
          S$DTCLK(DATE, TIME);
  
          QUERY$LINE[1] = " SORT/MERGE 5.0";
          C<20,10>QUERY$LINE[1] = DATE; 
          C<35,10>QUERY$LINE[1] = TIME; 
          QUERY$LLINE[1] = 45;
          QUERY$LINE[2] = " ";
          QUERY$LLINE[2] = 1; 
          QUERY$NLINES = 2; 
          S$PTQUE(QUERY$);
  
  
# TELL USER ABOUT DEFAULTS BT=C,RT=F,FL=150 FOR SORT FILES             #
  
          QUERY$LINE[1] = 
          "IS YOUR TERMINAL ALREADY SET TO NORMAL MODE OR UPPERCASE   ";
          QUERY$LLINE[1] =  56; 
          QUERY$LINE[2] = 
          "ASCII MODE. ALSO, ARE YOU SURE THAT ALL YOUR FILES (IF ANY)";
          QUERY$LLINE[2] = 59;
          QUERY$LINE[3] = 
          "ARE EITHER STANDARD UNIT RECORD FORMAT OR HAVE HAD FILE    ";
          QUERY$LLINE[3] =  55; 
          QUERY$LINE[4] = "CONTROL STATEMENTS SPECIFIED FOR THEM      ";
          QUERY$LLINE[4] = 37;
          QUERY$NLINES = 4; 
          S$HLP = 100;
          S$ANSYN(QUERY$, YES); 
          IF NOT YES THEN 
              BEGIN 
              QUERY$LINE[1] = 
       "UNLESS YOU SPECIFIED OTHERWISE, ALL INPUT FILES AND THE OUTPUT";
              QUERY$LLINE[1] = 62;
              QUERY$LINE[2] = 
         "FILE ARE ASSUMED TO HAVE STANDARD UNIT RECORD FORMAT SUCH AS";
              QUERY$LLINE[2] = 60;
              QUERY$LINE[3] = 
          "LINES TYPED FROM A TERMINAL, LINES IN A BATCH JOB, OR LINES";
              QUERY$LLINE[3] = 59;
              QUERY$LINE[4] = 
      "TO BE PRINTED ON A PRINTER OR A TERMINAL. THESE ARE TECHNICALLY";
              QUERY$LLINE[4] = 63;
              QUERY$LINE[5] = 
            "KNOWN AS BT=C, RT=Z, FL=N WITH N NO MORE THAN 150. DO YOU";
              QUERY$LLINE[5] = 57;
              QUERY$LINE[6] = 
          "HAVE ANY FILES THAT ARE NOT OF THIS FORMAT"; 
              QUERY$LLINE[6] = 42;
              QUERY$NLINES = 6; 
              S$HLP = 105;
              S$ANSYN(QUERY$, YES); 
              IF YES THEN 
                  BEGIN 
                  QUERY$LINE[1] = 
          "FOR EACH FILE THAT IS NOT OF THIS FORMAT YOU MUST HAVE"; 
                  QUERY$LLINE[1] = 54;
                  QUERY$LINE[2] = 
          "SPECIFIED A FILE CONTROL STATEMENT. SORT/MERGE WILL QUIT"; 
                  QUERY$LLINE[2] = 56;
                  QUERY$LINE[3] = "NOW SO YOU MAY DO SO.";
                  QUERY$LLINE[3] = 21;
                  QUERY$NLINES = 3; 
                  S$PTQUE(QUERY$);
                  S$QUIT; 
                  END 
              END 
  
# SET RP$TYPE TO $END$ TO INDICATE END OF S$GTIKD                      #
  
  
          RP$TYPE = RP$T"$END$";
#***#     RETURN; 
  
          END # S$GTIKD # 
          TERM
