*DECK S$GNIV9 
          IDENT  S$GNIV9
          TITLE  S$GNIV9 -  FINISH UP INVERSION 
          COMMENT  FINISH UP INVERSION
  
*CALL LBLPTR
  
          SPACE  4
**        S$GNIV9 -  FINISH UP INVERSION
* 
*     CALLING SEQUENCE- 
*         S$GNIV9;
* 
*     GIVEN - 
*         NOTHING 
* 
*     DOES- 
*         GENERATES LABELS "GOTREC" AND "GOTIREC".
*         FINISHES UP INVERSION PROCESSING
* 
  
  
          ENTRY  S$GNIV9
 S$GNIV9  SUBR
          SB1    1           CONSTANT 1 
*     IF *X6 IS NOT DESCRIPTOR, 
*         SAVE IT AND SET *X6 TO DESCRIPTOR 
  
          SA1    S$IRRL      NUMBER OF WORDS BEYOND DESCRIPTOR
          IFTHEN X1"0        IF MORE THAN *X6 SHOULD HAVE BEEN SET, 
            SA1    S$LR        NUMBER OF BITS FOR RECORD NUMBER 
            SA2    S$LK        NUMBER OF BITS APPENDED
            IX1    X1+X2
            SB7    X1+1+1      TOTAL NO OF BITS IN INTERNAL RECORD
            SB6    120
            IFTHEN B7@B6
              GEN    (SA3 "RECDESC")
              SA1    S$LR 
              GEN    (LX3 1+1),X1 
              SA1    S$LR 
              BX1    -X1
              GEN    (MX4 60-0),X1
              GEN    (BX3 -X4*X3) 
              SA1    S$IRRL 
              GEN    (SX4 0),X1 
              GEN    (IX3 X3*X4)
              SA1    S$ORSA 
              SA2    S$IRRL 
              IX1    X1-X2
              GEN    (SX3 X3+0),X1
              GEN    (SA4 "WSA")
              GEN    (IX3 X3+X4)
              GEN    (SA6 X3) 
            ELSE- 
              GEN    (SA6 A6+B1)
              ENDIF.
            GEN    (SA3 "RECDESC")
            GEN    (BX6 X3) 
            ENDIF.
          GENLBL GOTIREC
          GENLBL GOTREC 
* 
* 
* 
          EXIT
  
  
 S$IRRL   EXTERNAL           NUMBER OF WORDS PER SLOT IN THE RECORD 
                              STORAGE AREA  (I.E. REC$IRRL) 
 S$LK     EXTERNAL           NUMBER OF BITS OF INFORMATION THAT HAVE
                              BEEN PREVIOUSLY APPENDED
 S$LR     EXTERNAL           NUMBER OF BITS RESERVED FOR RECORD NUMBER
                              (REC$LR)
 S$ORSA   EXTERNAL           WORD OFFSET WITHIN WSA$ OF RECORD
                              STORAGE AREA  (WSAS$ORSA) 
  
  
          END 
