*DECK S$CLEAR 
          PROC S$CLEAR(FMTBL$); 
  
#**       S$CLEAR - RETURN INTERMEDIATE FILES                          #
#                                                                      #
#    CALLING SEQUENCE-                                                 #
#         S$CLEAR(FMTBL$)                                              #
#                                                                      #
#    GIVEN-                                                            #
#         FMTBL$ - LIST OF FILES NEEDED FOR FINAL MERGE                #
#                                                                      #
#    DOES -                                                            #
#         RETURNS ALL OF SORT 5'S INTERNAL FILES (ZZZZZ1A-ZZZZZ3Z)     #
#         -EXCEPT- 'ZZZZZ3X'  AND 'ZZZZZ3Y' AND THOSE INCLUDED IN      #
#         FMTBL$                                                       #
  
          BEGIN 
*CALL A 
*CALL FMTBL$
  
  
          XREF PROC S$RTNZZ;
  
          ITEM FILENAME;
          ITEM INDEX; 
          ITEM INDEX2;
          ITEM RETURNABLE   B;
  
          ARRAY FILESTOKEEP [1:20]; 
              BEGIN 
              ITEM FILETOKEEP;
              END 
  
              PROC CHECK(LFN);
              BEGIN 
              ITEM LFN; 
              ITEM LOOP;
              RETURNABLE = TRUE;
              FOR LOOP = 1 STEP 1 UNTIL INDEX2 DO 
                  BEGIN 
                  IF LFN EQ FILETOKEEP[LOOP] THEN 
                      BEGIN 
                      RETURNABLE = FALSE; 
                      RETURN; 
                      END 
                  END 
              END # CHECK # 
  
              PROC ZZZLOOP(LFN);
              BEGIN 
              ITEM LFN; 
              ITEM I; 
              FOR I = 1 STEP 1 UNTIL 26 DO
                  BEGIN 
                  B<36,6>LFN = I; 
                  CHECK(LFN); 
                  IF RETURNABLE THEN
                      S$RTNZZ(LFN); 
                  END 
              END # ZZZLOOP # 
  
  
#         SET UP ARRAY OF FILES TO KEEP DURING FINAL MERGE             #
          FOR INDEX = 1 STEP 1 UNTIL 20 DO
              FILETOKEEP[INDEX] = 0; # INITIALIZE # 
          FILETOKEEP[1] = O"32323232323630000001";  # ZZZZZ3X # 
          FILETOKEEP[2] = O"32323232323631000001";  # ZZZZZ3Y # 
          INDEX2 = FMTBL$MO;    # NUMBER OF FINAL-MERGE FILES          #
          INDEX2 = INDEX2 + 2;  # FIRST TWO ENTRIES ALREADY FILLED     #
          FOR INDEX = 3 STEP 1 UNTIL INDEX2 DO
              BEGIN 
              C<0,7>FILETOKEEP[INDEX] = FMTBL$FILE[INDEX-2];
              B<59>FILETOKEEP[INDEX] =1;
              END 
  
          # SET FILENAME = "ZZZZZ1-" AND RETURN ALL OF THEM            #
  
          FILENAME = O"32323232323400000001"; 
          ZZZLOOP(FILENAME);
  
          # SET FILENAME = "ZZZZZ2-" AND RETURN ALL OF THEM            #
  
          FILENAME = O"32323232323500000001"; 
          ZZZLOOP(FILENAME);
  
          # SET FILENAME = "ZZZZZ3-" AND RETURN ALL OF THEM            #
  
          FILENAME = O"32323232323600000001"; 
          ZZZLOOP(FILENAME);
          END 
  
          TERM
