*DECK S$ABORT 
          IDENT  S$ABORT
          TITLE  S$ABORT -  HANDLE INTERNAL ERROR 
          COMMENT  HANDLE INTERNAL ERROR
          SPACE  4
**        S$ABORT -  HANDLE INTERNAL ERROR
* 
*     CALLING SEQUENCE- 
*         SX1    =10H_S$XXXXX-N 
*         RJ     S$ABORT
* 
*     DOES- 
*         DISPLAYS "SORT- INTERNAL ABORT LABELLED S$XXXXX-N". 
*         ABORTS. 
* 
*     REGISTERS USED- 
*         B    - - - - - - -
*         X  - 1 - - - - - -
*         A  - 1 - - - - 6 -
  
  
          ENTRY  S$ABORT
 S$ABORT  SUBR
          SA6    SAVEX6      SAVE REGISTER X6 
          SA1    X1          10HS$XXXXX-N 
          BX6    X1          INSERT INTO MESSAGE
          SA6    ABORTC+3 
 ABORT1   SA1    1           ENSURE THAT RA+1 IS CLEAR
          NZ     X1,ABORT1
          SA1    ABORTA      SYSTEM REQUEST FOR MSG 
          BX6    X1 
          SA6    1           ISSUE SYSTEM REQUEST FOR MSG 
 ABORT2   SA1    1           WAIT UNTIL SYSTEM ACCEPTS REQUEST
          NZ     X1,ABORT2
          SX6    3RABT
          LX6    42          SYSTEM REQUEST FOR ABT 
          SA1    SAVEX6      ORIGINAL VALUE OF X6 
+         SA6    1           SIMULTANEOUSLY ISSUE ABT REQUEST 
          BX6    X1            AND RESTORE ORIGINAL X6
 ABORT3   SA1    A6          WAIT UNTIL SYSTEM ACCEPTS REQUEST
          CX1    X1          (DO NOT POUND MEMORY SO HARD)
          NZ     X1,ABORT3
          PS                 (SYSTEM SHOULD NOT LET US GET THIS FAR)
  
  
 ABORTA   VFD    18/3RMSG,2/1,22/,18/ABORTB 
  
 ABORTB   VFD    12/,18/ABORTC,12/,18/0 
  
 ABORTC   DATA   40HSORT- INTERNAL ABORT LABELLED **********
          DATA   0           (LINE TERMINATOR)
  
 SAVEX6   BSS    1
  
  
          END 
