*DECK S$DIRHD 
          PROC S$DIRHD(DIRFLNM);
  
#**       S$DIRHD - MAKE HEADING FOR LIST FILE CONTAINING DIR FILE     #
#                                                                      #
#     CALLING SEQUENCE -                                               #
#         S$DIRHD(DIRFLNM):                                            #
#                                                                      #
#     GIVEN -                                                          #
#         DIRFLNM = NAME OF DIRECTIVE FILE BEING PROCESSED             #
#                                                                      #
#     DOES -                                                           #
#         CREATES A HEADER WHICH CONTAINS:                             #
#             SORT/MERGE VERSION AND LEVEL NUMBERS                     #
#             FILE NAME OF DIR FILE BEING PROCESSED                    #
#             TIME AND DATE                                            #
#         THEN USES S$PTLF TO PUT HEADER INTO LIST FILE                #
#                                                                      #
  
          BEGIN 
  
          XREF
              BEGIN 
              PROC S$DTCLK;   # GETS TIME AND DATE                     #
              PROC S$PTLF;    # PUTS LINE INTO LIST FILE               #
              PROC S$PTLFU;   # PUT UNSHIFTED LINE INTO LINE FILE      #
              END 
  
          ITEM DATE       C(10);  # YEAR/MONTH/DATE                    #
          ITEM DIRFLNM    C(10);  # NAME OF CURRENT DIR FILE           #
          ITEM DFLNM      C(10);  # A BLANK-FILLED COPY OF 'DIRFLNM'   #
          ITEM LINL       I;      # LINE LENGTH                        #
          ITEM K          I;      # INCREMENT VALUE                    #
          ITEM PTLIN      C(100); # LINE OF TEXT CONTAINING HEADER     #
          ITEM TIME       C(10);  # HOUR.MINUTE.SECOND                 #
  
          S$DTCLK(DATE,TIME); 
  
#           CHANGE 'DIRFLNM' FROM BEING ZERO-FILLED TO BLANK-FILLED    #
#           AND SET THIS BLANK-FILLED NAME INTO 'DFLNM'                #
  
          DFLNM = DIRFLNM;            # COPY 'DIRFLNM' INTO 'DLFNM'    #
          FOR K=0 STEP 1 UNTIL 9  DO
             BEGIN
              IF C<K,1>DIRFLNM EQ 0 THEN  # CHANGE ZERO TO SPACE #
                C<K,1>DFLNM = " ";
             END
  
#           PAGE EJECT ON LIST FILE                                    #
  
          S$PTLFU("1",10);
  
#           PUT TEXT OF HEADING INTO 'PTLIN'                           #
  
          PTLIN = "    "; 
          C<6,14>PTLIN = "SORT/MERGE 5.0";
          C<24,39>PTLIN = 
                "* LISTING OF DIRECTIVE FILE - XXXXXXX *";
          C<54,7>PTLIN = C<0,7>DFLNM; 
          C<67,10>PTLIN = DATE; 
          C<80,10>PTLIN = TIME; 
  
          S$PTLF(PTLIN,100);         # PRINT HEADER                    #
  
          END 
          TERM
