*DECK S$GNRZR 
          IDENT  S$GNRZR
          TITLE  S$GNRZR -  GENERATE- ZERO OUT THE EXTERNAL RECORD
          COMMENT  ZERO OUT THE EXTERNAL RECORD 
  
*CALL LBLPTR
  
          SPACE  4
**        S$GNRZR -  GENERATE- ZERO OUT THE EXTERNAL RECORD 
* 
*     CALLING SEQUENCE- 
*         S$GNRZR(LENGTH);#(S$OREC)#
* 
*     GIVEN-
*         LENGTH = BIT LENGTH OF EXTERNAL RECORD  (BYTE*SPEC$MRL).
*         S$OREC = WORD OFFSET IN WSA$ FOR EXTERNAL RECORD. 
* 
*     DOES- 
*         GENERATES CODE. 
* 
*     GENERATED CODE EXPECTS- 
*         *B1 = 1.
*         *B2 = ADDRESS OF WORKING STORAGE AREA (WSA$). 
* 
*     GENERATED CODE DOES-
*         STORES BINARY ZEROS INTO THE EXTERNAL RECORD. 
* 
*     GENERATED CODE USES-
*         B    * * - - - - -    *B1=1, *B2=WSA$ 
*         X  0 - - - - - - 7
*         A  - - - - - - - 7
  
  
          ENTRY  S$GNRZR
 S$GNRZR  SUBR
          SB1    1           SET B1=1 FOR *GEN* 
  
*     SET X5 = NUMBER OF WORDS AFTER THE FIRST WORD 
  
          SA5    X1          VALUE OF LENGTH
          SX5    X5-1        LENGTH-1 
          SX0    1S22/60+1   1/60 * 2**22 
          IX5    X5*X0       (LENGTH-1)/60 * 2**22
          AX5    22          (LENGTH-1)/60
  
*     GENERATE THE CODE 
  
          GEN    (MX7 0)
          SA1    S$OREC 
          GEN    (SA7 B2+0),X1
          IFTHEN X5"0        IF MORE THAN ONE WORD IN THE RECORD, 
            BX1    -X5         -<NUMBER OF EXTRA WORDS> 
            MX0    -15         77777777777777700000B
            BX1    -X0*X1      00000000000000NNNNNNB
            GEN    (SX0 700000B+0),X1 
            NEWLBL NEXT 
            GENLBL NEXT 
            GEN    (SA7 A7+B1)
            GEN    (SX0 X0+B1)
            GEN    (NZ X0,"NEXT") 
            ENDIF.
  
*     SAVE *X6
  
          NEWLBL SAVEX6 
          GEN    (SA6 "SAVEX6") 
  
*     DECLARE LABELS FOR S$GNPRU ROUTINES 
  
          NEWLBL ORECLEN
          NEWLBL LRECLEN
          NEWLBL SRECLEN
  
          EXIT
  
  
 S$OREC   EXTERNAL           WORD OFFSET IN WSA$ OF THE EXTERNAL RECORD.
  
  
          END 
