*DECK S$GNSMB 
          IDENT  S$GNSMB
          COMMENT GENERATE SUMMING SETUP FOR BUFFER 
  
*CALL LBLPTR
  
**        S$GNSMB- GENERATE SUMMING SETUP FOR BUFFER
**
*     CALLING SEQUENCE- 
*         S$GNSMB(LR) 
* 
*     GIVEN-
*         LR = NUMBER OF BITS TO HOLD INDEX TO RSA
* 
*     DOES- 
*         GENERATE CODE TO SET UP POINTER TO FIRST WORD OF
*         EACH INTERNAL RECORD IN BUFFER.  POINTERS ARE 
*         IN REGISTERS B4 AND B6, FOR LL AND CR,
*         RESPECTIVELY.  (PLAGIARIZED FROM GNCMPB IN
*         S$GNCMP.) 
* 
*     GENERATED CODE EXPECTS REGISTERS- 
*         SAME AS S$GNSMA, WITHOUT X2.
  
  
          ENTRY  S$GNSMB
 S$GNSMB  SUBR
          SB1    1           CONSTANT 1 
  
*         SET UP REGISTERS
  
          SA4    X1          X4 = LR
          BX5    -X4         X5 = -LR 
  
          GEN    (MX0 60),X5           (X0 = MASK 60-LR)
          GEN    (SX2 7)               (X2 = LEN OF EACH IM FET)
          GEN    (SA3 "NFILES")        (X3 = LTRN)
  
*         OBTAIN ADDRESS OF FIRST WORD OF CR BUFFER 
  
          GEN    (BX5 X6)              (X5 = CR DESCRIPTOR) 
          GEN    (LX5 1+1),X4          *LX5 1+1+LR
          GEN    (BX5 -X0*X5)          (X5 = REC. NO. FOR CR) 
          GEN    (IX5 X5*X2)           (X5 = RN*(LENGTH OF FET))
          GEN    (IX5 X5+X3)           (+ OFFSET FROM WSA)
          GEN    (SA5 X5+B2)           (A5 = ADDRESS OF FET)
          GEN    (SX7 A5)              *SAVE FET OF CR
          GEN    (SA7 "FETOFCR")       *FOR LATER USE 
          GEN    (SA5 A5+3)            (X5 = OUT POINTER) 
          GEN    (SB6 X5)              (B6 = ADDRESS) 
  
*         OBTAIN ADDRESS OF FIRST WORD OF LL BUFFER 
  
          GEN    (BX5 X4)              (X5 = LL DESCRIPTOR) 
          GEN    (LX5 1+1),X4          *LX5 1+1+LR
          GEN    (BX5 -X0*X5)          (X5 = REC. NO. FOR LL) 
          GEN    (IX5 X5*X2)           (X5 = RN*(LENGTH OF FET))
          GEN    (IX5 X5+X3)           (+ OFFSET FROM WSA)
          GEN    (SA5 X5+B2)           (A5 = ADDRESS OF FET)
          GEN    (SX7 A5)              *SAVE FET OF LL
          GEN    (SA7 "FETOFLL")       *FOR LATER USE 
          GEN    (SA5 A5+3)            (X5 = OUT POINTER) 
          GEN    (SB4 X5)              (B4 = ADDRESS) 
  
          EXIT
          END 
